FiveTech Software tech support forums

www.FiveTechSoft.com
https://forums.fivetechsupport.com/

Velocidad de Internet.

https://forums.fivetechsupport.com/viewtopic.php?f=6&t=44568

Page 1 of 2

Velocidad de Internet.

PostPosted: Sun Jun 02, 2024 5:49 pm
by JoseAlvarez
Hola a Todos Amigos,

Hace ya algunos años trato de que mis clientes se decanten por alojar sus datos en la nube, gracias a todas las ventajas que esto conlleva.
Mis aplicaciones son hechas en FW+HARBOUR y se instalan localmente, es decir, aplicaciones DESKTOP, como cualquier otra, pero toda la data se guarda y gestiona en la nube.

¿Hay alguna función en FW que me indique a que velocidad esta el internet al momento de ejecutarse el sistema?

Si no contamos con esa función nativa, ¿existe alguna aplicación de terceros que pueda integrar a mis aplicaciones de manera transparente ?

Sugiero (si no hay manera de saberlo) que se integre en las nuevas versiones de FW, por supuesto si es posible y si más usuarios lo consideran de utilidad.

Quedo pendiente para recibir ideas y sugerencias.

Gracias.

Re: Velocidad de Internet.

PostPosted: Sun Jun 02, 2024 7:19 pm
by Antonio Linares
la web https://fast.com/ es el lugar ideal para medir la velocidad de internet.

Estamos viendo si podemos hacer una función que extraiga el valor automaticamente desde esa web

Re: Velocidad de Internet.

PostPosted: Mon Jun 03, 2024 12:23 am
by Armando
Antonio:

Muchas gracias.

Saludos

Re: Velocidad de Internet.

PostPosted: Mon Jun 03, 2024 2:14 am
by JoseAlvarez
Excelente maestro,

Con fivewin, siempre se puede !

Seguro que pronto lo tendremos!

Re: Velocidad de Internet.

PostPosted: Tue Jun 04, 2024 9:35 pm
by carlos vargas
Yo lo buscaría hacer con el componente twebview y con el URL de speedtest. Y lo íntegro en mi app.

Re: Velocidad de Internet.

PostPosted: Wed Jun 05, 2024 12:55 am
by JoseAlvarez
carlos vargas wrote:Yo lo buscaría hacer con el componente twebview y con el URL de speedtest. Y lo íntegro en mi app.


Hola carlos, saludos.

Lo que deseo es obtener el valor de la velocidad, no visualizarlo.

Si te entendí bien, lo que me sugieres es para mostrar la web.

Re: Velocidad de Internet.

PostPosted: Wed Jun 05, 2024 6:40 am
by Garbi
Hola,
No he podido investigar mucho, pero para otras cosas como descargar ficheros, yo lo hago por comandos.
Te pongo una URL donde te explica como hacerlo, supongo que si buscas un poco en la ayuda podrás saber como obtener el dato de la velocidad.

https://www.youtube.com/watch?v=NU15yYT2pwk

Ya nos dices si te ha servido.

Re: Velocidad de Internet.

PostPosted: Wed Jun 05, 2024 6:55 am
by Antonio Linares
Este código debería funcionar pero algo le falla aún:
Code: Select all  Expand view
#include 'hbcurl.ch'

#define CURLOPT_URL    10002
#define CURLOPT_NOBODY 10013

PROCEDURE Main()
   LOCAL curl, res, url, startTime, endTime
   LOCAL speed

   url := "https://github.com/FiveTechSoft/harbour_and_xharbour_builds/raw/master/harbour_msvc2022_64_20240530.zip"
   startTime := Seconds()

   curl := curl_easy_init()
   IF curl!= Nil
      curl_easy_setopt(curl, CURLOPT_URL, url)
      // curl_easy_setopt(curl, CURLOPT_NOBODY, 1) // solo obtener headers
      res := curl_easy_perform(curl)
      endTime := Seconds()
      IF res == 0
         speed := (endTime - startTime) / 60 // segundos a minutos
        ? "Velocidad de descarga:", speed * 1024, " KB/s"
      ELSE
        ? "curl_easy_perform() failed:", res, curl_easy_strerror(res)
      ENDIF
      curl_easy_cleanup(curl)
   ENDIF
   curl_global_cleanup()
RETURN

Re: Velocidad de Internet.

PostPosted: Wed Jun 05, 2024 10:36 am
by JoseAlvarez
Garbi wrote:Hola,
No he podido investigar mucho, pero para otras cosas como descargar ficheros, yo lo hago por comandos.
Te pongo una URL donde te explica como hacerlo, supongo que si buscas un poco en la ayuda podrás saber como obtener el dato de la velocidad.

https://www.youtube.com/watch?v=NU15yYT2pwk

Ya nos dices si te ha servido.


Gracias GARBI, agradecido por tu apoyo. Todas las ideas son bienvenidas.

Re: Velocidad de Internet.

PostPosted: Wed Jun 05, 2024 10:53 am
by JoseAlvarez
Antonio Linares wrote:Este código debería funcionar pero algo le falla aún:
Code: Select all  Expand view
#include 'hbcurl.ch'

#define CURLOPT_URL    10002
#define CURLOPT_NOBODY 10013

PROCEDURE Main()
   LOCAL curl, res, url, startTime, endTime
   LOCAL speed

   url := "https://github.com/FiveTechSoft/harbour_and_xharbour_builds/raw/master/harbour_msvc2022_64_20240530.zip"
   startTime := Seconds()

   curl := curl_easy_init()
   IF curl!= Nil
      curl_easy_setopt(curl, CURLOPT_URL, url)
      // curl_easy_setopt(curl, CURLOPT_NOBODY, 1) // solo obtener headers
      res := curl_easy_perform(curl)
      endTime := Seconds()
      IF res == 0
         speed := (endTime - startTime) / 60 // segundos a minutos
        ? "Velocidad de descarga:", speed * 1024, " KB/s"
      ELSE
        ? "curl_easy_perform() failed:", res, curl_easy_strerror(res)
      ENDIF
      curl_easy_cleanup(curl)
   ENDIF
   curl_global_cleanup()
RETURN


Perfecto master, haré las pruebas con este código y estaré comentando.

La idea con este dato es hacer lo mismo que muchas aplicaciones android que detectan la velocidad y avisan al usuario "su conexión a internet es débil", "su conexión presenta problemas" o "su conexión a internet es lenta".

De esta manera, estarán informados que la lentitud se debe a una mala calidad de su internet y no a mi aplicación.

Con la empresa y el plan de hosting que tengo contratado mi aplicación funciona al 100% con muy pero muy poco retardo en dar respuesta. Pero a veces la velocidad de internet varía, y algunos usuarios piensan que es por causa de la aplicación. Por eso es importante para mi que mi sistema les informe sobre el status de su conexión.

Se que en la mayoría de paises el servicio de internet funciona siempre de manera estable manteniendo la velocidad ofrecida por el proveedor, pero acá en Venezuela es una verdadera montaña rusa, literalmente.

Re: Velocidad de Internet.

PostPosted: Wed Jun 05, 2024 2:35 pm
by Jimmy
hi.

there is a SPEED TEST AT Google
https://fiber.google.com/speedtest/

Re: Velocidad de Internet.

PostPosted: Wed Jun 05, 2024 3:02 pm
by karinha
Tks, Jimmy.

Code: Select all  Expand view

// C:\FWH\SAMPLES\INTSPEED.PRG

#include "FiveWin.ch"

FUNCTION Main()

   LOCAL cURL := "https://fiber.google.com/speedtest/"

   /* comprobamos si tenemos conexion a internet */
   IF .NOT. IsInternet()

      // MsgAlert( "Verifique Sua Internet.", "Internet Fora do Ar?" )
      MsgAlert( "Revise su Internet.", "¿Internet caído?")

      RETURN NIL

   ENDIF

   CursorWait()

   // Funcion modificada para que funcione con Windows 7
   ShellExecute( , "open", cURL )

   CursorArrow()

RETURN NIL

// FIN / END
 


Regards, saludos.

Re: Velocidad de Internet.

PostPosted: Wed Jun 05, 2024 8:06 pm
by JoseAlvarez
Antonio Linares wrote:Este código debería funcionar pero algo le falla aún:
Code: Select all  Expand view
#include 'hbcurl.ch'

#define CURLOPT_URL    10002
#define CURLOPT_NOBODY 10013

PROCEDURE Main()
   LOCAL curl, res, url, startTime, endTime
   LOCAL speed

   url := "https://github.com/FiveTechSoft/harbour_and_xharbour_builds/raw/master/harbour_msvc2022_64_20240530.zip"
   startTime := Seconds()

   curl := curl_easy_init()
   IF curl!= Nil
      curl_easy_setopt(curl, CURLOPT_URL, url)
      // curl_easy_setopt(curl, CURLOPT_NOBODY, 1) // solo obtener headers
      res := curl_easy_perform(curl)
      endTime := Seconds()
      IF res == 0
         speed := (endTime - startTime) / 60 // segundos a minutos
        ? "Velocidad de descarga:", speed * 1024, " KB/s"
      ELSE
        ? "curl_easy_perform() failed:", res, curl_easy_strerror(res)
      ENDIF
      curl_easy_cleanup(curl)
   ENDIF
   curl_global_cleanup()
RETURN


Master Antonio,

no encuentro ninguna de las funciones que comienzan por curl_

enlace las lib hbcurl y hbcurls pero no aparecen al compilar.

donde estan?

Re: Velocidad de Internet.

PostPosted: Thu Jun 06, 2024 12:25 am
by Lailton
Jose,

Las funciones curl_* es parte da library CURL.

https://curl.se/download.html

Se utiliza vcpkg pode instalar lo package curl con lo comando
Code: Select all  Expand view
vcpkg install curl

Re: Velocidad de Internet.

PostPosted: Thu Jun 06, 2024 6:15 am
by Antonio Linares
Funcionando bien gracias a Carles Aubia! :-)
Code: Select all  Expand view
#include 'hbcurl.ch'

#define CURLOPT_NOBODY 10013

function speed()
       
    local hCurl, nRet, uValue, hRows
    local lError        := .f.
    local cUrl          := "https://github.com/FiveTechSoft/harbour_and_xharbour_builds/raw/master/harbour_msvc2022_64_20240530.zip"
   
   
    if ! empty( hCurl := curl_easy_init() )
     
        curl_easy_setopt( hCurl, HB_CURLOPT_DOWNLOAD )
        curl_easy_setopt( hCurl, HB_CURLOPT_URL, cUrl )    
       
        curl_easy_setopt( hCurl, HB_CURLOPT_SSL_VERIFYPEER, .f. )
        curl_easy_setopt( hCurl, HB_CURLOPT_SSL_VERIFYHOST, .f. )
        curl_easy_setopt( hCurl, HB_CURLOPT_FOLLOWLOCATION )        // Necesario para aquellos sitios que nos redirigen a otros

        curl_easy_setopt( hCurl, HB_CURLOPT_FILETIME, 1)
       
        //curl_easy_setopt(hCurl, CURLOPT_NOBODY, 1) // solo obtener headers
        curl_easy_setopt( hCurl, HB_CURLOPT_DL_FILE_SETUP, 'c:\temp\z.zip' )
        curl_easy_setopt( hCurl, HB_CURLOPT_NOPROGRESS, .t. )
        curl_easy_setopt( hCurl, HB_CURLOPT_VERBOSE, .f. )   
        curl_easy_setopt( hCurl, HB_CURLOPT_FAILONERROR , .t. )  // Change cUrl Dummy      
       
        nRet := curl_easy_perform( hCurl )
   
   
        if nRet == HB_CURLE_OK  //  HB_CURLE_OK == 0                   
         
            ? 'Size Download: ' +  ltrim(str(curl_easy_getinfo( hCurl, HB_CURLINFO_SIZE_DOWNLOAD )))
            ? 'Time: ' +  ltrim(str(curl_easy_getinfo( hCurl, HB_CURLINFO_TOTAL_TIME ))) + ' sec.'      //  receive the total time in seconds for the previous transfer, including name resolving, TCP connect etc.
            ? 'Bytes/sec: ' + ltrim(str(curl_easy_getinfo( hCurl, HB_CURLINFO_SPEED_DOWNLOAD )))     //  bytes/sec  
            ? 'Mb. Sec: ' + ltrim(str(curl_easy_getinfo( hCurl, HB_CURLINFO_SPEED_DOWNLOAD ) / 1024 /1024))
       
        else           
           lError := .t.
           ? 'Error: ' + curl_easy_strerror( nRet )
        endif            

        curl_easy_cleanup(hCurl)    
   
    endif
   
retu ! lError
 
All times are UTC
Page 1 of 2
Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group
http://www.phpbb.com/