Mostrar/ocultar consulta presionando/soltando boton de mouse

[JoseAlvarez]

Hola a Todos.. saludos.

Mi consulta es la siguiente:

¿de que manera puedo hacer que al clickar sobre un boton, se muestre una consulta dentro de un dialogo, pero que al soltar el boton del mouse el dialogo desaparezca ?

o sea, mientras el boton este presionado veo la consulta, al soltarlo, desaparece la consulta.

¿habra alguna forma de hacerlo ?

Espero haberme explicado bien...

[karinha]

Que tal un TIMER()?

Regards, saludos.

[JoseAlvarez]

Hola Joao..

¿de que manera se podria utilizar un timer? la idea es que mientras el usuario mantenga presionado el boton del mouse, la consulta se muestre en pantalla, y que al soltar el boton la consulta desaparezca.

Un timer funciona durante un tiempo determinado.

¿como podria usarse un timer en este caso?

No tengo idea...

[karinha]

Hello my dear, mira \samples\MNUSELECT.PRG, creo sea el camiño.

Regards, saludos.

[karinha]

http://wiki.fivetechsoft.com/doku.php?id=fivewin_pulldown_menu

[JoseAlvarez]

Ok Amigo.

voy a probar eso y te comento...

[cnavarro]

Y si investigas tambien con el

oControl:bLButtonUp = { | nRow, nCol | ....

[karinha]

Y si investigas tambien con el

oControl:bLButtonUp = { | nRow, nCol | ....

\samples\TESTMOUS.PRG ?

Regards, saludos.

[nageswaragunupudi]

Code: Select all  Expand view

function BtnUpDn()

   local oDlg, oBtn, oSay, oFont, oLarg

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE FONT oLarg NAME "TAHOMA" SIZE 0,-30

   DEFINE DIALOG oDlg SIZE 300,260 PIXEL TRUEPIXEL FONT oFont

   @ 160,20 BTNBMP oBtn ;
      PROMPT { || If( oBtn:lPressed, "DOWN", "UP" ) } ;
      SIZE 100,60 PIXEL OF oDlg FLAT
   oBtn:bPainted := { || oSay:Refresh() }

   @  20,20 SAY oSay PROMPT { || If( oBtn:lPressed, "BUTTON PRESSED", "" ) } ;
      SIZE 260,100 PIXEL OF oDlg CENTER VCENTER FONT oLarg UPDATE

   ACTIVATE DIALOG oDlg CENTERED

   RELEASE FONT oFont, oLarg

return nil
 

[nageswaragunupudi]

Another variation

Code: Select all  Expand view

function BtnUpDn()

   local oDlg, oBtn, oSay, oFont, oLarg
   local oMsgDlg

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE FONT oLarg NAME "TAHOMA" SIZE 0,-30

   DEFINE DIALOG oDlg SIZE 300,300 PIXEL TRUEPIXEL FONT oFont

   @ 200,20 BTNBMP oBtn ;
      PROMPT { || If( oBtn:lPressed, "DOWN", "UP" ) } ;
      SIZE 100,60 PIXEL OF oDlg FLAT
   oBtn:bPainted := <||
      if oBtn:lPressed
         if oMsgDlg == nil
            oMsgDlg  := ShowMessage()
         endif
      else
         if oMsgDlg != nil
            oMsgDlg:End()
            oMsgDlg  := nil
         endif
      endif
      return nil
      >

   ACTIVATE DIALOG oDlg CENTERED

   RELEASE FONT oFont, oLarg

return nil

//----------------------------------------------------------------------------//

static function ShowMessage()

   local oDlg

   DEFINE DIALOG oDlg SIZE 200,60 PIXEL TRUEPIXEL TITLE "DIALOG"
   @ 20,20 SAY "Button Pressed" SIZE 160,20 PIXEL OF oDlg ;
      CENTER VCENTER
   ACTIVATE DIALOG oDlg CENTERED NOMODAL

return oDlg

//----------------------------------------------------------------------------//
 

[JoseAlvarez]

Hola amigos del foro...

Gracias a los que me ayudaron con mi consulta.

Por gusto personal me quede con la sugerencia de Mr. Nages, me funciono a la primera y perfectamente...

Muchas gracias de verdad...

Un abrazo a todos, agradezco siempre su buena dispocison a ayudar.