FiveTech Software tech support forums

#include "FiveWin.ch"
#include "Report.ch"
static oWnd

//----------------------------------------------------------------------------//
function Main()
   DEFINE WINDOW oWnd FROM 1,1 To 22,75 TITLE "This is a MDI enviroment" MDI VSCROLL
   ACTIVATE WINDOW oWnd ON INIT CreateChild() MAXIMIZED
return nil

//----------------------------------------------------------------------------//
function CreateChild()
   local oWndC, oIcon, oDlg, bOk1, bOk2
   DEFINE ICON oIcon RESOURCE "test"
   DEFINE WINDOW oWndC NOMAXIMIZE MDICHILD OF oWnd FROM 0,0 TO 20,40 ICON oIcon
   oWndC:bGotFocus = {||oDlg:SetFocus()}          // Sempre coloca o foco no Dialog
   oWndC:SetColor(GetSysColor(8),GetSysColor(15)) // faz Cor da oWnd = oDlg
   DEFINE DIALOG oDlg OF oWndC STYLE WS_CHILD
   @ 0,0 BUTTON bOk1 PROMPT "&RPreview" SIZE 49,17 ACTION DoReport()
   @ 2,0 BUTTON bOk2 PROMPT "&Sair"     SIZE 49,17 ACTION oDlg:End()
   oWndC:Center()
   ACTIVATE DIALOG oDlg NOWAIT RESIZE16 VALID iif(!GetKeyState( 27 ), oWndC:End(), .F.)
   ACTIVATE WINDOW oWndC VALID MsgYesNo( "Want to close it ?" )
return nil

//----------------------------------------------------------------------------//
function DoReport()
   local oReport
   USE Customer
   INDEX ON Field->State+Field->City TO CustStCt
   SET INDEX TO CustStCt
   REPORT oReport ;
        TITLE "*** LISTADO DE PRUEBA ***","","FiveTech Software","" ;
        HEADER "Fecha: "+dtoc(date())+space(44)+"Hora:  "+time() ;
        FOOTER "P gina: "+str(oReport:nPage,3) PREVIEW
   GROUP ON Customer->State ;
        HEADER " " ;
        FOOTER "Total Estado "+oReport:aGroups[1]:cValue
   COLUMN TITLE "ST" ;
        DATA Customer->State
   COLUMN TITLE "City" ;
        DATA Customer->City ;
        SIZE 30
   COLUMN TITLE "First Name","Last Name" ;
        DATA Customer->First, Customer->Last ;
        SIZE 30
   COLUMN TITLE "   Salary" ;
        DATA Customer->Salary ;
        PICTURE "9,999,999" ;
        SIZE 9 ;
        TOTAL
   END REPORT
   ACTIVATE REPORT oReport ON STARTPAGE Tone( 100, 1 )
   USE
RETURN NIL