Mutar entre tree y datos con Xbrowse

[cmsoft]

Como puedo mutar la vista de un xbrowse entre datos y un tree.
Encontré esto en samples, pero no lo pude adaptar para Dolphin

Code: Select all  Expand view  RUN

function TestTree1()

   local oDlg, oBrw

   USE CUSTOMER NEW
   SET ORDER TO TAG STATE
   GO TOP

   DEFINE DIALOG oDlg SIZE 800,400 PIXEL TRUEPIXEL
   @ 60,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE Alias()  ;
      COLUMNS "STATE", "CITY", "STREET", "ZIP", "AGE" ;
      CELL LINES NOBORDER

   oBrw:lDisplayZeros   := .f.
   oBrw:CreateFromCode()

   @ 10, 20 BTNBMP PROMPT "TREE" SIZE 150,30 PIXEL OF oDlg FLAT ;
      WHEN oBrw:nDataType == DATATYPE_RDD ;
      ACTION oBrw:SetTree( 3, { 0x30082, 0x30084, 0x20097 } )

   @ 10,200 BTNBMP PROMPT "DBF" SIZE 150,30 PIXEL OF oDlg FLAT ;
      WHEN oBrw:nDataType != DATATYPE_RDD ;
      ACTION ( CUSTOMER->( oBrw:SetRDD( nil, nil, { "STATE", "CITY", "STREET", "ZIP", "AGE" } ) ), ;
               oBrw:GoTop() )

   ACTIVATE DIALOG oDlg CENTERED
   CLOSE CUSTOMER

return nil

[leandro]

No se si esto te pueda servir

http://forums.fivetechsupport.com/viewtopic.php?f=3&t=39913

[cmsoft]

Gracias Leandro por responder.
Por lo que veo mutar a arbol y despues volver a datos no esta respondido.
Tal vez Mr. Rao tenga un ejemplo funcional

[nageswaragunupudi]

This sample uses FWH native MySQL

Code: Select all  Expand view  RUN

function TestTree3()

   local oCn, oRs
   local oDlg, oBrw

   oCn   := FW_DemoDB( 6 )
   oRs   := oCn:Customer
   oRs:Sort := "STATE"
   oRs:GoTop()

   DEFINE DIALOG oDlg SIZE 800,400 PIXEL TRUEPIXEL
   @ 60,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE oRs  ;
      COLUMNS "STATE", "CITY", "STREET", "ZIP", "AGE" ;
      CELL LINES NOBORDER

   oBrw:lDisplayZeros   := .f.
   oBrw:CreateFromCode()

   @ 10, 20 BTNBMP PROMPT "TREE" SIZE 150,30 PIXEL OF oDlg FLAT ;
      WHEN oBrw:nDataType == DATATYPE_ODBF ;
      ACTION oBrw:SetTree( 3, { 0x30082, 0x30084, 0x20097 } )

   @ 10,200 BTNBMP PROMPT "MYSQL" SIZE 150,30 PIXEL OF oDlg FLAT ;
      WHEN oBrw:nDataType != DATATYPE_ODBF ;
      ACTION ( oBrw:ResetData( oRs, { "STATE", "CITY", "STREET", "ZIP", "AGE" } ), ;
               oBrw:GoTop() )

   ACTIVATE DIALOG oDlg CENTERED
   oRs:Close()
   oCn:Close()

return nil
 

Please check if this is working ok.

[cmsoft]

Muchas gracias Mr. Rao. Hice las adaptaciones para Dolphin y funciona muy bien!
Le agradezco muchisimo.
Dejo aca el codigo por si a alguien le interesa

Code: Select all  Expand view  RUN

#include "tdolphin.ch"
#include "fivewin.ch"
function TestTree3()

   local oCn, oRs
   local oDlg, oBrw
   
   CONNECT oCn HOST 'localhost' ;
                      USER 'user' ;
                      PASSWORD 'password' ;
                      PORT 3306;
                      FLAGS 0;
                      DATABASE 'mi_base'
   oRs   := oCn:Query("select STATE, CITY, STREET, ZIP, AGE  from customer")
   oRs:SetOrder("STATE")
   oRs:GoTop()

   DEFINE DIALOG oDlg SIZE 800,400 PIXEL TRUEPIXEL
   @ 60,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE oRs  ;
      COLUMNS "STATE", "CITY", "STREET", "ZIP", "AGE";
      CELL LINES NOBORDER

   oBrw:lDisplayZeros   := .f.
   oBrw:CreateFromCode()

   @ 10, 20 BTNBMP PROMPT "TREE" SIZE 150,30 PIXEL OF oDlg FLAT ;
      WHEN oBrw:nDataType != 96 ;
      ACTION oBrw:SetTree( 3, { 0x30082, 0x30084, 0x20097 } )

   @ 10,200 BTNBMP PROMPT "MYSQL" SIZE 150,30 PIXEL OF oDlg FLAT ;
      WHEN oBrw:nDataType = 96 ;
      ACTION ( oBrw:ResetData( oRs, { "STATE", "CITY", "STREET", "ZIP", "AGE" } ), ;
               oBrw:GoTop() )

   ACTIVATE DIALOG oDlg CENTERED
   oRs:End()
   oCn:End()

return nil
 

[Antonio Linares]

Cesar,

gracias por compartirlo

un abrazo