posible mejora en Tprinter

[mastintin]

Sería bueno añadir este par de metodos a la clase tPrinter , quitaría algo de trabajo .

Code: Select all  Expand view

METHOD CmBox( nRow, nCol, nBottom, nRight, oPen ) CLASS TPrinter
local aTmp := ::CmRect2Pix({ nRow, nCol, nBottom, nRight })
      ::Box( aTmp[1], atmp[2], aTmp[3], aTmp[4], oPen )
Return nil

METHOD CmLine( nRow, nCol, nBottom, nRight, oPen ) CLASS TPrinter
local aTmp := ::CmRect2Pix({ nRow, nCol, nBottom, nRight })
      ::Line( aTmp[1], atmp[2], aTmp[3], aTmp[4], oPen )
Return nil

 

[Antonio Linares]

Manuel,

gracias! Incluido para el próximo build

He modificado tu código asi:

Code: Select all  Expand view

METHOD CmBox( nRow, nCol, nHeight, nWidth, oPen ) CLASS TPrinter

   local aTmp := ::CmRect2Pix( { nRow, nCol, nRow + nHeight - 1, nCol + nWidth - 1 } )
   
return ::Box( aTmp[ 1 ], aTmp[ 2 ], aTmp[ 3 ], aTmp[ 4 ], oPen )
 
METHOD CmLine( nRow, nCol, nHeight, nWidth, oPen ) CLASS TPrinter

   local aTmp := ::CmRect2Pix( { nRow, nCol, nRow + nHeight - 1, nCol + nWidth - 1 } )
   
return ::Line( aTmp[ 1 ], aTmp[ 2 ], aTmp[ 3 ], aTmp[ 4 ], oPen )
 

[mastintin]

Esa implementación me parece muy correcta , pero rompe un poco con el paralelismo con ::box() y ::line() que no usan alto y ancho sino cordenadas "finales" .
Para mi es mas cómoda tu implementacion , pero ... ¿ Como lo ves ?

[Antonio Linares]

Manuel,

Tienes razón, es preferible implementarlo de la misma forma usada anteriormemte

gracias!

[mastintin]

mas mejora :

Code: Select all  Expand view

METHOD Pix2Cmtr(nRow, nCol) INLINE ;
                   ( nRow := ( nRow * 25.4 / ::nLogPixelX() ) / 10 ,;
                     nCol := ( nCol * 25.4 / ::nLogPixelY() ) /10  ,;
                     {nRow, nCol}                )

 

[Antonio Linares]

Incluido tambien, gracias!

[mastintin]

Aun mas . Estas devuelven el punto que centra el texto en la página .
La longuitud del texto en cm.
imprime un texto con un box .
imprime un texto con un box centrado en la pagina ( ideal para titulos)
Ya esta completo .

Code: Select all  Expand view

METHOD CmtrGetTextWidth( cText, oFont ) INLINE ( ::GetTextWidth( cText, oFont ) * 25.4 / ::nLogPixelX() ) / 10

METHOD CmtrTextToCenter( cText, oFont ) INLINE  ;
       (( ::nHorzSiZe() / 10   ) /2 ) -  ( ( ::GetTextWidth( cText, oFont ) * 25.4 / ::nLogPixelX() ) / 10) /2

METHOD TextInBoxCentered(nTop,cText,cmExRow,cmExCol,ofont,oPen,nColor ) INLINE  ;
    ::TextInBox( nTop, ::CmtrTextToCenter( cText, oFont ),cText,cmExRow,cmExCol,ofont,oPen,nColor )

METHOD TextInBox(nTop,nLeft,cText,cmExRow,cmExCol,oFont,oPen,nColor ) CLASS TPrinter

local cmTextWidth   := ( ::GetTextWidth( cText, oFont ) * 25.4 / ::nLogPixelX() ) / 10
local cmTextHeight  := ( ::GetTextHeight( cText, oFont ) * 25.4 / ::nLogPixelY() ) / 10

       ::cmBox( nTop - cmExRow  , ;
                 nLeft - cmExCol ,;
                 nTop + cmTextWidth  + cmExRow , ;
                 nLeft+ cmTextHeight + cmExCol , ;
                 oPen )

      ::cmsay( nTop,nLeft,cText,oFont,,nColor )

RETURN nil


 

[davidObarrio]

Estimado....

que bueno estas nuevas mejoras.... podrías publica como te queda la clase arregada ?

gracias totales

david

[sysctrl2]

En síntesis , si todo esto va de la mano con un TestPrn.Prg, es mas significativo.
saludos.

[mastintin]

Estimado....

que bueno estas nuevas mejoras.... podrías publica como te queda la clase arregada ?

gracias totales

david

Siento no poder enviar la clase tprinter pertenece a Fivetech y esta bajo licencia , por ello he publicar los trozos de código variados pero no la clase completa.

En síntesis , si todo esto va de la mano con un TestPrn.Prg, es mas significativo.
saludos.

Intentaré hacer un ejemplo sencillo entre hoy y mañana , aunque ahora mismo estoy algo liado , si mañana no publico el sample la cosa tendra que esperar a que vuelva pues salgo el sabado de viaje para toda la semana . Para la vuelta prometido que tienes algo .
Saludos.

[mastintin]

Aqui dejo un testprint7.prg rapido .No lo he testeado pues no estoy en windows pero tiene que funcionar si añadimos los metodos anteriores.

Code: Select all  Expand view

#include "FiveWin.ch"
 function Main()
    local oPrn, cText
    local  oFont
    local cmLeft
    local cmTexto
 
 
   PRINTER oPrn PREVIEW

      DEFINE FONT oFont NAME "Courier New" SIZE 0, -10 OF oPrn
      DEFINE PEN  oPen1  STYLE PS_SOLID WIDTH 2 OF oPrn
     
      PAGE

        oPrn:TextInBox( 10,5,"Texto dentro de box",0.2,0.2,oFont,oPen1 )
        oPrn:TextInBoxCentered(8,"Texto Centrado en pagina dentro de box",0.2,0.2,ofont,oPen1 )

         cmLeft:= oPrn:CmtrTextToCenter( "Texto que debemos centrar", oFont )
        oPrn:cmSay(12,cmLeft,"Texto que debemos centrar",oFont )

        cmText:= oPrn:CmtrGetTextWidth( "Texto del que queremos saber su longuitud en centimetros", oFont )

        oPrn:cmSay(14,5,"El texto anterior mide "+AllTrim(Str(cmtext))+ " cm.",oFont )
                       
      ENDPAGE          
     
   ENDPRINTER
   
 
   oFont:End()

return

 

[Antonio Linares]

Manuel,

Añadido para FWH 13.05, gracias!

[mastintin]

Antonio , En el código existe un gazapo en el metodo TextInBox ( cambiado alto * ancho )
La forma correcta es esta :

Code: Select all  Expand view

METHOD TextInBox(nTop,nLeft,cText,cmExRow,cmExCol,oFont,oPen,nColor ) CLASS TPrinter

local cmTextWidth   := ( ::GetTextWidth( cText, oFont ) * 25.4 / ::nLogPixelX() ) / 10
local cmTextHeight  := ( ::GetTextHeight( cText, oFont ) * 25.4 / ::nLogPixelY() ) / 10

       ::cmBox( nTop - cmExRow  , ;
                 nLeft - cmExCol ,;
                 nTop + cmTextHeight  + cmExRow , ;
                 nLeft+cmTextWidth  + cmExCol , ;
                 oPen )

      ::cmsay( nTop,nLeft,cText,oFont,,nColor )

RETURN nil


 

el testprint7 revisado :

Code: Select all  Expand view

#include "FiveWin.ch"
 function Main()
    local oPrn, cText
    local  oFont
    local cmLeft
    local cmTexto
 
 
   PRINTER oPrn PREVIEW

      DEFINE FONT oFont NAME "Courier New" SIZE 0, -10 OF oPrn
      DEFINE PEN  oPen1  STYLE PS_SOLID WIDTH 2 OF oPrn
     
      PAGE

        oPrn:TextInBox( 10,5,"Texto dentro de box",0.2,0.2,oFont,oPen1 )
        oPrn:TextInBoxCentered(8,"Texto Centrado en pagina dentro de box",0.2,0.2,ofont,oPen1 )

         cmLeft:= oPrn:CmtrTextToCenter( "Texto que debemos centrar", oFont )
        oPrn:cmSay(12,cmLeft,"Texto que debemos centrar",oFont )

        cmText:= oPrn:CmtrGetTextWidth( "Texto del que queremos saber su longuitud en centimetros", oFont )

        oPrn:cmSay(14,5,"El texto anterior mide "+AllTrim(Str(cmtext))+ " cm.",oFont )
                       
      ENDPAGE          
     
   ENDPRINTER
   
 
   oFont:End()

return


 

el resultado del test :

[Biel EA6DD]

Buen trabajo, gracias por tu tiempo y esfuerzo en mejorar las clases, y por compartir ese trabajo.