SYSMENU en DIALOG

[JmGarcia]

¿ Se puede poner un SYSMENU en un dialogo (DIALOG) ?

Gracias por las respuestas...

[Antonio Linares]

JM,

Prueba a crearlo desde la claúsula ON INIT del ACTIVTE DIALOG ... :

Code: Select all  Expand view

ACTIVATE DIALOG oDlg ON INIT BuildSysMenu( oDlg )

...

function BuildSysMenu( oDlg )

   local oSysMenu

   REDEFINE SYSMENU oSysMenu OF oDlg
      MENUITEM "&Hey! We are here" ACTION MsgInfo( "Yes, we are!" )

      MENUITEM FILE "..\bitmaps\Ico.bmp" ;
         ACTION MsgInfo( "FiveWin, Clipper + xBase + OOPS" )

      MENUITEM "&Reset..." ACTION oSysMenu:Reset()

   ENDMENU

return nil
 

[JmGarcia]

No funciona, no aparece... el SysMenu.

[Antonio Linares]

JM,

Este ejemplo funciona bien aqui:

jmsys.prg

Code: Select all  Expand view

#include "FiveWin.ch"

function Main()

   local oDlg

   DEFINE DIALOG oDlg STYLE WS_SYSMENU

   ACTIVATE DIALOG oDlg CENTERED ;
      ON INIT BuildSysMenu( oDlg )

return nil

function BuildSysMenu( oDlg )

   local oSysMenu

   REDEFINE SYSMENU oSysMenu OF oDlg
      MENUITEM "&Hey! We are here" ACTION MsgInfo( "Yes, we are!" )

      MENUITEM FILE "..\bitmaps\Ico.bmp" ;
         ACTION MsgInfo( "FiveWin, Clipper + xBase + OOPS" )

      MENUITEM "&Reset..." ACTION oSysMenu:Reset()

   ENDMENU

return nil

[Andrés González]

Confirmado, funciona perfecto, aparece en la esquina superior izquierda y cuando le pulsas al reset se desactiva.

[JmGarcia]

Mi dialogo es desde recurso (RC) y no me funciona...

Code: Select all  Expand view

#include "FiveWin.ch"
function main()
local oDlg
DEFINE DIALOG oDlg NAME "DIALOGO"
// ...
ACTIVATE DIALOG oDlg CENTER ON INIT BuildSysMenu( oDlg )
return nil

function BuildSysMenu( oDlg )
   local oSysMenu
   REDEFINE SYSMENU oSysMenu OF oDlg
      MENUITEM "&Hey! We are here" ACTION MsgInfo( "Yes, we are!" )
      MENUITEM FILE "..\bitmaps\Ico.bmp" ;
         ACTION MsgInfo( "FiveWin, Clipper + xBase + OOPS" )
      MENUITEM "&Reset..." ACTION oSysMenu:Reset()
   ENDMENU
return nil

/* Fichero RC
DIALOGO DIALOG 50, 50, 160, 140
STYLE DS_MODALFRAME | WS_POPUP | WS_VISIBLE | WS_CAPTION | WS_SYSMENU | WS_MINIMIZEBOX
CAPTION "Prueba..."
FONT 8, "MS Sans Serif"
{
//...
}
*/

[Antonio Linares]

JM,

Quita el estilo DS_MODALFRAME en tu RC y funcionando

[JmGarcia]

Quita el estilo DS_MODALFRAME en tu RC y funcionando

Efectivamente, ¡¡¡ funciona !!!
¿ Que hace el estilo DS_MODALFRAME ? o ¿ que hace si lo quito ?

¿ Como pongo un icono en la esquina superior izquierda, para un dialogo mediante recursos ? me sale un cuadradito blanco.

Gracias.

[Antonio Linares]

JM,

Al quitar DS_MODALFRAME aparece el menu de systema. Al usar DS_MODALFRAME se quita. Digamos que Microsoft, por defecto, prefiere que el diálogo no muestre menu de sistema, pero no pasa nada por usarlo.

Aqui tienes un ejemplo de como cambiarle el icono:

Code: Select all  Expand view

#include "FiveWin.ch"

function Main()

   local oDlg, oIco
   
   DEFINE ICON oIco FILE "..\icons\fivewin.ico"

   DEFINE DIALOG oDlg NAME "DIALOGO" ICON oIco

   ACTIVATE DIALOG oDlg CENTERED ;
      ON INIT BuildSysMenu( oDlg )

return nil

function BuildSysMenu( oDlg )

   local oSysMenu

   REDEFINE SYSMENU oSysMenu OF oDlg
      MENUITEM "&Hey! We are here" ACTION MsgInfo( "Yes, we are!" )

      MENUITEM FILE "..\bitmaps\Ico.bmp" ;
         ACTION MsgInfo( "FiveWin, Clipper + xBase + OOPS" )

      MENUITEM "&Reset..." ACTION oSysMenu:Reset()

   ENDMENU

return nil

[JmGarcia]

Perfecto... funciona todo correctamente.

Gracias.