ButtonBmp problem with FWH2402

[richard-service]

Hi
I use FWH2212 working fine.
When use FWH2402 appear Chinese word does not display syntax command REDEFINE

Code: Select all  Expand view

             REDEFINE BUTTONBMP oBtn[1] ID 301 OF ::oDlg  ;
                      PROMPT "確 定"                      ;
                      TEXTRIGHT                           ;
                      BITMAP "BTN_Confirm24"              ;
                      ACTION ( lOK := .T. , ::oDlg:End() )

             REDEFINE BUTTONBMP oBtn[2] ID 302 OF ::oDlg  ;
                      PROMPT "取 消"                      ;
                      CANCEL                              ;
                      TEXTRIGHT                           ;
                      BITMAP "BTN_Cancel24"               ;
                      ACTION ( lOK := .F. , ::oDlg:End() )

             REDEFINE BUTTONBMP oBtn[3] ID 303 OF ::oDlg  ;
                      PROMPT "設 定"                      ;
                      TEXTRIGHT                           ;
                      BITMAP "BTN_SetPrinter24"           ;
                      ACTION PrinterSetup()
 

This working fine below:

Code: Select all  Expand view

      @ 103, 0  BUTTONBMP ::oBut[1] OF ::oDlg         ;
                SIZE 50, 16 PIXEL                     ;
                PROMPT "確定"                         ;
                RESOURCE "BTN_Confirm24"              ;
                TOOLTIP "選取日期"                    ;
                ACTION (::lOk := .T., ::oDlg:End() )  ;
                CANCEL                                ;
                TEXTRIGHT                

      @ 103, 50 BUTTONBMP ::oBut[2] OF ::oDlg         ;
                SIZE 50, 16 PIXEL                     ;
                PROMPT "取消"                         ;
                RESOURCE "BTN_Cancel24"               ;
                TOOLTIP "取消選取日期"                ;
                ACTION (::lOk := .F., ::oDlg:End() )  ;
                CANCEL                                ;
                TEXTRIGHT                
 

I use .dll file not rc or res.

[leandro]

Es el mismo error que tenemos
https://forums.fivetechsupport.com/viewtopic.php?f=6&t=44318&sid=7bd4e3993b0800df89ecbc1c1755eb9a

[richard-service]

Es el mismo error que tenemos
https://forums.fivetechsupport.com/viewtopic.php?f=6&t=44318&sid=98c33a2775e6398e51a63e334c34bf32

Yes, And very unstable.

This PROMPT empty space that only not show Chinese word

Code: Select all  Expand view

REDEFINE BUTTONBMP ....
PROMPT "取 消"
 

This PROMPT not empty space that crash my app

Code: Select all  Expand view

REDEFINE BUTTONBMP ....
PROMPT "取消"
 

[nageswaragunupudi]

Trying to reproduce the problem here
First sample from Source Code (not Resource)

Code: Select all  Expand view

#include "fivewin.ch"

function Main()

   local oDlg, oBtn, oFont

   FW_SetUnicode( .T. )
   SetBalloon( .t. )

   DEFINE FONT oFont NAME "Segoe UI" SIZE 0,-24
   DEFINE DIALOG oDlg SIZE 300,300 PIXEL TRUEPIXEL TITLE FWVERSION ;
      FONT oFont


     @  50,50  BUTTONBMP oBtn OF oDlg         ;
                SIZE 150, 50 PIXEL                     ;
                PROMPT "確定"                         ;
                TOOLTIP "選取日期"                    ;
                ACTION ( oDlg:End() )  ;
                CANCEL                                ;
                TEXTRIGHT                

      @ 150,50 BUTTONBMP oBtn OF oDlg         ;
                SIZE 150, 50 PIXEL                     ;
                PROMPT "取消"                         ;
                TOOLTIP "取消選取日期"                ;
                ACTION ( oDlg:End() )  ;
                CANCEL                                ;
                TEXTRIGHT                

   ACTIVATE DIALOG oDlg CENTERED

return nil
 

We do not see any problem here

[nageswaragunupudi]

We see a problem here
This is the problem faced by Mr. Leandro also.

RC file used by us for testing:

Code: Select all  Expand view

#include "..\include\winapi.ch"

#ifndef __64__
   1 24 ".\winxp\WindowsXP.Manifest"
#endif

#ifdef __64__
   1 24 "WinXP/WindowsXP.Manifest64"
#endif


test DIALOG 117, 94, 194, 119
STYLE DS_MODALFRAME | WS_POPUP | WS_VISIBLE | WS_CAPTION | WS_SYSMENU
CAPTION "XP theme aware Buttons Bitmap"
FONT 8, "MS Sans Serif"
{
 PUSHBUTTON "", 10, 13, 18, 20, 17
 DEFPUSHBUTTON "&OK", IDOK, 69, 95, 50, 16
 PUSHBUTTON "", 20, 13, 43, 120, 30
}
 

Test program in Chinese:

Code: Select all  Expand view

#include "FiveWin.ch"

//----------------------------------------------------------------------------//

function Main()

   local oDlg, oFont

   FW_SetUnicode( .T. )

   DEFINE FONT oFont NAME "Segoe UI" SIZE 0,-20
   DEFINE DIALOG oDlg RESOURCE "Test" TITLE FWVERSION FONT oFont

   REDEFINE BUTTONBMP ID 10 OF oDlg ;
      BITMAP "..\bitmaps\16x16\garrow.bmp"

   REDEFINE BUTTONBMP ID 20 OF oDlg ;
      BITMAP "..\bitmaps\32x32\paste.bmp" ;
      PROMPT "取 消" TEXTRIGHT

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil
 

Result:



Please give us sometime and we will get back to you with fix.

[nageswaragunupudi]

What is observed till now is that the misbehavior is when FW_SetUnicode( .T. )
Request Mr. Leandro to set FW_SetUnicode( .F. ) and retry
We will work on fixing this problem

[nageswaragunupudi]

This is working

Code: Select all  Expand view

#include "FiveWin.ch"

//----------------------------------------------------------------------------//

function Main()

   local oDlg, oFont, oBmp

   FW_SetUnicode( .f. )

   DEFINE FONT oFont NAME "Segoe UI" SIZE 0,-20
   DEFINE DIALOG oDlg RESOURCE "Test" TITLE FWVERSION FONT oFont

   REDEFINE BUTTONBMP ID 10 OF oDlg ;
      BITMAP "..\bitmaps\16x16\garrow.bmp"

   REDEFINE BUTTONBMP oBmp ID 20 OF oDlg ;
      BITMAP "..\bitmaps\32x32\paste.bmp" ;
      PROMPT "取 消" TEXTRIGHT
   oBmp:lUnicode := .t.

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

RC file

Code: Select all  Expand view

#include "..\include\winapi.ch"

#ifndef __64__
   1 24 ".\winxp\WindowsXP.Manifest"
#endif

#ifdef __64__
   1 24 "WinXP/WindowsXP.Manifest64"
#endif


test DIALOG 117, 94, 494, 119
STYLE DS_MODALFRAME | WS_POPUP | WS_VISIBLE | WS_CAPTION | WS_SYSMENU
CAPTION "XP theme aware Buttons Bitmap"
FONT 8, "MS Sans Serif"
{
 PUSHBUTTON "", 10, 13, 18, 20, 17
 DEFPUSHBUTTON "&OK", IDOK, 69, 95, 50, 16
 PUSHBUTTON "", 20, 13, 43, 420, 30
}
 

We will fix the issue and get back to you soon

[richard-service]

Trying to reproduce the problem here
First sample from Source Code (not Resource)

Code: Select all  Expand view

#include "fivewin.ch"

function Main()

   local oDlg, oBtn, oFont

   FW_SetUnicode( .T. )
   SetBalloon( .t. )

   DEFINE FONT oFont NAME "Segoe UI" SIZE 0,-24
   DEFINE DIALOG oDlg SIZE 300,300 PIXEL TRUEPIXEL TITLE FWVERSION ;
      FONT oFont


     @  50,50  BUTTONBMP oBtn OF oDlg         ;
                SIZE 150, 50 PIXEL                     ;
                PROMPT "確定"                         ;
                TOOLTIP "選取日期"                    ;
                ACTION ( oDlg:End() )  ;
                CANCEL                                ;
                TEXTRIGHT                

      @ 150,50 BUTTONBMP oBtn OF oDlg         ;
                SIZE 150, 50 PIXEL                     ;
                PROMPT "取消"                         ;
                TOOLTIP "取消選取日期"                ;
                ACTION ( oDlg:End() )  ;
                CANCEL                                ;
                TEXTRIGHT                

   ACTIVATE DIALOG oDlg CENTERED

return nil
 

We do not see any problem here

Yes, I know. I said no problem.

[richard-service]

This is working

Code: Select all  Expand view

#include "FiveWin.ch"

//----------------------------------------------------------------------------//

function Main()

   local oDlg, oFont, oBmp

   FW_SetUnicode( .f. )

   DEFINE FONT oFont NAME "Segoe UI" SIZE 0,-20
   DEFINE DIALOG oDlg RESOURCE "Test" TITLE FWVERSION FONT oFont

   REDEFINE BUTTONBMP ID 10 OF oDlg ;
      BITMAP "..\bitmaps\16x16\garrow.bmp"

   REDEFINE BUTTONBMP oBmp ID 20 OF oDlg ;
      BITMAP "..\bitmaps\32x32\paste.bmp" ;
      PROMPT "取 消" TEXTRIGHT
   oBmp:lUnicode := .t.

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

RC file

Code: Select all  Expand view

#include "..\include\winapi.ch"

#ifndef __64__
   1 24 ".\winxp\WindowsXP.Manifest"
#endif

#ifdef __64__
   1 24 "WinXP/WindowsXP.Manifest64"
#endif


test DIALOG 117, 94, 494, 119
STYLE DS_MODALFRAME | WS_POPUP | WS_VISIBLE | WS_CAPTION | WS_SYSMENU
CAPTION "XP theme aware Buttons Bitmap"
FONT 8, "MS Sans Serif"
{
 PUSHBUTTON "", 10, 13, 18, 20, 17
 DEFPUSHBUTTON "&OK", IDOK, 69, 95, 50, 16
 PUSHBUTTON "", 20, 13, 43, 420, 30
}
 

We will fix the issue and get back to you soon

Dear Mr.Rao

I just to test my code below:

Code: Select all  Expand view

FW_SetUnicode( .T. )
SET RESOURCES TO 'WinCrane365.dll'
......
   REDEFINE BUTTONBMP oBmp ID 20 OF oDlg ;
      BITMAP "..\bitmaps\32x32\paste.bmp" ;
      PROMPT "取 消" TEXTRIGHT
   
     oBmp:lUnicode := .t.
 

Add oBmp:lUnicode := .t. working find.
There's no way I could spend too much time adding this.

[Antonio Linares]

Dear Richard,

We are working to solve it asap

We apologize for these inconveniencies

[nageswaragunupudi]

Dear Richard,

We are working to solve it asap

We apologize for these inconveniencies

We do not expect you to do that.
We will provide an easy fix for you.

[nageswaragunupudi]

This problem appears only when both AppIsThemed() and FW_SetUnicode() is set to .T.
In all other cases it is working fine.

Now we request you to apply the following fix and let us know if everything is working fine.

Please open \fwh\source\classes\buttonb.prg

Please locate this method

Code: Select all  Expand view

METHOD ReDefine( nId, bAction, oWnd, nHelpId, cMsg,;
                 lUpdate, bWhen, bValid, cPrompt, lCancel, cBitmap, cPosText, cToolTip, lGDIP ) CLASS TButtonBmp

   DEFAULT cPrompt := "", cPosText := ::cPosDefault, lGDIP := .F.

   ::LoadBitmap( cBitmap )
   ::cPosText  = Upper( cPosText )
   ::cToolTip  = cToolTip
   ::lGDIP     = lGDIP

return ::Super:Redefine( nId, bAction, oWnd, nHelpId, cMsg, lUpdate, bWhen,;
                       bValid, cPrompt, lCancel )
 

Insert this line

Code: Select all  Expand view

::lUnicode  = oWnd:lUnicode

as indicted below:

Code: Select all  Expand view

METHOD ReDefine( nId, bAction, oWnd, nHelpId, cMsg,;
                 lUpdate, bWhen, bValid, cPrompt, lCancel, cBitmap, cPosText, cToolTip, lGDIP ) CLASS TButtonBmp

   DEFAULT cPrompt := "", cPosText := ::cPosDefault, lGDIP := .F.

   ::LoadBitmap( cBitmap )
   ::cPosText  = Upper( cPosText )
   ::cToolTip  = cToolTip
   ::lGDIP     = lGDIP
   ::lUnicode  = oWnd:lUnicode  // <-- INSERT THIS LINE HERE

return ::Super:Redefine( nId, bAction, oWnd, nHelpId, cMsg, lUpdate, bWhen,;
                       bValid, cPrompt, lCancel )
 

Please use this modified buttonb.prg and provide us your feedback.
Thank you both

[richard-service]

This problem appears only when both AppIsThemed() and FW_SetUnicode() is set to .T.
In all other cases it is working fine.

Now we request you to apply the following fix and let us know if everything is working fine.

Please open \fwh\source\classes\buttonb.prg

Please locate this method

Code: Select all  Expand view

METHOD ReDefine( nId, bAction, oWnd, nHelpId, cMsg,;
                 lUpdate, bWhen, bValid, cPrompt, lCancel, cBitmap, cPosText, cToolTip, lGDIP ) CLASS TButtonBmp

   DEFAULT cPrompt := "", cPosText := ::cPosDefault, lGDIP := .F.

   ::LoadBitmap( cBitmap )
   ::cPosText  = Upper( cPosText )
   ::cToolTip  = cToolTip
   ::lGDIP     = lGDIP

return ::Super:Redefine( nId, bAction, oWnd, nHelpId, cMsg, lUpdate, bWhen,;
                       bValid, cPrompt, lCancel )
 

Insert this line

Code: Select all  Expand view

::lUnicode  = oWnd:lUnicode

as indicted below:

Code: Select all  Expand view

METHOD ReDefine( nId, bAction, oWnd, nHelpId, cMsg,;
                 lUpdate, bWhen, bValid, cPrompt, lCancel, cBitmap, cPosText, cToolTip, lGDIP ) CLASS TButtonBmp

   DEFAULT cPrompt := "", cPosText := ::cPosDefault, lGDIP := .F.

   ::LoadBitmap( cBitmap )
   ::cPosText  = Upper( cPosText )
   ::cToolTip  = cToolTip
   ::lGDIP     = lGDIP
   ::lUnicode  = oWnd:lUnicode  // <-- INSERT THIS LINE HERE

return ::Super:Redefine( nId, bAction, oWnd, nHelpId, cMsg, lUpdate, bWhen,;
                       bValid, cPrompt, lCancel )
 

Please use this modified buttonb.prg and provide us your feedback.
Thank you both

Dear Mr.Rao

Now it's working.

[nageswaragunupudi]

Now it's working.

Glad to know.
Mr. Leandro
Can you too please test and provide your feedback?

[leandro]

Mr. Rao, Antonio gracias por responder

Antonio te molesto si me envías las libs con el ajuste que menciona Mr. Rao, ya que al agregar el buttonb.prg modificado al proyecto de fivedit, sale el siguiente error:

Code: Select all  Expand view

Turbo Incremental Link 6.97 Copyright (c) 1997-2022 Embarcadero Technologies, Inc.
Fatal: Unable to open file 'BUTTONB.OBJ'
Link Error
 

no hemos podido comprobar si es la solución , de antemano gracias