OUTLOOK 2003 Y XBROWSE

[FRANCISDAX]

hola a todos del foro

Tengo una ventana mdi, y quiero que dentro de una mdichild tenga el outlook2003 y a la derecha un xbrowse se puede?

Aqui extracto del codigo

Code: Select all  Expand view

FUNCTION MantCentCosto( oVentana, oMenuItem, cCod )
  LOCAL oWChild, oBar, oBrw, oFont, oCursor, oIcon
  LOCAL lSalir := .F., oBrush
  local oOutLook2003, oStatusBar, oSplit, cCombo, oRad, nValue := 1

  cAliUsu := AbreDbf( "CKUSUARI" )
  ( cAliUsu )->( DBSetOrder( "CODIGO" ) )

  IF ( cAliUsu )->( DBSeek( cCod ) )
    IF !( cAliUsu )->USEM16
      __StopMsg("Usuario no tiene permiso para ingresar a este M¢dulo ...")
      CierraDbf( "CKUSUARI", cAliUsu )
      RETURN( .T. )
    ENDIF
  ELSE
    CierraDbf( "CKUSUARI", cAliUsu )
    RETURN( .T. )
  ENDIF
  CierraDbf( "CKUSUARI", cAliUsu )

  DEFINE FONT oFont NAME "Ms Sans Serif" SIZE 0, -05
  DEFINE ICON oIcon RESOURCE "FWCIBCONT"
  DEFINE CURSOR oCursor RESOURCE "Mano"
  DEFINE BRUSH oBrush NAME "GRADIEN"

  CursorWait()

  cAliCos := AbreDbf( "T10REF09" )
  ( cAliCos )->( DBSetOrder( "CODIGO" ) )
  ( cAliCoS )->( DBGoTop() )

  oMenuItem:Disable()

  DEFINE WINDOW oWChild;
         TITLE OToA( "Gesti¢n de Centros de Costo" );
         MDICHILD;
         ICON oIcon;
         OF oVentana

  SET FONT OF oWChild TO oFont

/*  DEFINE SBUTTONBAR oBar;
         OF oWChild;
         SIZE 80,60;
         3D;
         CURSOR oCursor CRYSTAL

         DEFINE SBUTTON NAME "NEWDOC";
                GROUP;
                PROMPT "NUEVO";
                TEXT ON_BOTTOM;
                OF oBar;
                TOOLTIP "Nuevo Costo";
                ACTION( MCLICK(), AMCosto( oBrw, .T., cAliCos ),;
                        oBrw:Refresh() )

         DEFINE SBUTTON NAME "WRITE";
                OF oBar;
                PROMPT "MODIFICA";
                TEXT ON_BOTTOM;
                TOOLTIP "Modifica Costo";
                ACTION( MCLICK(), AMCosto( oBrw, .F., cAliCos ),;
                        oBrw:Refresh() )

         DEFINE SBUTTON NAME "STOP";
                OF oBar;
                PROMPT "ELIMINA";
                TEXT ON_BOTTOM;
                TOOLTIP "Borra Costo";
                ACTION( MCLICK(), BorrCosto( "este Centro de Costo" ),;
                        oBrw:Refresh() )

         DEFINE SBUTTON NAME "PRINT";
                GROUP;
                PROMPT "IMPRIME";
                TEXT ON_BOTTOM;
                OF oBar;
                TOOLTIP "Imprimir";
                ACTION( MCLICK(), PrintCCos(), oBrw:Refresh() )

         DEFINE SBUTTON NAME "DOOR";
                GROUP;
                OF oBar;
                PROMPT "SALIR";
                TEXT ON_BOTTOM;
                TOOLTIP "Salir de esta ventana";
                ACTION( MCLICK(), oMenuItem:Enable(),;
                        lSalir := .T., oWChild:End() )

  oBar:brClicked:= { || NIL } */
  DEFINE OUTLOOK2003 oOutLook2003 OF oWChild;
         PROMPTS "Centros de Costo", "Calendario", "Otros";
         BITMAPS "..\bitmaps\mail.bmp", "..\bitmaps\calendar.bmp", "..\bitmaps\notes.bmp"

         oWChild:oLeft = NIL
         
  @ 1, 2 BUTTON "Nuevo Costo" OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION ( MCLICK(), AMCosto( oBrw, .T., cAliCos ), oBrw:Refresh() )
 
  @ 3, 2 BUTTON "Edita Costo" OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION ( MCLICK(), AMCosto( oBrw, .F., cAliCos ), oBrw:Refresh() )

  @ 5, 2 BUTTON "Borra Costo" OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION ( MCLICK(), BorrCosto( "este Centro de Costo" ), oBrw:Refresh() )
   
  @ 7, 2 BUTTON "Salir"       OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION ( MCLICK(), oMenuItem:Enable(), lSalir := .T., oWChild:End() )  
 
  *@ 00, 00 XBROWSE oBrw;
  *         FIELDS ( cAliCos )->COSTCOD, ( cAliCos )->COSTNOB;
  *         HEADERS OToA(" C¢digo "), OToA(" Descripci¢n ");
  *         SIZE 00, 00 COLOR CLR_BLACK, RGB( 200,200,200 ) ;
  *         UPDATE OF ( oWChild:oWndClient );
  *         ON LEFT DBLCLICK( MCLICK(), AMCosto( oBrw, .F., cAliCos ),;
  *                           oBrw:Refresh() )

           oBrw := TXBrowse():New( oWChild:oWndClient )
           
           WITH OBJECT oBrw
            :bKeyDown := { | nKey, nFlags | ;
                              IIF( nKey == 13,; // [Enter]
                                   ( MCLICK(), AMCosto( oBrw, .F., cAliCos ) ),;
                              IIF( nKey == 46,; // [DEL]
                                   ( MCLICK(), BorrCosto( "este Centro de Costo " ) ),;
                              IIF( nKey == ASC("N") .AND. GetKeyState( VK_CONTROL ),; // [CTRL+N]
                                   ( MCLICK(), AMCosto( oBrw, .T., cAliCos ) ),;
                              IIF( nKey == ASC("M") .AND. GetKeyState( VK_CONTROL ),; // [CTRL+M]
                                   ( MCLICK(), AMCosto( oBrw, .F., cAliCos ) ),;
                              IIF( nKey == ASC("P") .AND. GetKeyState( VK_CONTROL ),; // [CTRL+P]
                                   ( MCLICK(), PrintCCos() ),;
                              IIF( nKey == ASC("S") .AND. GetKeyState( VK_CONTROL ),; // [CTRL+S]
                                   ( MCLICK(), oMenuItem:Enable(), lSalir := .T., oWChild:End() ), ) ) ) ) ) ) }
           END

           WITH OBJECT oBrw
             :cAlias     := cAliCos
             :bClrHeader := { || { 65535, 0  } }
             :nHeaderHeight := 35
             :SetRdd()
             :SetBackGround( oBrush )
             :lRecordSelector := .F.
             :nStretchCol := STRETCHCOL_LAST
             :nMarqueeStyle := MARQSTYLE_HIGHLROW
             :CreateFromCode()            
           END
           *oWChild:SetControl( oBrw )
           
  SetParent( oOutLook2003:hWnd, oWChild:hWnd )
   
  oWChild:oClient = NIL
   
  @ 0, 191 SPLITTER oSplit ;
       VERTICAL _3DLOOK ;
       PREVIOUS CONTROLS oOutLook2003 ;
       HINDS CONTROLS oWChild:oWndClient, oBrw;
       SIZE 4, oWChild:nHeight - 70 PIXEL ;
       OF oWChild

  SetParent( oSplit:hWnd, oWChild:hWnd )


  ACTIVATE WINDOW oWChild;
           ON RESIZE ( oSplit:Adjust(),;
                       WndLeft( oWChild:oWndClient:hWnd, oSplit:nRight + 1 ),;
                       WndWidth( oWChild:oWndClient:hWnd, oWChild:nWidth - oOutLook2003:nWidth + 80 ) ) ;
           VALID( CierraDbf( "T10REF09", cAliCos ), lSalir )
     
*  ACTIVATE WINDOW oWChild;
*           VALID( CierraDbf( "T10REF09", cAliCos ), lSalir )

  RELEASE FONT oFont

RETURN( .T. )

 

No se como ponerle el xbrowse a la derecha de la ventana hija ...

Salu2

Francis

[joseluisysturiz]

Esto lo hago con una texplorer a la izquierda y un xbrowse a la derecha, espero te sirva...saludos..

Code: Select all  Expand view

      @ 00, 201 SPLITTER oSplitV VERTICAL ;
         PREVIOUS CONTROLS oExpBar ;
         HINDS CONTROLS oBrow ;
         SIZE 1, oWndCon:nHeight PIXEL ;
         OF oWndCon ;
         3DLOOK UPDATE

      oSplitV:lStatic := .t. // PARA QUE ES SPLITER NO SE MUEVA POR EL USUARIO

      oBrow:SetFocus()

      ACTIVATE WINDOW oWndCon MAXIMIZED ;
         ON RESIZE( oExpBar:AdjLeft(), oSplitV:AdjClient(), oSplitV:AdjRight() ) ;
         VALID( oWndCon := NIL, .t. )
 

[MarioG]

Francis;
va un sample:

Code: Select all  Expand view

  DEFINE WINDOW soWnd0 ;
          TITLE  "..." ;
          ICON   aO[_Ico] COLOR CLR_BLACK,CLR_BLACK ;
          NOMAXIMIZE ;
          FROM   2000,5 TO 2001,5 ;
          MENU   BuildMenu()

   // Barra Tipo Outlook
   DEFINE OUTLOOK2003 aO[_OL2003] OF soWnd0 ;
          PROMPTS "Transferencias" ;
          BITMAPS "bmp_iGO24"

   @ 0, 0 EXPLORERBAR aO[_ExpBar1] OF aO[_OL2003]:aDialogs[ 1 ]
   aO[_Panel1] = aO[_ExpBar1]:AddPanel( "Transferencias", "bmp_iGO24", 120 )
   aO[_Panel1]:lSpecial = .f.
   aO[_Panel1]:AddLink( "Historico",  {|| oConxFTP:BrwHisLog() ), ) }, "bmp_ShowHis" )      // ACCESO AL XBROWSE en el margen derecho del Splitter

   // Salir
   @ 110, 25 BTNBMP PROMPT "Salir" OF aO[_Panel1] SIZE 100, 30 CENTER NOBORDER 2007 ;
             ACTION soWnd0:End()

   // Splitter - CON ESTO DIVIDO LA VENTANA
   soDlg:= nil
   soBrw:= nil
   @ 0, 191 SPLITTER soSplit ;
            VERTICAL _3DLOOK ;
            PREVIOUS CONTROLS aO[_OL2003] ;
            HINDS CONTROLS soDlg, soBrw ;
            SIZE 3, soWnd0:nHeight PIXEL ;
            OF soWnd0
   soSplit:lStatic:= TRUE                    // Inmobiliza Splitter

   ACTIVATE WINDOW soWnd0 ON INIT soWnd0:Center()
 

[FRANCISDAX]

Muchas gracias por responder amigos.

Cuando es una ventana principal no tengo problemas, el problema es cuando es ventanas hijas de la ventana principal... Probare y les comento amigos.

[FRANCISDAX]

Con este codigo del ejemplo funciona bien porque es una ventana principal.

Code: Select all  Expand view

// FWH Class TOutLook2003

#include "FiveWin.ch"
#include "Splitter.ch"

static lExit := .F., CTAS, oWnd

//----------------------------------------------------------------------------//

function Main()

   local oWnd, oOutLook2003, oStatusBar, oSplit, cCombo, oRad, nValue := 1
   local oFont, oLbx, oTaskPanel

   DEFINE WINDOW oWnd TITLE "FWH new Class TOutLook2003" MDI;
      MENU BuildMenu()

   DEFINE OUTLOOK2003 oOutLook2003 OF oWnd ;
      PROMPTS "Cuentas Contables", "Calendario", "Contactos", "" ;
      BITMAPS "..\bitmaps\mail.bmp", "..\bitmaps\calendar.bmp", "..\bitmaps\notes.bmp"

   oWnd:oLeft = nil // Because the splitter is going to control the resize  

   @ 1, 2 BUTTON "Nueva Cuenta" OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION MsgInfo( "Search" ) //AMPCta( oBrw, .T., cTmp, CTAS ) //BuildDlg()

   @ 3, 2 BUTTON "Edita Cuenta" OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION MsgInfo( "Search" ) //AMPCta( oBrw, .F., cTmp, CTAS )

   @ 5, 2 BUTTON "Busca Cuenta" OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION MsgInfo( "Search" )  
   
   @ 7, 2 BUTTON "Salir"        OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION oWnd:End()
   
   @ 1, 1 COMBOBOX cCombo ITEMS { "January", "February", "March", "April", "May" } ;
      OF oOutLook2003:aDialogs[ 2 ] SIZE 170, 100
   
   DEFINE FONT oFont NAME "Arial" SIZE 0, -10
   
   @ 12, 10 SAY Date() OF oOutLook2003:aDialogs[ 2 ] SIZE 80, 20 FONT oFont
   
   @ 3, 1 RADIO oRad VAR nValue OF oOutLook2003:aDialogs[ 2 ] ;
      ITEMS "&Day", "&Week", "&Month" SIZE 100, 20
     
   oRad:SetFont( oFont )  

   USE M10PCTA ALIAS CTAS
   oLbx := TXBrowse():New(oWnd:oWndClient)   // AQUI SE INSERTA AL LADO DERECHO DE LA VENTANA SIN PROBLEMAS
   oLbx:lRecordSelector     := .F.
   oLbx:cALias              := "CTAS"
   oLbx:lHeader             := .T.
   oLbx:nTop                := 2
   oLbx:nLeft               := 3
   oLbx:nBottom             := 295
   oLbx:nRight              := 186
   oLbx:nHeaderLines        := 2
   oLbx:CreateFromCode()  

   #ifndef __CLIPPER__
      DEFINE STATUSBAR oStatusBar PROMPT "  FWH Class TOutLook2003" OF oWnd
   #else  
      DEFINE MESSAGE oStatusBar PROMPT "  FWH Class TOutLook2003" OF oWnd
   #endif  

   SetParent( oOutLook2003:hWnd, oWnd:hWnd )
   
   oWnd:oClient = nil
   
   @ 0, 191 SPLITTER oSplit ;
      VERTICAL _3DLOOK ;
      PREVIOUS CONTROLS oOutLook2003 ;
      HINDS CONTROLS oLbx;
      SIZE 4, oWnd:nHeight - 70 PIXEL ;
      OF oWnd

   SetParent( oSplit:hWnd, oWnd:hWnd )

   ACTIVATE WINDOW oWnd ;
      ON RESIZE ( oSplit:Adjust(),;
                  WndLeft( oWnd:oWndClient:hWnd, oSplit:nRight + 1 ),;
                  WndWidth( oWnd:oWndClient:hWnd, oWnd:nWidth - oOutLook2003:nWidth + 80 ) ) ;
      VALID lExit := .T.

return nil

//----------------------------------------------------------------------------//

function BuildMenu()

   local oMenu
   
   MENU oMenu
      MENUITEM "&One"
      MENUITEM "&Two"
      MENUITEM "&Salir" ACTION oWnd:End()
   ENDMENU
   
return oMenu  

//----------------------------------------------------------------------------//

function BuildDlg()

   local oDlg, oOutL2003
   
   DEFINE DIALOG oDlg RESOURCE "Test"
   
   REDEFINE OUTLOOK2003 oOutL2003 ID 110 OF oDlg ;
      PROMPTS "Uno", "Dos", "Tres" ;
      BITMAPS "..\bitmaps\mail.bmp", "..\bitmaps\calendar.bmp", "..\bitmaps\notes.bmp" ;
      DIALOGS "Page1", "Page2", "Page3"

   REDEFINE BUTTON ID 110 OF oOutL2003:aDialogs[ 1 ] ACTION MsgInfo( "Click" )
     
   ACTIVATE DIALOG oDlg CENTERED
   
return nil      

//----------------------------------------------------------------------------//

function WinRun()

   while NoGPF()
      if lExit
         PostQuitMessage( 0 )
      endif  
   end
   
return nil        

//----------------------------------------------------------------------------//

#pragma BEGINDUMP

#include <windows.h>
#include <hbapi.h>

BOOL SysRefresh( void );

HB_FUNC( NOGPF )
{
   __try
   {
      hb_retl( SysRefresh() );
   }
   __except ( ( hb_retl( TRUE ), TRUE ) )
   {}
}

#pragma ENDDUMP  
 

Pero cuendo es una ventana hija de la principal no puedo colocar el xbrowse al lado derecho de la ventana hija.

Code: Select all  Expand view

FUNCTION MantCentCosto( oVentana, oMenuItem, cCod )
  LOCAL oWChild, oBar, oBrw, oFont, oCursor, oIcon
  LOCAL lSalir := .F., oBrush
  local oOutLook2003, oStatusBar, oSplit, cCombo, oRad, nValue := 1

  cAliUsu := AbreDbf( "CKUSUARI" )
  ( cAliUsu )->( DBSetOrder( "CODIGO" ) )

  IF ( cAliUsu )->( DBSeek( cCod ) )
    IF !( cAliUsu )->USEM16
      __StopMsg("Usuario no tiene permiso para ingresar a este M¢dulo ...")
      CierraDbf( "CKUSUARI", cAliUsu )
      RETURN( .T. )
    ENDIF
  ELSE
    CierraDbf( "CKUSUARI", cAliUsu )
    RETURN( .T. )
  ENDIF
  CierraDbf( "CKUSUARI", cAliUsu )

  DEFINE FONT oFont NAME "Ms Sans Serif" SIZE 0, -05
  DEFINE ICON oIcon RESOURCE "FWCIBCONT"
  DEFINE CURSOR oCursor RESOURCE "Mano"
  DEFINE BRUSH oBrush NAME "GRADIEN"

  CursorWait()

  cAliCos := AbreDbf( "T10REF09" )
  ( cAliCos )->( DBSetOrder( "CODIGO" ) )
  ( cAliCoS )->( DBGoTop() )

  oMenuItem:Disable()

  DEFINE WINDOW oWChild;
         TITLE OToA( "Gesti¢n de Centros de Costo" );
         MDICHILD;
         ICON oIcon;
         OF oVentana

  SET FONT OF oWChild TO oFont

 DEFINE OUTLOOK2003 oOutLook2003 OF oWChild;
         PROMPTS "Centros de Costo", "Calendario", "Otros";
         BITMAPS "..\bitmaps\mail.bmp", "..\bitmaps\calendar.bmp", "..\bitmaps\notes.bmp"

         oWChild:oLeft = NIL
         
  @ 1, 2 BUTTON "Nuevo Costo" OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION ( MCLICK(), AMCosto( oBrw, .T., cAliCos ), oBrw:Refresh() )
 
  @ 3, 2 BUTTON "Edita Costo" OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION ( MCLICK(), AMCosto( oBrw, .F., cAliCos ), oBrw:Refresh() )

  @ 5, 2 BUTTON "Borra Costo" OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION ( MCLICK(), BorrCosto( "este Centro de Costo" ), oBrw:Refresh() )
   
  @ 7, 2 BUTTON "Salir"       OF oOutLook2003:aDialogs[ 1 ] SIZE 80, 22 ACTION ( MCLICK(), oMenuItem:Enable(), lSalir := .T., oWChild:End() )  
 
           oBrw := TXBrowse():New( oWChild:oWndClient )
           
           WITH OBJECT oBrw
            :bKeyDown := { | nKey, nFlags | ;
                              IIF( nKey == 13,; // [Enter]
                                   ( MCLICK(), AMCosto( oBrw, .F., cAliCos ) ),;
                              IIF( nKey == 46,; // [DEL]
                                   ( MCLICK(), BorrCosto( "este Centro de Costo " ) ),;
                              IIF( nKey == ASC("N") .AND. GetKeyState( VK_CONTROL ),; // [CTRL+N]
                                   ( MCLICK(), AMCosto( oBrw, .T., cAliCos ) ),;
                              IIF( nKey == ASC("M") .AND. GetKeyState( VK_CONTROL ),; // [CTRL+M]
                                   ( MCLICK(), AMCosto( oBrw, .F., cAliCos ) ),;
                              IIF( nKey == ASC("P") .AND. GetKeyState( VK_CONTROL ),; // [CTRL+P]
                                   ( MCLICK(), PrintCCos() ),;
                              IIF( nKey == ASC("S") .AND. GetKeyState( VK_CONTROL ),; // [CTRL+S]
                                   ( MCLICK(), oMenuItem:Enable(), lSalir := .T., oWChild:End() ), ) ) ) ) ) ) }
           END

           WITH OBJECT oBrw
             :cAlias     := cAliCos
             :bClrHeader := { || { 65535, 0  } }
             :nHeaderHeight := 35
             :SetRdd()
             :SetBackGround( oBrush )
             :lRecordSelector := .F.
             :nStretchCol := STRETCHCOL_LAST
             :nMarqueeStyle := MARQSTYLE_HIGHLROW
             :CreateFromCode()            
           END
           
  SetParent( oOutLook2003:hWnd, oWChild:hWnd )
   
  oWChild:oClient = NIL
   
  @ 0, 191 SPLITTER oSplit ;
       VERTICAL _3DLOOK ;
       PREVIOUS CONTROLS oOutLook2003 ;
       HINDS CONTROLS oBrw;
       SIZE 4, oWChild:nHeight - 70 PIXEL ;
       OF oWChild

  SetParent( oSplit:hWnd, oWChild:hWnd )


  ACTIVATE WINDOW oWChild;
           ON RESIZE ( oSplit:Adjust(),;
                       WndLeft( oWChild:oWndClient:hWnd, oSplit:nRight + 1 ),;
                       WndWidth( oWChild:oWndClient:hWnd, oWChild:nWidth - oOutLook2003:nWidth + 80 ) ) ;
           VALID( CierraDbf( "T10REF09", cAliCos ), lSalir )
     
  RELEASE FONT oFont

RETURN( .T. )

//----------------------------------------------------------------------------//
 

[joseluisysturiz]

El ejemplo que te envie es con ventana hijas y con mysql usando tdolphin, te lo pongo totalmente para que lo veas...

Code: Select all  Expand view

FUNCTION masesores() // MAESTRO asesores

   LOCAL oWnd, oDlg
   LOCAL oExpBar, oPanel1, oPanel2, oPanel3 // PARA TExplorerBar
   LOCAL oBrow, oSplitV // xBROWSE y SPLIT
   LOCAL cSqlCmd // COMADO QUE SE EJECUTARA EN SQL PARA CONSULTA...
   LOCAL aCampos // CONTENDRA LOS CAMPOS QUE SE MOSTRARAN EN EL xBROWSE
   LOCAL cQuery // PARA HACER LA CONSULTA EN MYSQL...
   LOCAL oError // CAPTURA LOS ERRORES DE MYSQL...

   oWnd := oDatos:oWndPPAL // HACE oWnd = a VENTANA PPAL.PARA MEJOR MANEJO

   IF oWndAse == NIL
//-------- INICIO CONEXION MYSQL --------------
      cSqlCmd := "SELECT * FROM asesores ORDER BY cedula ASC" // ORDENO LA TABLA asesores POR cedula ASCendente

      TRY // INTENTO CONECTARME CON LA BASE DE DATOS...
        cQuery := TDolphinQry():New( cSqlCmd, oDatos:oConex ) //REALIZA CONSULTA CON TDolphin

      CATCH oError // CAPTURA EL ERROR Y LO MUESTRO CON msgstop()
         MSGSTOP( oError:description() + CRLF + CRLF + "Error Ejecución de Sentencia: " + ;
                  CRLF + CRLF + cSqlCmd, oDatos:cTitMsg )
         RETURN( NIL )

      END
//-------- HASTA ACA CONEXION MYSQL --------------


//---------------- DEFINO MENU - PANTALLA CON TExplorerBar
      DEFINE WINDOW oWndAse ;
             TITLE " SISPROCOM - PERSONAL - Maestro de Asesores" ;//ICON oIcon ;
             BORDER SINGLE ; //NOSYSMENU(asi queda maximizada) ;
             MDICHILD OF oWnd

// METODO New( nTop, nLeft, nWidth, nHeight, oWnd)
      oExpBar = TExplorerBar():New( 00, 00, 200, oWndAse:nHeight, oWndAse )

      oPanel1 = oExpBar:AddPanel( "ASESORES", "evalua32" )
      oPanel1:lSpecial = .t.
      oPanel1:AddLink( "Nuevo    ", {|| asesores( .t., .t., cQuery, oBrow ) }, "nuevo16" ) // AGREGAR REGISTROS

// REPORTES
      oPanel2 = oExpBar:AddPanel( "REPORTES", "print32" )
      oPanel2:AddLink( "Listado General", {|| rep_asesores( cQuery, .t. ) }, "repo1" )

// SALIDA
      oPanel3 = oExpBar:AddPanel( "SALIDA", "salir32" )
      oPanel3:AddLink( "Salir", {|| oWndAse:End() }, "salir16" )
//---------------- FIN DEFINO MENU - PANTALLA CON TExplorerBar

// DEFINICION DEL xBROWSE CON DATA
      aCampos := {"cedula","apellidos","nombres","celular","fchingreso"} // CAMPOS PARA EL xBROWSE
      oBrow := TXBrowse():New( oWndAse )

      WITH OBJECT oBrow
         :SetDolphin( cQuery, .t., .t., aCampos )
         :nMarqueeStyle    := MARQSTYLE_HIGHLROW
         :nColDividerStyle := LINESTYLE_BLACK
         :nStretchCol      := STRETCHCOL_LAST
         :lColDividerComplete := .t.
         :nHeaderHeight := 30
         :nLeft := 203 // DISTANCIA DESDE EL BORDER IZQ.
         :l2007 := .t.
         :lFooter := .f.
         :lRecordSelector := .t.
         :bClrStd := {|| IF(  cQuery:RecNo() % 2 == 0, {CLR_BLACK, CLR_WHITE}, {0, RGB(203,226,254)} ) }

      END WITH

      oBrow:aCols[1]:cHeader       := " Cédula "
      oBrow:aCols[1]:bStrData      := {|| IIF( cQuery:LastRec() > 0, cQuery:cedula, SPACE(10) ) }
      oBrow:aCols[1]:nHeadStrAlign := AL_CENTER
      oBrow:aCols[1]:nDataStrAlign := AL_LEFT

      oBrow:aCols[2]:cHeader       := " Apellidos "
      oBrow:aCols[2]:bStrData      := {|| IIF( cQuery:LastRec() > 0, cQuery:apellidos, SPACE(25) ) }
      oBrow:aCols[2]:nHeadStrAlign := AL_CENTER
      oBrow:aCols[2]:nDataStrAlign := AL_LEFT

      oBrow:aCols[3]:cHeader       := " Nombres "
      oBrow:aCols[3]:bStrData      := {|| IIF( cQuery:LastRec() > 0, cQuery:nombres, SPACE(25) ) }
      oBrow:aCols[3]:nHeadStrAlign := AL_CENTER
      oBrow:aCols[3]:nDataStrAlign := AL_LEFT

      oBrow:aCols[4]:cHeader       := " Celular "
      oBrow:aCols[4]:bStrData      := {|| IIF( cQuery:LastRec() > 0, cQuery:celular, SPACE(20) ) }
      oBrow:aCols[4]:nHeadStrAlign := AL_CENTER
      oBrow:aCols[4]:nDataStrAlign := AL_CENTER

      oBrow:aCols[5]:cHeader       := " Fecha Ingreso "
      oBrow:aCols[5]:bStrData      := {|| IIF( cQuery:LastRec() > 0, DTOC( cQuery:fchingreso), SPACE(10) ) }
      oBrow:aCols[5]:nHeadStrAlign := AL_CENTER
      oBrow:aCols[5]:nDataStrAlign := AL_CENTER

      oBrow:CreateFromCode()

      @ 00,201 SPLITTER oSplitV VERTICAL ;
         PREVIOUS CONTROLS oExpBar ;
         HINDS CONTROLS oBrow ;
         SIZE 1, oWndAse:nHeight PIXEL ;
         OF oWndAse ;
         3DLOOK UPDATE

         oSplitV:lStatic:=.t. // PARA QUE ES SPLITER NO SE MUEVA POR EL USUARIO

      SET MESSAGE OF oWndAse TO "Asesores...2011"

      oBrow:SetFocus() // DA EL FOCUS AL BROWSE POR DEFECTO

      ACTIVATE WINDOW oWndAse MAXIMIZED ;
         ON RESIZE( oExpBar:AdjLeft(), oSplitV:AdjClient(), oSplitV:AdjRight() ) ;
         VALID( oWndAse := NIL, .t. )

   ELSE
      oWndAse:Restore()
      oWndAse:SetFocus()

   ENDIF

RETURN (.t.)
 

[FRANCISDAX]

Gracias amigo lo pruebo y te lo comento ...

Salu2

[FRANCISDAX]

Bueno creo que no me resulta lo que quiero hacer, no puedo hacer con los ejemplos que me enviaron porque tengo una version antigua de fwh oct 2008 y alli no existe el texplorer, por eso lo queria hacer con el outlook2003, de todas maneras muchas gracias por sus respuestas amigos mios. Exitos a todos ...

Salu2

[joseluisysturiz]

Bueno creo que no me resulta lo que quiero hacer, no puedo hacer con los ejemplos que me enviaron porque tengo una version antigua de fwh oct 2008 y alli no existe el texplorer, por eso lo queria hacer con el outlook2003, de todas maneras muchas gracias por sus respuestas amigos mios. Exitos a todos ...

Salu2

El ejemplo que te puso Mario es con la OUTLOOK y no importa si es la outlook o la explorer..solo debes cambiar el objeto, el trabajo de division lo hace es la splitter, saludos...