Clic Derecho Xbrowse (Solucionado)

[leandro]

Compañeros del foro buen día

Lo que pasa es que tengo varias columnas definidas en un xbrowse. Y necesito que al hacer clic derecho me muestre un menu popup. Actualmente lo estoy haciendo de la siguiente manera:

Code: Select all  Expand view

  oBrwDofa:bRClicked           := { | nRow, nCol | ShowPopup( nRow, nCol , oBrwDofa }
 

y el menu

Code: Select all  Expand view

***********************************
*MENU POP-UP CON TODAS LAS OPCIONES
***********************************
function ShowPopup( nRow, nCol, oBrw )
local oPopup, oFont

MENU oPopup POPUP 2007
  MENUITEM "Agregar Lote" RESOURCE "#8073" ACTION oLamcla:autoriza(72)
  MENUITEM "Modificar Lote" RESOURCE "#8082" ACTION oLamcla:autoriza(73)
  MENUITEM "Borrar Lote" RESOURCE "#8074" ACTION oLamcla:autoriza(74)
  SEPARATOR
  MENUITEM "Fotografia Lote" RESOURCE "#8081" ACTION oLamcla:autoriza(76)
  if alltrim(oRsDocfac:Fields( "estdcpt" ):Value)="L"
    MENUITEM "Vender Lote" RESOURCE "#8084" ACTION oLamcla:autoriza(79)
  else
    MENUITEM "Vender Lote" DISABLED RESOURCE "#8084"
  endif
  MENUITEM "Consulta Pagos" ACTION oLamcla:autoriza(77)
  MENUITEM "Linderos Lote" RESOURCE "#8098" ACTION oLamcla:autoriza(105)
  SEPARATOR
  if alltrim(oRsDocfac:Fields( "estdcpt" ):Value)="G"
    MENUITEM "Gestion Acuerdos de Pago" RESOURCE "#8097" ACTION oLamcla:autoriza(87)
  else
    MENUITEM "Gestion Acuerdos de Pago" RESOURCE "#8097" DISABLED
  endif
  SEPARATOR
  MENUITEM "Contrato C-Vta Entregado" RESOURCE "#8084" ACTION oLamcla:autoriza(108)
  SEPARATOR
  MENUITEM "Cerrar Ventana" RESOURCE "#8076" ACTION oWHiCt:End()
ENDMENU
ACTIVATE POPUP oPopup OF oBrw AT nRow, nCol
return nil
 

Hasta ahí todo bien ahora el tema se complica, por que necesito saber sobre que columna se hace el clic. Dependiendo de la columna se deben mostrar opciones diferentes.

Alguien sabe como hacer esto?.

[Armando]

Leandro:

Y la variable nCol de tu código no te da el número de columna sobre la que se da el clic?

Code: Select all  Expand view

oBrwDofa:bRClicked           := { | nRow, nCol | ShowPopup( nRow, nCol , oBrwDofa }
 

En la función ShowPopup()

MsgInfo(nCol)

Saludos

[nageswaragunupudi]

Please do not use bRClicked at all.

Recommended:
This is how XBrowse implements popups.

oBrw:bPopUp := { |oCol| MyPopUp( oCol ) } // applies to the entire browse

oCol:bPopup := { |oCol| MyPopUp( oCol ) } // Popup is shown when right clicked on this column only.

Sample popup function:

function MyPopUp( oCol )

local oBrw := oCol:oBrw
local oPop

MENU oPop POPUP 2007
... menuitems depending on the column
ENDMENU

// do not activate popup here.
// return oPop object.
// xbrowse automatically activates the popup at the correct position.

return oPop

Please see \fwh\samples\testxbr3.prg for sample usage.

[leandro]

Leandro:

Y la variable nCol de tu código no te da el número de columna sobre la que se da el clic?

Code: Select all  Expand view

oBrwDofa:bRClicked           := { | nRow, nCol | ShowPopup( nRow, nCol , oBrwDofa }
 

En la función ShowPopup()

MsgInfo(nCol)

Saludos

Gracias por Responder Armando... Pense exactamente lo mismo que tu. Pero lo que retorna es la posición (y) del cursor.

Mr. Rao.. Muchas gracias por responder. Voy a realizar pruebas y comento.

[cnavarro]

Aunque, evidentemente la indicacion correcta es la que indica Mr. Rao, creo que el metodo ::nAtCol( nPix ) devolvia la columna en la que te encuentras

[leandro]

Excelente Mr.Rao Era lo que necesitaba. Muchas Gracias

Cristobal... Voy a realizar pruebas con tu informacion.