resize browse when click maximized dialog

[damianodec]

hi,
I would like to maximized my browse when I click maximized on my dialog but dialog maximized and browse not...

Code: Select all  Expand view

    DEFINE DIALOG oDlg2 RESOURCE "SQL" FONT oFont
       
        REDEFINE XBROWSE oBrw ALIAS "ESPCAT" ;
        COLUMNS "CDFOR" COLSIZES 70 HEADERS "CODICE" ID 200 OF oDlg2
       
        ADD oCol TO oBrw AT 2 DATA espcat->CDPAR TITLE "ARTICOLO"  SIZE 100 LEFT
        ADD oCol TO oBrw AT 3 DATA espcat->DEPAR TITLE "DESCRIZIONE"  SIZE 300 LEFT    
        ADD oCol TO oBrw AT 4 DATA espcat->UNMIS TITLE "UM"  SIZE 25 LEFT
       
        WITH OBJECT oBrw
        :nMarqueeStyle       := MARQSTYLE_HIGHLROW
        :nColDividerStyle    := LINESTYLE_BLACK
        :nRowDividerStyle    := LINESTYLE_BLACK
        :lColDividerComplete := .T.
        :lRecordSelector     := .F.
        :lHScroll            := .T.
        :lVScroll            := .T.
        :lExcelCellWise := .t.
        END
        REDEFINE BTNBMP BtnEsc ID 11 OF oDlg2            ;
            ACTION (oDlg2:End())               
        REDEFINE BTNBMP BtnEsc ID 12 OF oDlg2 RESOURCE "EXCEL"          ;
            ACTION (oBrw:ToExcel())                            

    ACTIVATE dialog oDlg2 CENTERED
 

I created my dialog by Pelles C with class name TXBROWSE and in Custom control properties "resizable dialog" I put VERT RESIZING "RESIZING and HORZ RESIZING "RESIZING"

any help?
thank you
ciao
Damiano

[nageswaragunupudi]

Code: Select all  Expand view

oBrw:nRightMargin := 20
oBrw:nBottomMargin := 40  // or whatever values in pixels

[damianodec]

hi Mr Rao, it work!
now I have another problem, when I maximized the dialog, browse is ok but BTNBMP buttons remain in their posizion overlapping to the browse.

ciao
Damiano

[nageswaragunupudi]

You need to move them with code in the ON RESIZE clause of the Dialog.
Best way to have fully flexible dialogs is to create from source code and not with resources.

OT:
We recommend creating xbrowse as below and not to use ADD TO oBrw

Code: Select all  Expand view

REDEFINE XBROWSE oBrw ALIAS "ESPCAT" ;
COLUMNS "CDFOR", "CDPAR", "DEPAR", "UNIMIS" ;
HEADERS "CDFOR", "ARTICOLO", "DESCRIZIONE", "UM" ;
COLSIZES 70, 100, 300, 25  ;
ID 200 OF oDlg2
 

[damianodec]

thank you!!!

[nageswaragunupudi]

This is an example of resizable dialog with adjusting controls when resized.

Code: Select all  Expand view

function RcBrowse

   local oDlg, oBrw, oBtn1, oBtn2, oRect

   USE STATES  // use any DBF you have

   DEFINE DIALOG oDlg SIZE 600,400 PIXEL TRUEPIXEL ;
   STYLE nOR( DS_MODALFRAME, WS_POPUP, WS_CAPTION, WS_SYSMENU, ;
              WS_MAXIMIZEBOX, WS_MINIMIZEBOX, WS_THICKFRAME )

   @ 80,20 XBROWSE oBrw SIZE -20,-80 PIXEL OF oDlg ;
      DATASOURCE "STATES" AUTOCOLS NOBORDER

   oBrw:CreateFromCode()

   @  20,500 BUTTON oBtn1 PROMPT "BtnOne" SIZE 80,30 PIXEL OF oDlg

   @ 350,500 BUTTON oBtn2 PROMPT "Close" SIZE 80,30 PIXEL OF oDlg ACTION oDlg:End()

   oDlg:bResized := { || ;
      oRect          := oDlg:GetCliRect(), ;
      oBtn2:nTop     := oRect:nBottom - 50, ;
      oBtn2:nLeft    := oRect:nRight - 100, ;
      oBtn1:nLeft    := oRect:nRight - 100  }

   ACTIVATE DIALOG oDlg CENTERED

return nil
 

Please build and run this program.
You may use this as a template

[damianodec]

very good mr rao
but I have FWH 12.01 and TRUEPIXEL do not work

ciao
Damiano

[nageswaragunupudi]

Without TRUEPIXEL clause:

Code: Select all  Expand view

#include "fivewin.ch"

function Main()

   local oDlg, oBrw, oBtn1, oBtn2, oRect

   USE STATES

   DEFINE DIALOG oDlg SIZE 600,400 PIXEL ;
   STYLE nOR( DS_MODALFRAME, WS_POPUP, WS_CAPTION, WS_SYSMENU, ;
              WS_MAXIMIZEBOX, WS_MINIMIZEBOX, WS_THICKFRAME )

   @ 40,10 XBROWSE oBrw SIZE -10,-40 PIXEL OF oDlg ;
      DATASOURCE "STATES" AUTOCOLS NOBORDER

   oBrw:CreateFromCode()

   @  10,250 BUTTON oBtn1 PROMPT "BtnOne" SIZE 40,15 PIXEL OF oDlg

   @ 175,250 BUTTON oBtn2 PROMPT "Close" SIZE 40,15 PIXEL OF oDlg ACTION oDlg:End()

   oDlg:bResized := { || ;
      oRect          := oDlg:GetCliRect(), ;
      oBtn2:nTop     := oRect:nBottom - 50, ;
      oBtn2:nLeft    := oRect:nRight - 100, ;
      oBtn1:nLeft    := oRect:nRight - 100  }

   ACTIVATE DIALOG oDlg CENTERED

return nil
 

[damianodec]

thank you Mr Rao

ciao
Damiano

[Silvio.Falconi]

This is an example of resizable dialog with adjusting controls when resized.

Code: Select all  Expand view

function RcBrowse

   local oDlg, oBrw, oBtn1, oBtn2, oRect

   USE STATES  // use any DBF you have

   DEFINE DIALOG oDlg SIZE 600,400 PIXEL TRUEPIXEL ;
   STYLE nOR( DS_MODALFRAME, WS_POPUP, WS_CAPTION, WS_SYSMENU, ;
              WS_MAXIMIZEBOX, WS_MINIMIZEBOX, WS_THICKFRAME )

   @ 80,20 XBROWSE oBrw SIZE -20,-80 PIXEL OF oDlg ;
      DATASOURCE "STATES" AUTOCOLS NOBORDER

   oBrw:CreateFromCode()

   @  20,500 BUTTON oBtn1 PROMPT "BtnOne" SIZE 80,30 PIXEL OF oDlg

   @ 350,500 BUTTON oBtn2 PROMPT "Close" SIZE 80,30 PIXEL OF oDlg ACTION oDlg:End()

   oDlg:bResized := { || ;
      oRect          := oDlg:GetCliRect(), ;
      oBtn2:nTop     := oRect:nBottom - 50, ;
      oBtn2:nLeft    := oRect:nRight - 100, ;
      oBtn1:nLeft    := oRect:nRight - 100  }

   ACTIVATE DIALOG oDlg CENTERED

return nil
 

Please build and run this program.
You may use this as a template

Nages,
it is very nice.