Cambiar icono carpeta desde codigo

[leandro]

Buenos días para todos

Estuve buscando en el foro pero no encontré respuesta, es que deseo cambiar el icono de la carpeta de contiene nuestra aplicación, lo hice de manera manual, pero quiero saber si es posible hacerlo desde código.

[Antonio Linares]

"Change Icon of EXE file through code extracting it from other EXE file | Go4Expert" https://www.go4expert.com/articles/chan ... ting-t643/

La clave es usar UpdateResource()

[nageswaragunupudi]

Code: Select all  Expand view  RUN

function SetFolderIcon( cFolder, cFileIco, cInfoTip )

   local lSet  := .f.
   local oIni, cIni, cSec := ".ShellClassInfo"

   cFolder  := RemRight( cFolder, "\" )
   DEFAULT cInfoTip := ""

   if File( cFileIco ) .and. Lower( cFileExt( cFileIco ) ) == "ico" .and. ;
      !File( cFolder )

      if !lIsDir( cFolder )
         lMkFullPath( cFolder )
      endif

      if lIsDir( cFolder )
         SetFAttr( cFolder, 4 )
         cFileIco := cRelativePath( cFileIco, cFolder )
         cIni     := cFolder + "\desktop.ini"
         INI oIni FILE cIni
         SET SECTION cSec ENTRY "ConfirmFileOp" TO 0        OF oIni
         SET SECTION cSec ENTRY "NoSharing"     TO 1        OF oIni
         SET SECTION cSec ENTRY "IconFile"      TO cFileIco OF oIni
         SET SECTION cSec ENTRY "IconIndex"     TO 0        OF oIni
         SET SECTION cSec ENTRY "InfoTip"       TO cInfoTip OF oIni
         SetFAttr( cIni, 2 )
         lSet  := .t.
      endif
   endif

return lSet

This function is included in the next version of FWH

Test:

Code: Select all  Expand view  RUN

? SetFolderIcon( "c:\fwh\icofolder", "c:\fwh\icons\fivetech.ico", "FWH SetFolderIcon() function" )

[leandro]

Excelente Mr.Nages

Era lo que estaba buscando. Muchas gracias.

[acuellar]

Buenas estimados

Y la función cRelativePath donde la encuentro?

[karinha]

Buenas estimados

Y la función cRelativePath donde la encuentro?

Borland shell32.lib


regards, saludos

[acuellar]

Gracias estimado Joao

Pero no está en en la Lib Shell32

[karinha]

Mira estimado:

http://forums.fivetechsoft.com/viewtopic.php?p=219133&sid=45f46e346cd14b3af0b2efd091e281f1#p219133

Regards, saludos.

[karinha]

Code: Select all  Expand view  RUN

// \samples\CRELATIV.PRG

#Include "FiveWin.ch"

FUNCTION Main()

   ? SetFolderIcon( "c:\FWH1905\icofolder", "c:\FWH1905\icons\fivetech.ico", ;
      "FWH SetFolderIcon() function" )

RETURN NIL

FUNCTION SetFolderIcon( cFolder, cFileIco, cInfoTip )

   local lSet  := .f.
   local oIni, cIni, cSec := ".ShellClassInfo"

   cFolder  := RemRight( cFolder, "\" )

   DEFAULT cInfoTip := ""

   IF FILE( cFileIco ) .AND. Lower( cFileExt( cFileIco ) ) == "ico" .AND. ;
      .NOT. FILE( cFolder )

      IF .NOT. lIsDir( cFolder )

         lMkFullPath( cFolder )

      ENDIF

      IF lIsDir( cFolder )

         SetFAttr( cFolder, 4 )

         cFileIco := cRelativePath( cFileIco, cFolder )
         cIni     := cFolder + "\desktop.ini"

         INI oIni FILE cIni
         SET SECTION cSec ENTRY "ConfirmFileOp" TO 0        OF oIni
         SET SECTION cSec ENTRY "NoSharing"     TO 1        OF oIni
         SET SECTION cSec ENTRY "IconFile"      TO cFileIco OF oIni
         SET SECTION cSec ENTRY "IconIndex"     TO 0        OF oIni
         SET SECTION cSec ENTRY "InfoTip"       TO cInfoTip OF oIni

         SetFAttr( cIni, 2 )

         lSet  := .t.

      ENDIF

   ENDIF

   ? cIni // ??

RETURN( lSet )

// FIN / END

Regards, saludos.

[acuellar]

Gracias Estimado

Tengo FWH 18.04

[nageswaragunupudi]

Buenas estimados

Y la función cRelativePath donde la encuentro?

You need to upgrade FWH

[nageswaragunupudi]

Buenas estimados

Y la función cRelativePath donde la encuentro?

You need to upgrade FWH

[acuellar]

Thanks Mr. Rao