Cambiar el borde a un Get *SOLUCIONADO*

[VictorCasajuana]

Hola.

Estoy haciendo una validación de datos ( Crsitobal ) y me gustaría remarcar los valores que no son correctos. Lo ideal sería poder cambiar el borde del Get de dichos valores a otro color, por ejemplo rojo como hacen la mayoría de formularios web. Es posible?

He revisado la clase TGET y sus herencias pero no doy con la clave.

El resultado sería como este, el segundo get sería el inválido.

[hmpaquito]

Prueba asi oGet:bPainted:= {| hDC | DrawBox( 0, 0, oGet:nHeight, oGet:nWidth, hDC, 0, 0, 1, CLR_RED ) }

[VictorCasajuana]

Gracias,

Con

Code: Select all  Expand view  RUN

oGet:bPainted:= {| hDC | DrawBox( 0, 0, oGet:nHeight, oGet:nWidth, hDC, 0, 0, 1, CLR_RED ) }

Me arroja el siguiente error:
Error description: Error BASE/1068 Argument error: array access
Args:
[ 1] = N 0
[ 2] = N 2

Stack Calls
===========
Called from: .\source\classes\TCALEX.PRG => DRAWBOX( 1830 )

He revisado la función DrawBox() de TCalex.PRG y solo recibe 3 parámetros:

Code: Select all  Expand view  RUN

FUNCTION DrawBox( hDC, aRect, nAdj )
   local aPoints
   DEFAULT nAdj := 0

   aPoints := { { aRect[ 2 ], aRect[ 1 ] },; //start
                { aRect[ 4 ], aRect[ 1 ] },; //top
                { aRect[ 4 ], aRect[ 3 ] },; //right
                { aRect[ 2 ], aRect[ 3 ] },; //Bottom
                { aRect[ 2 ], aRect[ 1 ] - nAdj } } //left

   PolyLine(  hDC,  aPoints )

return nil

Ajustando:

Code: Select all  Expand view  RUN

oGet2:bPainted:= {| hDC | DrawBox( hDC, { 0, 0, oGet2:nHeight, oGet2:nWidth } ) }

Me hace un cuadro "diferente" pero no se le puede pasar el color a DrawBox()

[cmsoft]

Es muy interesante la funcionalidad que queres hacer.
En la clase TGraph hay metodos que te pueden ser de utilidad
METHOD DrawBox( nTop, nLeft, nBottom, nRight, nColor )
METHOD DrawLine( nY, nX, nHigh, nWidth, nColor, lDotted )
...
MESSAGE CreatePen METHOD _CreatePen()
METHOD DeletePen()

[nageswaragunupudi]

Why are you looking in tcalex.prg and tgraph.prg for drawing boxes?
TWindow class has a method Box and is available for every dialog and control too.

oWnd/oDlg/oCtrl:Box( nTop, nLeft, nBottom, nRight, uBorder, uBrush, aText )
uBorder can be Color constant, or oPen or hPen.

[VictorCasajuana]

Es muy interesante la funcionalidad que queres hacer.
En la clase TGraph hay metodos que te pueden ser de utilidad

Gracias, estoy intentando emular el sistema de validaciones automáticos que lleva Laravel o Angular.

Why are you looking in tcalex.prg and tgraph.prg for drawing boxes?
TWindow class has a method Box and is available for every dialog and control too.

Sorry, I got confused looking for the right function/method!

oWnd/oDlg/oCtrl:Box( nTop, nLeft, nBottom, nRight, uBorder, uBrush, aText )
uBorder can be Color constant, or oPen or hPen.

Test with Box() Method of TGet Class but don't function....


Code:

Code: Select all  Expand view  RUN

#include 'fivewin.ch'

Function Main()

    Local oDlg
    Local oGet1
    Local cVar1 := Space( 100 )
    Local oGet2
    Local cVar2 := Space( 100 )

    DEFINE DIALOG oDlg Resource "Dialogo2"

    Redefine Get oGet1 Var cVar1 Id 4004 Of oDlg

    Redefine Get oGet2 Var cVar2 Id 4001 Of oDlg
    oGet2:Box( 0, 0, oGet2:nHeight, oGet2:nWidth, CLR_RED )
   
    ACTIVATE DIALOG oDlg CENTER

Return ( Nil )

Resource:

Code: Select all  Expand view  RUN

// RESOURCE SCRIPT generated by "Pelles C for Windows, version 10.00".

#include <windows.h>
#include <commctrl.h>
#include <richedit.h>

LANGUAGE LANG_NEUTRAL,SUBLANG_NEUTRAL

DIALOGO2 DIALOG DISCARDABLE 14, 40, 330, 36
STYLE WS_POPUP|DS_MODALFRAME|DS_CONTEXTHELP|WS_THICKFRAME|WS_CAPTION|WS_SYSMENU|WS_MINIMIZEBOX|WS_MAXIMIZEBOX|WS_CLIPSIBLINGS|WS_CLIPCHILDREN|WS_VISIBLE
EXSTYLE WS_EX_TRANSPARENT|WS_EX_CONTEXTHELP
CAPTION "Dialogo"
FONT 10, "Segoe UI Light"
{
  CONTROL "Edit", 4004, "Edit", ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 8, 4, 316, 12
  CONTROL "Edit", 4001, "Edit", ES_AUTOHSCROLL|WS_BORDER|WS_TABSTOP, 8, 20, 316, 12
}

 

[karinha]

Code: Select all  Expand view  RUN

#Include 'FiveWin.Ch'

#Define CLR_PINK       RGB( 255, 128, 128)

FUNCTION Main()

   Local oDlg, cTitle
   Local oGet1
   Local cVar1 := Space( 100 )
   Local oGet2
   Local cVar2 := Space( 100 )

   cTitle := OemToAnsi( "FIVEWIN: GET CON BORDES RED COLOR Y PAINT" )

   DEFINE DIALOG oDlg Resource "DIALOGO2" TITLE cTitle ;
      COLORS CLR_BLACK, CLR_WHITE TRANSPARENT

   oDlg: lHelpIcon := .F.

   REDEFINE GET oGet1 VAR cVar1 ID 4004 OF oDlg

   REDEFINE GET oGet2 VAR cVar2 ID 4001 OF oDlg
   
   ACTIVATE DIALOG oDlg CENTER                                               ;
      ON PAINT( oGet2:Box( -1, -1, oGet2:nHeight, oGet2:nWidth, CLR_HRED ) )

RETURN NIL
 

Saludos.

[VictorCasajuana]

Thanks! it works fine with PAINT or bPainted and NOBORDER in resource.
This is the Result:

[VictorCasajuana]

A vueltas con este tema, he conseguido que se muestren los bordes dependiendo de la validación del get que tengo montada, el problema es que los caracteres del get están arriba y cuando escribo se tapa la línea del borde superior. He estado revisando la clase tGet() para ver como puedo desplazar dichos caracteres hacia abajo pero no he encontrado nada.
El diálogo lo defino desde recurso y los gets están marcados sin borde



Gracias!

[karinha]

Cual és la FONT?

-1 -1, funciona perfecto con WorkShop.exe y el GET sin Border.

Saludos.

[VictorCasajuana]

Cual és la FONT?

-1 -1, funciona perfecto con WorkShop.exe y el GET sin Border.

Saludos.

Utilizo esta:

Code: Select all  Expand view  RUN

::oFont := TFont():New ( 'Segoe UI', 0, -12,,,,,,,,,,,,,,,.f. )

[VictorCasajuana]

En vez de oGet:Box he utilizado oGet:oWnd:Box y ya funciona bien sin tener que quitar el borde del get en el recurso, por lo que también se ha solucionado el problema que se eliminaba el marco al pasar el el cursor del ratón

[jgabri]

Hola
Puedes publicar el código, de cómo lo estás haciendo ?
Un saludo y gracias

[VictorCasajuana]

Hola
Puedes publicar el código, de cómo lo estás haciendo ?
Un saludo y gracias

Code: Select all  Expand view  RUN

oGet:oWnd:Box ( oGet:nTop - 1,;
                oGet:nLeft - 1,;
                oGet:nTop + oGet:nHeight ,;
                oGet:nLeft + oGet:nWidth ,;
                { HexToRgb ( '#d4edda' ), 1 } )

[jgabri]

Mil gracias Víctor, funciona perfectamente !!