MariaDb y oReport

[pedroluis]

Hola Gente !!!
Estoy empezando a hacer pruebas con el MariaDb.
He logrado hacer mi primer actualización de una
tabla de clientes, pero...

Quiero preguntarles con hacer andar un oReport,
como el siguiente:
Y también si me pueden indicar que tengo que
hacer para impromir con la clase Print.

Muchas Gracias !!!

*--------------------------------------
FUNCTION VTA010LI1( oBrw )
*--------------------------------------
local oReport
local oFont1
local oFont2
local xtipiva:={"RI ","RNI","C/F","EXE","MON"}
sysrefresh()

oR31 := oCn:RowSet( "SELECT * FROM mae_cli ORDER BY cliente" ) // !!!

PRINTER oReport NAME "Clientes"
DEFINE FONT oFont1 NAME "Arial" SIZE 0,-8 BOLD
DEFINE FONT oFont2 NAME "Arial" SIZE 0,-8
REPORT oReport;
TITLE "LISTADO DE CLIENTES (NUMERICO)" ;
FONT oFont1, oFont2 ;
HEADER "Fecha: " + DToC( Date() ) , "Hora.: " + Time() ;
FOOTER "Página: " + Str( oReport:nPage, 3 ) ;
PREVIEW NAME "Clientes" ;
CAPTION "Clientes"
COLUMN TITLE "NRO.","IVA";
DATA cliente,if(str(sit_iva,1) $"12345",xtipiva[sit_iva],"") FONT 2
COLUMN TITLE "NOMBRE","DIRECCION";
DATA nombre,direccion," " FONT 2
COLUMN TITLE "LOCALIDAD","PROVINCIA";
DATA subs(localidad,1,15),provincia FONT 2
END REPORT
oReport:bInit:={||.t.}
oReport:bInit := { || dbGoTop() }
ACTIVATE REPORT oR31:oReport
return nil

[nageswaragunupudi]

Code: Select all  Expand view

COLUMN TITLE "NOMBRE" DATA oR31:nombre FONT 2

[nageswaragunupudi]

This is a sample you can try

Code: Select all  Expand view

#include "fivewin.ch"

function Main()

   local oCn, oRs, oRep

   oCn   := FW_DemoDB()
   oRs   := oCn:RowSet( "select * from customer where id < 21" )

   xbrowser oRs

   REPORT oRep PREVIEW

   COLUMN TITLE "ID" DATA oRs:id
   COLUMN TITLE "FIRST","LAST"  DATA oRs:First, oRs:Last
   COLUMN TITLE "AGE", "MARRIED" DATA oRs:Age, If( oRs:Married,"Married","Single" )
   COLUMN TITLE "SALARY" DATA oRs:Salary TOTAL

   ENDREPORT

   oRep:bInit := { || oRs:GoTop() }
   oRep:bSkip  := { |n| oRs:Skip( n ) }

   ACTIVATE REPORT oRep WHILE !oRs:Eof()

   oRs:Close()
   oCn:Close()

return nil
 

[pedroluis]

Muchas gracias Mr. Dao !!!