FiveTech Software tech support forums

This is the sample:

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oWnd, oBrw

    USE TEST

    DEFINE WINDOW oWnd

    @ 0, 0 LISTBOX oBrw FIELDS

    oBrw:lCellStyle = .T.

    oWnd:oClient = oBrw

    ACTIVATE WINDOW oWnd;
             MAXIMIZED

    CLOSE

    RETURN NIL

Try to:

- move the hilight to a column near the right side of the browse

- restore the window (click the button near the right-top X)

- move the now invisible hilight to the left

You should get an error.

EMG

Enrico,

I confirm it with Aug 2006 build. I'm surprized nobody has reported it sooner.

James

This seems as a possible fix:

Code: Select all  Expand view

METHOD ReSize( nSizeType, nWidth, nHeight ) CLASS TWBrowse

   local nTotalSize := 0

   ::nRowPos = Min( ::nRowPos, Max( ::nRowCount(), 1 ) )
   ::nColAct = Min( ::nColAct, AScan( ::GetColSizes(),;
                                      { | nSize | nTotalSize += nSize,;
                                      nWidth < nTotalSize }, ::nColPos ) )

return Super:ReSize( nSizeType, nWidth, nHeight )


and in function wbrwline():

Code: Select all  Expand view

   ...
   nColPos = Max( nColPos, 1 )  // new!

   for n := nColPos to Len( aValues )
      nLeft   = nColStart + 1
      nRight  = Min( nColStart := ( nLeft + aColSizes[ n ] - 1 ), nWidth )
      if nLeft > nWidth
         exit
      endif
      if n >= Len( aValues ) // changed!
         nRight = nWidth
      endif
      ...


though is this the desirable behavior ?

Antonio Linares wrote:This seems as a possible fix:

Thank you.

Antonio Linares wrote:though is this the desirable behavior ?

Yes, it is similar to the vertical resize behavior. But there is one more problem: the horizontal scrollbar is not correctly updated. Can you fix that too?

EMG

Enrico,

Horizontal scrollbar updated:

Code: Select all  Expand view

METHOD ReSize( nSizeType, nWidth, nHeight ) CLASS TWBrowse

   local nTotalSize := 0

   ::nRowPos = Min( ::nRowPos, Max( ::nRowCount(), 1 ) )
   ::nColAct = Min( ::nColAct, AScan( ::GetColSizes(),;
                                      { | nSize | nTotalSize += nSize,;
                                      nWidth < nTotalSize }, ::nColPos ) )
   if ::oHScroll != nil
      ::oHScroll:SetPos( ::nColAct )
   endif

return Super:ReSize( nSizeType, nWidth, nHeight )


Perfect for me, thank you!

EMG

Unfortunately there is still a bug:

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oWnd, oBrw

    DBCREATE( "BUGTEST", { { "TEST1", "C", 10, 0 },;
                           { "TEST2", "C", 10, 0 } } )

    USE BUGTEST

    APPEND BLANK

    DEFINE WINDOW oWnd

    @ 0, 0 LISTBOX oBrw FIELDS

    oBrw:lCellStyle = .T.

    oWnd:oClient = oBrw

    ACTIVATE WINDOW oWnd;
             MAXIMIZED

    CLOSE

    RETURN NIL

No cell is selected.

EMG

Enrico,

It is a side effect of the latest change. This seems to fix it:

Code: Select all  Expand view

METHOD ReSize( nSizeType, nWidth, nHeight ) CLASS TWBrowse

   local nTotalSize := 0

   ::nRowPos = Min( ::nRowPos, Max( ::nRowCount(), 1 ) )
   ::nColAct = Min( ::nColAct, AScan( ::GetColSizes(),;
                                      { | nSize | nTotalSize += nSize,;
                                      nWidth < nTotalSize }, ::nColPos ) )
   ::nColAct = Max( ::nColAct, 1 )
                                     
   if ::oHScroll != nil
      ::oHScroll:SetPos( ::nColAct )
   endif

return Super:ReSize( nSizeType, nWidth, nHeight )


Thank you.

EMG

Sorry, one more bug:

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oWnd, oBrw

    DBCREATE( "BUGTEST", { { "TEST1", "C", 10, 0 },;
                           { "TEST2", "C", 10, 0 } } )

    USE BUGTEST

    APPEND BLANK

    DEFINE WINDOW oWnd

    @ 0, 0 LISTBOX oBrw FIELDS

    oBrw:lCellStyle = .T.

    oWnd:oClient = oBrw

    ACTIVATE WINDOW oWnd;
             MAXIMIZED

    CLOSE

    RETURN NIL

Select the second column and the resize the window: the first column will be selected back.

EMG

Any news?

EMG

Enrico,

Fixed. This code seems the right one:

Code: Select all  Expand view

METHOD ReSize( nSizeType, nWidth, nHeight ) CLASS TWBrowse

   local n, nTotalSize := 0, aSizes := ::GetColSizes()

   ::nRowPos = Min( ::nRowPos, Max( ::nRowCount(), 1 ) )
   
   n = Max( ::nColPos, 1 )
   while nTotalSize < nWidth .and. n <= Len( aSizes )
      nTotalSize += aSizes[ n++ ]
   end
   ::nColAct = Min( --n, ::nColAct )
                                     
   if ::oHScroll != nil
      ::oHScroll:SetPos( ::nColAct )
   endif

return Super:ReSize( nSizeType, nWidth, nHeight )


Please modify your example as follows and shrink the window and you will see how the selected cell is changed to the last visible one:

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oWnd, oBrw

    DBCREATE( "BUGTEST", { { "TEST1", "C", 10, 0 },;
                           { "TEST2", "C", 10, 0 },;
                           { "TEST3", "C", 10, 0 },;
                           { "TEST4", "C", 10, 0 } } )

    USE BUGTEST

    APPEND BLANK

    DEFINE WINDOW oWnd

    @ 0, 0 LISTBOX oBrw FIELDS

    oBrw:lCellStyle = .T.

    oWnd:oClient = oBrw

    ACTIVATE WINDOW oWnd
           

    CLOSE

    RETURN NIL


Many thanks!

EMG