Disable mouse double click event on xBrowse ? (Solved)

[anserkk]

Anybody any help ?

I have already spent hours trying to solve this problem.

I think I can solve the problem if I know how to ignore a mouse double clcik event on a particular column of xBrowse.

I am repeating the Problem Description once more
Problem : Double click event on a column in xBrowse is avtivating a GET, which I do not want. I want to ignore the double click event.

I am trying to do a CheckOn,CheckOff on an xBrowse column by either using a Enter Key, or Mouse Click. Enter key and mouse click is working fine, but double click is activating a GET (which I dont want).

A sample self containing code is posted in this thread itself.

Screen Snapshot




I have searched this forumn for the past 2 days and found nothing regarding ignoring a double click event.

Is this possible Or Am I moving in a wrong direction ?.

Mr.Antonio, Any hint ?

Regards

Anser

[anserkk]

Code: Select all  Expand view

oBrwMenu:bLDblClick:={|nRow, nCol| if(oBrwMenu:nColSel == 2, MsgInfo("Col 2"),MsgInfo("Some other Column") )}

With the above code, If I double clcik on any column OTHER THAN THE 2nd COLUMN, the MsgInfo displays the mesage "Some other Column"

but If I double click on the 2nd column MsgInfo("Col 2") is not getting executed at all and instead the GET is activated.

Regards

Anser

[Daniel Garcia-Gil]

ya vi que resolviste el problema, te respondi en el foro de español...

http://forums.fivetechsoft.com/viewtopic.php?t=14034

[Detlef Hoefner]

Anser,

i played a little with your code and modified the program.

At first i must state that in all answers to your questions it was supposed that nCol gives you the column number of the actual browse column.

Code: Select all  Expand view

oBrwMenu:bLDblClick:={|nRow, nCol| ... }

This is wrong.
To get the real column number you must use

Code: Select all  Expand view

oBrwMenu:MouseColPos( nCol )

With the Row number it's the same.

Now my version of your program.
I avoided a colum get.

Code: Select all  Expand view

#Include "FiveWin.ch"
#Include "xBrowse.ch"

////////////////
PROCEDURE Main()
////////////////
Local oDlg, oBrwMenu, oBtnCancel
Local aClrCol :={ { 0, nRGB( 192, 221, 255 ) }, { 0, nRGB( 221, 245, 255 ) } } // Xbrowse Alternative Column colours
Local aMenu   :={;
                    {  1, "Masters                       ", .F., .T. },;
                    {  2, "     Account Groups           ", .F., .F. },;
                    {  3, "     Account Heads            ", .F., .F. },;
                    {  4, "     Exit                     ", .F., .F. },;
                    {  5, "Transactions                  ", .F., .T. },;
                    {  6, "     Voucher Entry            ", .F., .F. },;
                    {  7, "     Sales Postings           ", .F., .T. },;
                    {  8, "          From GDMS           ", .F., .T. },;
                    {  9, "               Test sub menu 1", .F., .F. },;
                    { 10, "          From PDMS           ", .F., .F. },;
                    { 11, "     Test Menu                ", .F., .F. },;
                    { 12, "Reports                       ", .F., .T. },;
                    { 13, "     Trial Balance            ", .F., .F. },;
                    { 14, "     Profit & Loss Statement  ", .F., .F. },;
                    { 15, "     Balance Sheet            ", .F., .F. },;
                    { 16, "     Statement of Account     ", .F., .F. },;
                    { 17, "     Debtor                   ", .F., .F. },;
                    { 18, "Tools                         ", .F., .T. },;
                    { 19, "     Select Financial Year    ", .F., .F. },;
                    { 20, "     Calculator               ", .F., .F. },;
                    { 21, "Users                         ", .F., .T. },;
                    { 22, "     Create User              ", .F., .F. },;
                    { 23, "     Set user Permissions     ", .F., .F. } ;
                }



   DEFINE DIALOG oDlg FROM 70,20 to 630,690 TITLE "Test" PIXEL

   @ 0,100 XBROWSE oBrwMenu ;
       COLUMNS 2, 3 ;
       HEADERS "Menu", "Status" ;
       OF oDlg ;
       ARRAY aMenu   // should not use AUTOCOLS now

   oBrwMenu:lHScroll      := .F.  // Horizontal Scroll Bar not required
   oBrwMenu:lFooter       := .T.
   oBrwMenu:nMarqueeStyle :=  MARQSTYLE_HIGHLROWRC // MARQSTYLE_HIGHLROWMS MS can be used to place rec point on a partucular record and move futher using mouse scroll         

   // Sub Menu in different colour and Menu's in different Coclour
   oBrwMenu:bClrStd           :=  { || if( oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 4 ], aClrCol[ 1 ], aClrCol[ 2 ] ) }
   oBrwMenu:lUpdate           := .t.
   oBrwMenu:aCols[ 1 ]:nWidth := 350
   
   // Alternative way to display BMP, if multiple conditions and more than 2 bitmaps are there
   oBrwMenu:aCols[ 2 ]:AddResource( "CheckOn"  )
   oBrwMenu:aCols[ 2 ]:AddResource( "CheckOff" )
 
   // Checkbox should be displayed only if the menu type is not a Submenu
   oBrwMenu:aCols[ 2 ]:bBmpData := { || if( oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 4 ],;
                                            0,;
                                            if( oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 3 ],;
                                                1,;
                                                2;
                                              );
                                          );
                                   }
 
   oBrwMenu:aCols[ 2 ]:nWidth        := 50
   oBrwMenu:aCols[ 2 ]:bStrData      := { || NIL }
   oBrwMenu:aCols[ 2 ]:nDataStrAlign := AL_CENTER

   // here the permission is changed when lDblClick happens exactly on column 2
   // -------------------------------------------------------------------------
   oBrwMenu:bLDblClick := { | nRow, nCol | if( !oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 4 ] .and. oBrwMenu:MouseColPos( nCol ) == 2,;
                                               (;
                                                  oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 3 ] := !oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 3 ],;
                                                  oBrwMenu:Refresh();
                                               ),;
                                               NIL;
                                             );
                         
                          }
/*

   // here the permission is changed when lDblClick happens on whole row
   // ------------------------------------------------------------------
   oBrwMenu:bLDblClick := { | nRow, nCol | if( !oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 4 ] .and. oBrwMenu:MouseColPos( nCol ) == 2,;
                                               (;
                                                  oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 3 ] := !oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 3 ],;
                                                  oBrwMenu:Refresh();
                                               ),;
                                               NIL;
                                             );
                          }

*/
   oBrwMenu:bKeyDown := { | nKey | if( !oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 4 ],; // Is submenu the do nothing, bwhen will take care
                                       if ( nKey  == VK_SPACE,;
                                            (;
                                               oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 3 ] := !oBrwMenu:aArrayData[ oBrwMenu:nArrayAt ][ 3 ],;
                                               oBrwMenu:Refresh();
                                            ),;
                                            NIL;
                                          ),;
                                       NIL;
                                     );
                        }
                       
   oBrwMenu:CreateFromCode()

   @14.3, 05 BUTTON oBtnCancel PROMPT "Cancel" OF oDlg SIZE 50,15 ACTION oDlg:End()     
   
   ACTIVATE DIALOG oDlg CENTERED ;
      ON INIT (;
                  oBrwMenu:nLeft   := 220,;
                  oBrwMenu:nHeight := oDlg:nHeight - 35,;
                  oBrwMenu:nWidth  := 450,;
                  oBrwMenu:SetFocus();
              )

RETURN

Regards,
Detlef

[anserkk]

Dear Daniel and Detlef,

Thankyou for the support.

Is this possible Or Am I moving in a wrong direction ?.

As I doubted, I was moving in the wrong direction.

For the code to work successfully, I had to eliminate the following lines (GET), Detlef you are right.

Code: Select all  Expand view

oBrwMenu:aCols[2]:nEditType  := EDIT_GET
oBrwMenu:aCols[2]:bEditvalue := { || space(0) }

Detlef,

With the command

Code: Select all  Expand view

oBrwMenu:nColSel

I am able to get the xBrowse column no. So I believe that the commands

oBrwMenu:MouseColPos( nCol )
and
oBrwMenu:nColSel

gives the same result.

Once again I thank Daniel & Detlef.

Regards

Anser