RBBTN Passing a parameter to popup menu

[betoncu]

Is it possible to pass a parameter to the popup menu which is changed dynamically during the run time.
See the example below. Changing the value of nNum has no effect.
Best regards,

Code: Select all  Expand view

#include "FiveWin.ch"
#include "Ribbon.ch"

function Main()
local oDlg, oBtn, nNum:=10

   DEFINE DIALOG oDlg FROM 5, 5 TO 15, 40 TITLE "Testing RBBTN Popup Menu"

   @ 1, 3 GET nNum OF oDlg PICTURE '9999'

   @ 30, 5 RBBTN oBtn OF oDlg POPUP ;
           SIZE 90,29 PIXEL ;
           PROMPT "Class TRBtn" ;
           MENU BuildPopup(nNum) ;  
           ROUND BORDER ;
           BITMAP "..\bitmaps\16x16\fivetech.bmp" LEFT

   ACTIVATE DIALOG oDlg CENTERED
return nil

function BuildPopup(nNum)
local oPopup
   MENU oPopup POPUP 2007
      MENUITEM "Multiply by 10" ACTION MsgInfo( nNum*10 )
      MENUITEM "Multiply by 20" ACTION MsgInfo( nNum*20 )
      MENUITEM "Multiply by 30" ACTION MsgInfo( nNum*30 )
   ENDMENU
return oPopup      
 

[Antonio Linares]

Birol,

Do it this way:

Code: Select all  Expand view

#include "FiveWin.ch"
#include "Ribbon.ch"

static nNum := 10

function Main()
local oDlg, oBtn

   DEFINE DIALOG oDlg FROM 5, 5 TO 15, 40 TITLE "Testing RBBTN Popup Menu"

   @ 1, 3 GET nNum OF oDlg PICTURE '9999'

   @ 30, 5 RBBTN oBtn OF oDlg POPUP ;
           SIZE 90,29 PIXEL ;
           PROMPT "Class TRBtn" ;
           MENU BuildPopup() ;  
           ROUND BORDER ;
           BITMAP "..\bitmaps\16x16\fivetech.bmp" LEFT

   ACTIVATE DIALOG oDlg CENTERED
return nil

function BuildPopup()
local oPopup
   MENU oPopup POPUP 2007
      MENUITEM "Multiply by 10" ACTION MsgInfo( nNum*10 )
      MENUITEM "Multiply by 20" ACTION MsgInfo( nNum*20 )
      MENUITEM "Multiply by 30" ACTION MsgInfo( nNum*30 )
   ENDMENU
return oPopup

[nageswaragunupudi]

Another way:

In the original sample, please change this line:

Code: Select all  Expand view

          MENU BuildPopup(nNum) ;  
 

as

Code: Select all  Expand view

          MENU { || BuildPopup(nNum) } ;  
 

Note: This works for versions later than 14.10

[betoncu]

Thanks for your kind help.