Page 1 of 1
Sobreescribir metodo ?
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Wed Mar 14, 2007 11:56 am
by Frafive
Hola
Se puede sobreescribir un metodo de una clase con las nueva extensiones de xharbour ?
Por ejemplo quiero modificar el metodo paint de la clase timage
Un saludo
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Wed Mar 14, 2007 5:40 pm
by carlos vargas
claro que se puede en la mayoria de los casos, dejame llegar al trabajo por la tarde y te mando unos ejemplos de sobreescitura y de agregar metodos a una clase.
salu2
carlos vargas
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Thu Mar 15, 2007 8:21 am
by Frafive
Gracias Carlos , cuando puedas pones un ejemplo aqui en el foro
un saludo
Sobreescribir Método
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Fri Mar 16, 2007 4:36 pm
by César E. Lozada
PROCEDURE tDialog_Modify()
OVERRIDE METHOD Help95 CLASS tDialog WITH MyHelp95
RETURN
*============================================
#define GWL_EXSTYLE -20
#define WS_EX_CONTEXTHELP 1024
Static Function MyHelp95()
Local Self:=qSelf()
if ::lHelpIcon == NIL
::lHelpIcon := .f.
endif
if ::lHelpIcon
SetWindowLong( ::hWnd, GWL_EXSTYLE,;
nOr( GetWindowLong( ::hWnd,GWL_EXSTYLE ),;
WS_EX_CONTEXTHELP ) )
endif
return nil
*============================================
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Fri Mar 16, 2007 7:39 pm
by carlos vargas
ops.
disculpa, se me olvido
salu2
carlos vargas
al inicio de tu aplicacion llama al procedimiento OverrideAndExtend
- Code: Select all Expand view
function main(...)
...
/*sobreescritura y extencion de metodos*/
OverrideAndExtend()
...
return nil
- Code: Select all Expand view
PROCEDURE OverrideAndExtend()
OVERRIDE METHOD DispBegin IN CLASS TWindow WITH KDispBegin
OVERRIDE METHOD DispEnd IN CLASS TWindow WITH KDispEnd
EXTEND CLASS TFOLDER WITH METHOD RefreshPages
EXTEND CLASS TFOLDER WITH METHOD GoFirstControl
EXTEND CLASS TDIALOG WITH METHOD RefreshDialog
EXTEND CLASS TPRINTER WITH METHOD Cm2Pix
RETURN
- Code: Select all Expand view
/*----------------------------------------------------------------------------------*/
STATIC FUNCTION KDispBegin()
LOCAL SELF := HB_QSelf()
RETURN SELF
/*----------------------------------------------------------------------------------*/
STATIC FUNCTION KDispEnd()
LOCAL SELF := HB_QSelf()
RETURN NIL
/*----------------------------------------------------------------------------------*/
STATIC FUNCTION RefreshDialog( nPos )
LOCAl Self := HB_QSelf()
aeval( ::aControls, { |oCtrl| oCtrl:Refresh() } )
::aControls[ nPos ]:SetFocus()
RETURN NIL
/*----------------------------------------------------------------------------------*/
STATIC FUNCTION RefreshPages()
LOCAl Self := HB_QSelf()
LOCAL oPage
FOR EACH oPage IN ::aDialogs
aeval( oPage:aControls, { |oCtrl| oCtrl:Refresh() } )
NEXT
RETURN NIL
/*----------------------------------------------------------------------------------*/
STATIC FUNCTION GoFirstControl()
LOCAL SELF := HB_QSelf()
::aDialogs[1]:aControls[1]:SetFocus()
RETURN NIL
/*----------------------------------------------------------------------------------*/
STATIC FUNCTION Cm2Pix(nCm)
LOCAL SELF := HB_QSelf()
IF ValType( ::nXOffset ) == "U"
::nXoffset := 0
ENDIF
nPix := Max( 0, ( nCm * 10 * ::nHorzRes() / ::nHorzSize() ) - ::nXoffset )
RETURN nPix
/*----------------------------------------------------------------------------------*/
Re: Sobreescribir metodo ?
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Thu Jun 06, 2013 11:39 pm
by rolando
Buenas noches,
Retomo el tema porque me interesa y seguramente alguien me ayudará.
¿Como hago cuando necesito agregar una DATA para que funcione un método sobreescrito ó un método agregado a alguna clase?
Por ej. si en la xBrowse quisiera agregar la DATA oMiObjeto
- Code: Select all Expand view
CLASS TXBrowse FROM TControl
DATA oVScroll,; // Vertical scrollbar (used internally)
oHScroll,; // Horizontal scrollbar (used internally)
oCapCol,; // Actual mouse captured column (used internally)
oSeek,; // Optional TSay control to display the value of current ::cSeek value
oDbf // Just a container for a DBF object for your own use (it is not used by the class)
oMiObjeto // Data de un objeto que debo agregar
Gracias.
Rolando
![Very Happy :D](./images/smilies/icon_biggrin.gif)
Re: Sobreescribir metodo ?
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Fri Jun 07, 2013 12:37 am
by TecniSoftware
Rolando
Es bien fácil!
EXTEND CLASS TXBrowse WITH DATA oMiObjeto
Saludos
Re: Sobreescribir metodo ?
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Fri Jun 07, 2013 12:40 am
by rolando
Gracias Alejandro,
Rolando
Re: Sobreescribir metodo ?
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Fri Aug 16, 2013 1:27 am
by rolando
Buenas noches,
En realidad estoy empezando con esto y tengo una consulta más (que seguramente no será la última):
¿Como hacer para sobreescribir una function de una clase?
Gracias.
Rolando
![Very Happy :D](./images/smilies/icon_biggrin.gif)
Re: Sobreescribir metodo ?
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Fri Aug 16, 2013 10:01 am
by xmanuel
La verdad es que no es una buena manera de sobreescribir un método o crear una nueva data.
Imaginad que quereis usar el método original y el sobreescrito.
Además de otros inconvenientes que podemos explicar...
Pienso que lo mejor es crear tu propia clase heredada de la original, es un concepto muy importante en la POO, la ESPECIALIZACION.
Por ejemplo:
- Code: Select all Expand view
CLASS MiTXBrowse FROM TXBrowse // Definicion de mi clase especializada
DATA oMiObjeto // Mi data
METHOD new() CONSTRUCTOR
ENDCLASS
METHOD new() CLASS MiTXBrowse
::super:New() // Ejecutamos el metodo de la clase madre
::oMiObjeto := Clase():new() // Instanciamos la data tipo objeto
return self
Luego en mi codigo podría hacer esto:
- Code: Select all Expand view
oXbrw := TXBrowse():new() // objeto sin cambios
oMiBrw := MiTXBrowse():new() // objeto con nueva data y metodo sobreescrito.
Re: Sobreescribir metodo ?
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Tue Aug 27, 2013 1:09 pm
by cuatecatl82
Saludos:
He intentado probar con Harbour pero no funciona, al compilar me salen los siguientes errores:
- Code: Select all Expand view
Compiling 'Virtual.prg'...
Virtual.prg(725) Error E0030 Syntax error "syntax error at 'METHOD'"
Virtual.prg(726) Error E0030 Syntax error "syntax error at 'METHOD'"
Virtual.prg(728) Error E0030 Syntax error "syntax error at 'CLASS'"
Virtual.prg(729) Error E0030 Syntax error "syntax error at 'CLASS'"
Virtual.prg(730) Error E0030 Syntax error "syntax error at 'CLASS'"
Virtual.prg(732) Error E0030 Syntax error "syntax error at 'CLASS'"
6 errors
No code generated.
Por lo que se es que solo funciona con xHarbour, existe alguna manera de hacerlo con Harbour..?
Saludos.
![Mr. Green :mrgreen:](./images/smilies/icon_mrgreen.gif)
Re: Sobreescribir metodo ?
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Tue Aug 27, 2013 1:22 pm
by carlos vargas
#include hbcompat.ch
y ademas incluye la libreria xhb.lib que tiene compatibiliad con xharbour.
salu2
Re: Sobreescribir metodo ?
![Post Post](./styles/prosilver/imageset/icon_post_target.gif)
Posted:
Tue Aug 27, 2013 1:23 pm
by carlos vargas
en los repositorios de harbour esta una carpeta xhb en contrib, ahi estan varios ch que dan soporte a esto.
normalmente no esta incluido en los binarios por lo que sera necesario que los tomes y los incluyas en el include de harbour.