Is it possible to save a pdf file into a memo field?

[hua]

Hi,
Is it possible to save/retrieve a pdf file to a memo field (without having to resort to ADS)?

If it is could anyone share some code snippets?

TIA

[StefanHaupt]

maybe you can do it with blob, but I have noe xperience with it.

[Gale FORd]

Code: Select all  Expand view

#INCLUDE "DBINFO.CH"
#INCLUDE "FILEIO.CH"

function my_file2blob( cFileName, cFieldName )
   local nHandle, lReturn := .f., bFieldBlock, cFileBuf
   local nPos
   bFieldBlock := fieldblock( cFieldName )
   nHandle := fopen( cFileName )
   if nHandle = -1
      Alert("Cannot access file " + cFileName)
   else
      nPos := fseek( nHandle,0,FS_END)
      if nPos > 0
         fseek( nHandle,0,FS_SET)
         cFileBuf:=space(nPos)
         fread(nHandle,@cFileBuf,nPos)
      endif
      lReturn := fclose(nHandle)
      if lReturn
         eval( bFieldBlock, cFileBuf )
      endif
   endif
return( lReturn )

function my_blob2file( cFileName, cFieldName )
   local nHandle, lReturn := .f., bFieldBlock
   bFieldBlock := fieldblock( cFieldName )
   nHandle := fcreate( cFileName )
   if nHandle = -1
      Alert("Cannot create file " + cFileName + ", export failed!")
   else
      if fwrite( nHandle, eval( bFieldBlock ) ) > 0
         lReturn := fclose( nHandle )
      else
         fclose( nHandle )
      endif
   endif
return( lReturn )


 

[hua]

Thanks Stefan and Gale