To Mr Rao

[Silvio.Falconi]

where I can found this test sample ?
http://forums.fivetechsupport.com/viewtopic.php?f=3&t=35626&hilit=xbrowse#p212105

[nageswaragunupudi]

Code: Select all  Expand view  RUN

#include "fivewin.ch"

function Main()

   local oDlg, oFont, oBrw

   USE CUSTOMER

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 500,400 PIXEL TRUEPIXEL FONT oFont

   @ 20,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE "CUSTOMER" ;
      COLUMNS "FIRST", "AGE", "SALARY" ;
      LINES NOBORDER

   WITH OBJECT oBrw
      :nRowHeight    := 30
      WITH OBJECT :Age
         :nWidth        := 100
         :nDataStrAlign := AL_CENTER
         :AddBitmap( { FW_BmpPlus(), FW_BmpMinus() } )

         // Right Button
         :nEditType     := EDIT_BUTTON
         :bEditBlock    := { |r,c,oCol| oCol:Value + 1 }
         :nBtnBmp       := 1
         :lBtnTransparent  := .t.

         // Left Button
         :bBmpData      := { |v,lSel| If( lSel, 2, 0 ) }
         :bBmpAction    := { |oCol| oCol:VarPut( oCol:Value - 1 ) }
      END

      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil
 

[Silvio.Falconi]

Thanks Mr Rao

[Silvio.Falconi]

Nages,
the first button is transparent , the second no , why ?

[nageswaragunupudi]

Do not change bBmpAction.

Use

Code: Select all  Expand view  RUN

bCalcRow := { || oBrw:aCols[ 5 ]:VarPut( oBrw:aCols[ 3 ]:Value * oBrw:aCols[ 4 ]:Value ) }
oBrw:aCols[ 3 ]:bOnChange := bCalcRow
oBrw:aCols[ 4 ]:bOnChange := bCalcRow
 

XBrowse recalculates totals automatically

[Silvio.Falconi]

ok but there is a problem


if I press - it can go to zero and then -1

How I can to insert MIN and Max as get spinner ?

[Silvio.Falconi]

I resolved with
:bBmpAction := { |oCol| IIF( oCol:Value>0,oCol:VarPut( oCol:Value - 1 ),) }