How To Change Radion Button

[acwoo1]

Hi

Code: Select all  Expand view

function testbutton()


   local oDlg
   local nOption := 2
   local obtn1, obtn2
   local oRad

             DEFINE DIALOG oDlg FROM 0, 0 TO 34, 99 ;
               TITLE "Test RADIO BUTTON" ;
          GRADIENT { { 1, nRGB( 199, 216, 237 ), nRGB( 237, 242, 248 ) } }
      @ 13, 0.22 RADIO oRad VAR nOption PROMPT "This is option 1",;
           "This is option 2" OF oDlg;
         ON CHANGE { || radiobtntest(nOption) } size 100, 10.45 UPDATE

   @ 13.49, 29.3 BUTTON "&OK"  OF oDlg SIZE 40, 12 ACTION (oDlg:End())
   @ 1, 1 BUTTON oBtn1 PROMPT "&Change To Option 1"  OF oDlg SIZE 8, 8 ACTION (changebutton(1))
   @ 2, 1 BUTTON oBtn2 PROMPT "C&hange To Option 2"  OF oDlg SIZE 8, 8 ACTION (changebutton(2))

   ACTIVATE DIALOG oDlg CENTERED

return nil
*****************************************
function radiobtntest()

parameter ckhradio

   if ckhradio = 1
      nOption = 1
   else
      nOption = 2
   endif
return nil
********************************************
function changebutton(buttontype)

if buttontype = 1
   nOption = 1
else
   nOption = 2
endif

return nil
***************************
 

How do I change the radio button to option 1 when I click the top button.

Thanks

ACWOO
Using bcc582+harbour+FWH1304

[FranciscoA]

Try this way:

Code: Select all  Expand view

function testbutton()

   local oDlg
   local nOption := 2
   local obtn1, obtn2
   local oRad

   DEFINE DIALOG oDlg FROM 0, 0 TO 34, 99 ;
          TITLE "Test RADIO BUTTON" ;
          GRADIENT { { 1, nRGB( 199, 216, 237 ), nRGB( 237, 242, 248 ) } }
   @ 3, 3 RADIO oRad VAR nOption PROMPT "This is option 1",;
              "This is option 2" OF oDlg //;
   //      ON CHANGE { || MsgInfo("This is option "+str(oRad:nOption,2)) } size 100, 10.45 UPDATE

   @ 5, 3 BUTTON oBtn1 PROMPT "&Change To Option 1"  OF oDlg SIZE 80,12 ACTION (changebutton(1,oRad))
   @ 6, 3 BUTTON oBtn2 PROMPT "C&hange To Option 2"  OF oDlg SIZE 80,12 ACTION (changebutton(2,oRad))
   @ 7, 3 BUTTON "&OK"  OF oDlg SIZE 80, 12 ACTION (oDlg:End())

   ACTIVATE DIALOG oDlg CENTERED

return nil

********************************************
function changebutton(buttontype,oRad)

if buttontype = 1
   oRad:nOption = 1
else
   oRad:nOption = 2
endif

   oRad:Refresh()
return nil
 

Regards.

[acwoo1]

Thanks

It Works

Regards

ACWoo
Using BCC582+Harbour+FWH1304

[nageswaragunupudi]

Is this not enough?

Code: Select all  Expand view

function testbutton

   local oDlg
   local nOption := 2
   local obtn1, obtn2
   local oRad

   DEFINE DIALOG oDlg FROM 0, 0 TO 34, 99 ;
          TITLE "Test RADIO BUTTON" ;
          GRADIENT { { 1, nRGB( 199, 216, 237 ), nRGB( 237, 242, 248 ) } }
   @ 3, 3 RADIO oRad VAR nOption PROMPT "This is option 1",;
              "This is option 2" OF oDlg

   @ 5, 3 BUTTON oBtn1 PROMPT "&Change To Option 1"  OF oDlg SIZE 80,12 ACTION ( nOption := 1, oRad:Refresh() )
   @ 6, 3 BUTTON oBtn2 PROMPT "C&hange To Option 2"  OF oDlg SIZE 80,12 ACTION ( nOption := 2, oRad:Refresh() )
   @ 7, 3 BUTTON "&OK"  OF oDlg SIZE 80, 12 ACTION (oDlg:End())

   ACTIVATE DIALOG oDlg CENTERED

return nil