Mostrar imágen desde GOOGLE DRIVE

[acuellar]

Buenas estimados

Necesito mostrar imágenes almacenadas en GOOGLE DRIVE
Hago lo siguiente y no muestra nada

Code: Select all  Expand view

  cNomImg:="http://drive.google.com/uc?export=view&id=10an-18yRqOyRljuIWZ2-OKXADIDoWrG-"
    oPoster:SetBmp(cNomImg)

 @83,70 BITMAP oPoster SIZE 290,400 PIXEL OF oWnd  NOBORDER CENTER ROUNDED ADJUST

 

Gracias por la ayuda

[karinha]

Adhemar, intente con este también:

https://imgur.com/

Haga un teste.

Saludos.

[acuellar]

Gracias João

Funciona con Imgur

Pero quisiera hacerlo con GOOGLE DRIVE por es mas práctico y seguro.

Quizás alguien lo ha logrado.

[cnavarro]

Buenas estimados

Necesito mostrar imágenes almacenadas en GOOGLE DRIVE
Hago lo siguiente y no muestra nada

Code: Select all  Expand view

  cNomImg:="http://drive.google.com/uc?export=view&id=10an-18yRqOyRljuIWZ2-OKXADIDoWrG-"
    oPoster:SetBmp(cNomImg)

 @83,70 BITMAP oPoster SIZE 290,400 PIXEL OF oWnd  NOBORDER CENTER ROUNDED ADJUST

 

Gracias por la ayuda

Prueba asi

Code: Select all  Expand view

  cNomImg:="http://drive.google.com/uc?export=view&id=10an-18yRqOyRljuIWZ2-OKXADIDoWrG-"
 @83,70 BITMAP oPoster SIZE 290,400 PIXEL OF oWnd  NOBORDER CENTER ROUNDED ADJUST
    oPoster:SetBmp(cNomImg)
 

[acuellar]

Gracias Estimado Cristobal

No funciona.

[karinha]

Code: Select all  Expand view

// \samples\ADHEMAR2.PRG - 30/07/2021 - kapiabafwh@gmail.com

#Include "FiveWin.ch"

FUNCTION Main()

   LOCAL oWnd, aBmp, oFont
   LOCAL cUrl         := "https://i.imgur.com/teS9kHy.png"
   // google drive no funciona, porque no tiene extension.
   LOCAL cCorinthians := "https://drive.google.com/file/d/1YHX2ragWXF1wC08Zuax1-SNZMA3Rm0GK/view?usp=sharing"
   LOCAL cFalhaFive   := "https://drive.google.com/file/d/0B81trAa2AvzUYzRwRmR3angyQnY4SU15dV9JOEFaZ0RoYkVz/view?usp=sharing&resourcekey=0-VlhYhG3Ym3n9EOdcXFno7A"
   LOCAL cAcuellar    := "http://drive.google.com/uc?export=view&id=10an-18yRqOyRljuIWZ2-OKXADIDoWrG-"

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0, -16

   DEFINE WINDOW oWnd TITLE "BITMAPS LINKED TO URL"

   oWnd:SetFont( oFont )

   DEFINE BUTTONBAR oWnd:oBar OF ownd SIZE 64,80 2015

   oWnd:oBar:bPainted := { || oWnd:oBar:SayText( ;
      "All Images" + CRLF + "are directly" + CRLF + "from URL Links", ;
      { nil, nil, nil, -20 }, "R" ) }

   DEFINE BUTTON OF oWnd:oBar PROMPT "Timao" ;
      ACTION( ShellExecute(GetActiveWindow(),"open",'"'+cCorinthians+'"') )

   DEFINE BUTTON OF oWnd:oBar PROMPT "Fivedit" ;
      ACTION( ShellExecute(GetActiveWindow(),"open",'"'+cFalhaFive+'"') )

   DEFINE BUTTON OF oWnd:oBar PROMPT "Acuellar" ;
      ACTION( ShellExecute(GetActiveWindow(),"open",'"'+cAcuellar+'"') )

   aBmp  := oWnd:ReadImage( cUrl )

   oWnd:nHeight := 600
   oWnd:nWidth  := 700

   ACTIVATE WINDOW oWnd CENTERED ;
      ON PAINT oWnd:DrawImage( aBmp, { oWnd:oBar:nHeight,nil,nil,nil } )

   RELEASE FONT oFont

   PalBmpFree( aBmp )

   oFont:End()

RETURN NIL

// fin / end
 

Regards, saludos.

[acuellar]

Muchas gracias estimado João por tu tiempo

Seguiré intentando.

[karinha]

Muchas gracias estimado João por tu tiempo

Seguiré intentando.

Mi caro amigo Adhemar, imgur.com és totalmente seguro. uso a mucho tiempo. No tengo nada a decir de mal sobre imgur.com.

Saludos.

[acuellar]

Muchas gracias Estimado João

Por la sugerencia.

Lo haré con IMGUR

[cnavarro]

Adhemar, con el código que te he puesto, a mí me funciona perfectamente
La imagen que pones es de una pelicula?

[karinha]

Adhemar, con el código que te he puesto, a mí me funciona perfectamente
La imagen que pones es de una pelicula?

Master Navarro, porfa, podrias poner un ejemplo completo para testes? Con el link de tu imagen? BMP, JPG ó PNG?

Gracias, saludos.

[cnavarro]

Joao, aqui lo tienes

Code: Select all  Expand view

#include "Fivewin.ch"
#include "colores.ch"

Static oWindow
Static oBar
Static oFont
Static oFont2
Static oFont3
Static oFont4

Static nCP
Static nW

Function Main()

   DEFINE FONT oFont  NAME "TAHOMA" SIZE 0,-11
   DEFINE FONT oFont2 NAME "TAHOMA" SIZE 0,-16
   DEFINE FONT oFont3 NAME "CALIBRI" SIZE 0,-20
   DEFINE FONT oFont4 NAME "CALIBRI" SIZE 0,-14

   TestFldEx()

   RELEASE oFont
   RELEASE oFont2
   RELEASE oFont3
   RELEASE oFont4

Return nil

//----------------------------------------------------------------------------//

Function TestFldEx()

   local oSay5
   local oSay6
   local nClrL   := Rgb( 0, 188, 142 )
   local oFld12
   local oPoster
   local cNomImg

   DEFINE WINDOW oWindow FROM 20, 20 TO GetSysMetrics( 1 ) - 60, 1120 ;
      PIXEL TITLE "Test Panels and FolderEx" ;
      MENU MyMenu();
      COLOR CLR_BLACK, Rgb( 224, 224, 224 )
      oWindow:SetFont( oFont )

      @ 1, 10 FOLDEREX oFld12 ;
         PROMPTS "PRUEBA DE FOLDER", "OTRAS", "CONEXIONES RECIENTES" ; //, "CONEXIONES GUARDADAS", "CONEXIONES" PIXEL ;
         OF oWindow SIZE 600, 600 ; //TRANSPARENT ;
         FONT oFont4 COLOR CLR_WHITE //LEFT
   
      WITH OBJECT oFld12
         //:lNewPaint      := .T.
         :nFolderHeight  := 24
         :nRound         := 0
         :nSeparator     := 0
         :aGradSel       := { { 1, CLR_WHITE, CLR_WHITE } }
         :aGradUnSel     := { { 1, CLR_WHITE, CLR_WHITE } }
         :bClrText       := { | o, n | if( n = o:nOption, ;
                              METRO_GRIS2, Rgb( 184, 184, 184 ) ) }
         :aGradOver      := { { 0.8, CLR_WHITE, CLR_WHITE }, { 0.2, nClrL, nClrL } }
         :aGradOverUnSel := :aGradOver
         :bChange        := { || .F. }
         //:AdjClient()
         //:Refresh()
//         :nFolderWidth   := 128
         :Default()
//         :aDialogs[ 1 ]:bValid := { || .F. }
      END

      @ 0, 10 SAY oSay5 PROMPT "Esto es un Folder Pestaña 1" OF oFld12:aDialogs[ 1 ] ;
         SIZE 250, 32 PIXEL ;
         FONT oFont2 /*TRANSPARENT*/ VCENTER COLOR Rgb( 128, 128, 128 )

    cNomImg:="http://drive.google.com/uc?export=view&id=10an-18yRqOyRljuIWZ2-OKXADIDoWrG-"
    @ 83,70 BITMAP oPoster SIZE 290,400 PIXEL OF oFld12:aDialogs[ 1 ]  NOBORDER ADJUST // CENTER ROUNDED
    oPoster:SetBmp(cNomImg)

      @ 5, 10 SAY oSay6 PROMPT "Esto es un Folder Pestaña 2" OF oFld12:aDialogs[ 2 ] ;
         SIZE 250, 32 PIXEL ;
         FONT oFont2 /*TRANSPARENT*/ VCENTER COLOR Rgb( 128, 128, 128 )

   ACTIVATE WINDOW oWindow ;
      VALID ( .T. )

Return nil

//----------------------------------------------------------------------------//

Function MyMenu()

   Local oMnu
   MENU oMnu
      MENUITEM FwString( "Acciones" )
      MENUITEM FwString( "Editar" )
      MENUITEM FwString( "Ver" )
      MENUITEM FwString( "Ayuda" )
   ENDMENU

Return oMnu

//----------------------------------------------------------------------------//

 

[karinha]

Gracias Master. Con FOLDEREX funciona. Regards, saludos.

[karinha]

Perfecto Maestro Navarro.

Code: Select all  Expand view

// \SAMPLES\TESTIMG3.PRG

#Include "FiveWin.ch"

FUNCTION Main()

   LOCAL oDlg, oImg, cNomImg

   cNomImg := "http://drive.google.com/uc?export=view&id=10an-18yRqOyRljuIWZ2-OKXADIDoWrG-"
   
   DEFINE DIALOG oDlg TITLE "Image Google Drive"

   @ 0, 0 BITMAP oImg SIZE 250, 350 PIXEL OF oDlg NOBORDER ADJUST

   oImg:SetBmp( cNomImg )

   ACTIVATE DIALOG oDlg CENTERED ;
      ON INIT ( oDlg:SetSize( oImg:nWidth, oImg:nHeight ), oDlg:Center() )

   oImg:End()

RETURN NIL
 

Regards, saludos.

[cmsoft]

Desde que version de FW funciona esta opcion?
Porque a mi no me funciona.
Tengo la 16.06