Funciones de 32 bits omonimas de 16 bits (Funcky-2)

[JmGarcia]

Estoy tratando de pasar programas de 16 bits a 32 bits, y me encuentro con algunos problemas.
Entre ellos estas funciones de FUNCKY-II (16 bits):

Name: dec2hex() - convert decimal value to hexadecimal string
Usage: <string> = dec2hex(<integer>)
Params: an integer in the range 0 - 65535
Returns: a string containing the hexadecimal representation of
the integer passed.

Name: shr() - bitwise shift right of a number
Usage: shr(<int>,<number>)
Params: integer <int> - number to shift, not greater then 65535
integer <number> number of shifts, not greater than 255
Returns: integer equal to the bitwise shr of <int> and <number>

Name: feof() - see if the file pointer is at the end of file
Usage: <logical> = feof(<handle>)
Params: integer <handle> - handle from a previous fopen()
Returns: logical .T. if file pointer is at the beginning of the
file, .F. if it is not

Name: bin2num() - convert 16/8 bit binary string to integer
Usage: <integer> = bin2num(<binstr>)
Params: string <binstr> - a string of 16 or 8 ones and zeros
that form a binary byte or word.
A binary string has the format where a "1" signifies
that the bit is on, and "0" signifies bit is off:
"0001110000111100" or "00111001"
Returns: An integer equal to the decimal value of the binary
string that was sent.

Name: byte2bin() - convert byte value to 8 bit binary string
Usage: <string> = byte2bin(<integer>)
Params: an integer in the range of 0 - 255
Returns: a string filled with ones and zeros representing the
the bit settings that form the binary equivalent of the
integer sent

Name: and() - bitwise and of two numbers
Usage: <integer> = and(<int>,<number>)
Params: integer <int> - number to and, not greater then 65535
integer <number> number to and <int> with
Returns: integer equal to the bitwise and of <int> and <number>

Teniendo en cuenta que las Funcky 6.0 NO traen librerias ".LIB" (o no las he encontrado), como lo hago.
Es decir busco las omonimas en FW+xHARBOUR pero de 32 bits.
Gracias.

[Antonio Linares]

>
Name: dec2hex() - convert decimal value to hexadecimal string
Usage: <string> = dec2hex(<integer>)
>

Puedes usar DecToHex() de FWH. Funciona igual.

>
Name: shr() - bitwise shift right of a number
Usage: shr(<int>,<number>)
Params: integer <int> - number to shift, not greater then 65535
integer <number> number of shifts, not greater than 255
Returns: integer equal to the bitwise shr of <int> and <number>
>

Code: Select all  Expand view  RUN

HB_FUNC( SHR )
{
   unsigned int ui = hb_parnl( 1 );
   unsigned char uc = hb_parnl( 2 );

   hb_retnl( ui >>= uc );
}


>
Name: feof() - see if the file pointer is at the end of file
Usage: <logical> = feof(<handle>)
>

Code: Select all  Expand view  RUN

function feof( nHandle )
   local lEof := ( fseek( nHandle, 1, FS_RELATIVE ) == fseek( nHandle, 0, FS_RELATIVE ) )

   if ! lEof
      fseek( nHandle, -1, FS_RELATIVE )
   endif

return lEof


>
Name: bin2num() - convert 16/8 bit binary string to integer
Usage: <integer> = bin2num(<binstr>)
>

Code: Select all  Expand view  RUN

function bin2num( cBinStr )

   local n := 1, nResult := 0

   for n = 1 to Len( cBinStr )
      if SubStr( cBinStr, Len( cBinStr ) - n + 1, 1 ) == "1"
         nResult += ( 2 ^ ( n - 1 ) )
      endif
   next

return Int( nResult )


>
Name: byte2bin() - convert byte value to 8 bit binary string
Usage: <string> = byte2bin(<integer>)
>

Code: Select all  Expand view  RUN

function Byte2Bin( nValue )

   local cResult := "", n := 7

   while n >= 0
      if Int( nValue / ( 2 ^ n ) ) != 0
         cResult += "1"
         nValue -= Int( nValue / ( 2 ^ n ) ) * ( 2 ^ n )
      else
         cResult += "0"
      endif
      n--
   end

return cResult


>
Name: and() - bitwise and of two numbers
Usage: <integer> = and(<int>,<number>)
>
Puedes usar nAnd() de FWH. Funciona igual.

OJO: No he probado estas funciones, las he escrito sobre la marcha, pruébalas y asegúrate de que funcionen bien

[JmGarcia]

Y como seria esta funcion:

Name: freadline() - read in one line from a file
Usage: <string> = freadline(<handle>,[<linelen>])
Params: integer <handle> from a previous fopen() or fcreate()
integer <linelen> - maximum line length to read in, if not
specified than the default is a maximum length of 512.
Returns: a string filled with one line of text

[Antonio Linares]

No la he probado, pero debería funcionar

Code: Select all  Expand view  RUN

function freadline( nHandle, nLineLen )

   local cBuffer, nBytes, nAt

   DEFAULT nLineLen := 512

   cBuffer := Space( nLineLen )
   nBytes = FRead( nHandle, @cBuffer, nLineLen )
   nAt = At( Chr( 13 ) + Chr( 10 ), cBuffer )
   if nAt != 0
      FSeek( nHandle, -( nBytes - nAt + 2 ), FS_RELATIVE )
   endif

return If( nAt != 0, SubStr( cBuffer, 1, nAt - 1 ), SubStr( cBuffer, 1, nBytes ) )


[JmGarcia]

Gracias Antonio.
Ya me puedo despedir de las LIB de Funcky, en desarrollos de 32bits.

[JmGarcia]

Al compilar esta funcion con BCC551+FWH75+Make030

Code: Select all  Expand view  RUN

HB_FUNC( SHR )
{ // Esta es la linea 1175
   unsigned int ui = hb_parnl( 1 );
   unsigned char uc = hb_parnl( 2 );
   hb_retnl( ui >>= uc );
} // Esta es la linea 1179


Me da este error:
E:\Bases\Practicas\InyectaS.prg(1175) Error E0020 Incomplete statement or unbalanced delimiters
E:\Bases\Practicas\InyectaS.prg(1179) Error E0030 Syntax error: "parse error at 'INT'"




Esta otra funcion siempre me da TRUE, es decir FIN DE FICHERO

Code: Select all  Expand view  RUN

function feof( nHandle )
   local lEof := ( fseek( nHandle, 1, FS_RELATIVE ) == fseek( nHandle, 0, FS_RELATIVE ) )
   if ! lEof
      fseek( nHandle, -1, FS_RELATIVE )
   endif
return lEof


Me he "inventado" esta (y voy tirando) y me funciona, pero si se arregla la de arriba mejor:

Code: Select all  Expand view  RUN

function feof( nHandle )
   local BLOCK_SIZE := 1 // 1 o lo que sea mayor de 0 (cero)
   LOCAL cBuffer    := Space( BLOCK_SIZE )
   LOCAL nRead      := 0
   local lEof       := .T.
   nRead := FRead( nHandle, @cBuffer, BLOCK_SIZE )
   IF nRead == BLOCK_SIZE
      fseek( nHandle, -BLOCK_SIZE, FS_RELATIVE )
      lEof:= .F.
   ELSE
      lEof:= .T.
   ENDIF
return lEof

En realidad quiero que sea haga lo mismo que la de FuncKy:
Name: feof() - see if the file pointer is at the end of file
Usage: <logical> = feof(<handle>)
Params: integer <handle> - handle from a previous fopen()
Returns: logical .T. if file pointer is at the beginning of the
file, .F. if it is not

[JmGarcia]

La funcion LASTDAY de Funcky cual es la de FWH.

Name: lastday() - get the last day in a month
Usage: <integer> = lastday(<date>)
Params: <date> - a date type variable
Returns: an integer equal to the last day in the month specified
by the date variable.

[Armando]

JmGarcía:

Te servirá EOM(Date()) de xHarbour ?

Saludos

[mmercado]

La funcion LASTDAY de Funcky cual es la de FWH.

Code: Select all  Expand view  RUN

Function LastDay( dDate, dLast ) // dLast solo para ahorrar definiciones
Return ( dLast := If( dDate == Nil, Date(), dDate ) + If( Month( dDate + 28 ) == Month( dDate ), 31, 28 ) ) - Day( dLast )

Saludos

Manuel Mercado

[Biel EA6DD]

Bonita implementacion la de Manuel, yo tengo una funcion parecida, aunque haciendo honor a la verdad, la de Manuel queda mas corta y elegante.
Para ser igual que la de funcky, debiera devolver day( dlasta:= ... ).
Y prevenir el pase de nil, que se tiene en cuenta con dLast, pero no con dDate, y produciria un error en ejecución.

Otra función alternativa seria en lugar de sumar dias, montar la fecha de dia 1 del mes siguiente, y restarle un dia, algo así.

Code: Select all  Expand view  RUN

FUNCTION LastDay(dDate)
   DEFAULT dDate:=Date()
RETURN IF(Day(dDate:=StoD(Str(Year(dDate),4)+PadL(lTrim(Str(Month(dDate)+1)),2,'0')+'01')-1)==0,31,Day(dDate))

[Antonio Linares]

Jose Maria,

Te respondo con mucho retraso, pero es cuando he visto el mensaje (a veces se me pasan mensajes

>
E:\Bases\Practicas\InyectaS.prg(1175) Error E0020 Incomplete statement or unbalanced delimiters
E:\Bases\Practicas\InyectaS.prg(1179) Error E0030 Syntax error: "parse error at 'INT'"
>

Tienes que usar ese código desde C incluyendo #include <hbapi.h> ó desde un PRG usando #pragma BEGINDUMP y #pragma ENDDUMP y tambien usando ese include.

[mmercado]

Para ser igual que la de funcky, debiera devolver day( dlasta:= ... ).

Hola Biel:

Lo pensé pero según mi experiencia tiene más uso como variable de fecha que como día del mes. Además creo que el nombre de la función quedaría mejor como dFinalMes() o dMonthEnd()

Y prevenir el pase de nil, que se tiene en cuenta con dLast, pero no con dDate, y produciria un error en ejecución.

Si observas bien, verás que también traté de considerarlo pero no escribí adecuadamente la expresión (con dDate = Nil asume la fecha del sistema), también te darás cuenta que la acabo de inventar.

Aquí está ya correctamente escrita:

Code: Select all  Expand view  RUN

Function dFinalMes( dDate, dLast )
Return ( dLast := ( dDate := If( dDate == Nil, Date(), dDate ) ) + If( Month( dDate + 28 ) == Month( dDate ), 31, 28 ) ) - Day( dLast )

Un abrazo.

Manuel Mercado

[JmGarcia]

Mmercado y Biel muchas gracias.

¿ Hemos considerado los años bisiestos ?

La función la necesito para poner la fecha interna del S.O.Solaris (SUN) que es en formato de 4 octetos, esa que empieza el 01/01/1987.

Así la cifra 1211636418 es 24/05/2008 13:40:18

Gracias de nuevo.

[Biel EA6DD]

Hola Manuel,
con este último cambio queda perfecta.

JM, ambas funciones tienen en cuenta los bisisestos.

[George]

Pregunta sobre codigo C implementado en [x]Harbour

Antonio Linares escribio:

Jose Maria,
Te respondo con mucho retraso, pero es cuando he visto el mensaje (a veces se me pasan mensajes
>
E:\Bases\Practicas\InyectaS.prg(1175) Error E0020 Incomplete statement or unbalanced delimiters
E:\Bases\Practicas\InyectaS.prg(1179) Error E0030 Syntax error: "parse error at 'INT'"
>
Tienes que usar ese código desde C incluyendo #include <hbapi.h> ó desde un PRG usando #pragma BEGINDUMP y #pragma ENDDUMP y tambien usando ese include.

Que diferencia hay entre usar codigo C en un archivo externo y usarlo dentro de un PRG?
Cual de los dos se ejecuta mas rapido?

George