FiveTech Software tech support forums

www.FiveTechSoft.com

Skip to content

Erro com 9.07

Post a reply

Re: Erro com 9.07

Postby Rossine » Fri Aug 21, 2009 9:15 pm

Olá Antonio,

Deste jeito realmente não dá mais erro mas também não executa nenhuma das ações abaixo:

Code: Select all  Expand view  RUN

function RibbonBarEvent( cEvent, aParams, pParams, aButtons, oWnd )

   do case
      case cEvent == "Execute" .and. Len( aButtons ) > 0
           do case
              case aButtons[ 1 ]:__hObj == aParams[ 1 ]:__hObj
                   MsgInfo( "Button 1" )
                   
              case aButtons[ 2 ]:__hObj == aParams[ 1 ]:__hObj
                   MsgInfo( "Button 2" )

              case aButtons[ 3 ]:__hObj == aParams[ 1 ]:__hObj
                   MsgInfo( "From Quick Access Button 1" )

              case aButtons[ 4 ]:__hObj == aParams[ 1 ]:__hObj
                   MsgInfo( "From Quick Access Button 2" + CRLF + "FIVEWIN SHARING POWER" )

              case aButtons[ 5 ]:__hObj == aParams[ 1 ]:__hObj
                   MsgInfo( "From Quick Access Button 3" )
                   
              case aButtons[ 6 ]:__hObj == aParams[ 1 ]:__hObj
                   oWnd:End()      
                               
              case aButtons[ 7 ]:__hObj == aParams[ 1 ]:__hObj
                   oWnd:End()
                   
              case aButtons[ 8 ]:__hObj == aParams[ 1 ]:__hObj
                   MsgInfo( "FWH's ActiveX Power support Codejock", "About Codejock" )      
                   
              case aButtons[ 9 ]:__hObj == aParams[ 1 ]:__hObj
                   PrinterSetup()  
           endcase        
   endcase        
   
return nil

 
Obrigado, Regards, Saludos

Rossine.

Harbour and Harbour++
Rossine
 
Posts: 344
Joined: Tue Oct 11, 2005 11:33 am
Top

Re: Erro com 9.07

Postby Antonio Linares » Fri Aug 21, 2009 9:39 pm

Rossine,

Prueba a comprobar el Id del botón:

case aParams[ 1 ]:Id == ...
regards, saludos

Antonio Linares
www.fivetechsoft.com
User avatar
Antonio Linares
Site Admin
 
Posts: 42203
Joined: Thu Oct 06, 2005 5:47 pm
Location: Spain
Top

Re: Erro com 9.07

Postby Rossine » Sat Aug 22, 2009 3:20 pm

Olá Antonio,

A sintaxe correta é :

Code: Select all  Expand view  RUN

function RibbonBarEvent( cEvent, aParams, pParams, aButtons, oWnd )

   do case
      case cEvent == "Execute" .and. Len( aButtons ) > 0
           do case
              case aButtons[ 1 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "Button 1" )
                   
              case aButtons[ 2 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "Button 2" )

              case aButtons[ 3 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "From Quick Access Button 1" )

              case aButtons[ 4 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "From Quick Access Button 2" + CRLF + "FIVEWIN SHARING POWER" )

              case aButtons[ 5 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "From Quick Access Button 3" )
                   
              case aButtons[ 6 ]:Id == aParams[ 1 ]:Id
                   oWnd:End()      
                               
              case aButtons[ 7 ]:Id == aParams[ 1 ]:Id
                   oWnd:End()

              case aButtons[ 8 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "FWH's ActiveX Power support Codejock", "About Codejock" )      
                   
              case aButtons[ 9 ]:Id == aParams[ 1 ]:Id
                   PrinterSetup()  
           endcase        
   endcase        
   
return nil

 


Porque estas propriedades estão dando erro de execução, como se elas não existissem:

Code: Select all  Expand view  RUN

*   oAct:Do( "VisualTheme", .T. )
...    
*   oRb:ShowQuickAccessBelowRibbon(.F.)
*   oRb:ShowCaptionAlways(.T.)
*   oRb:ShowQuickAccess(.T.)  
...
*   oSysButton:IconId( 5 )
...
*   oTabFiles_Grp1:ControlGroupOption:IconId(3)
 


Veja quando chamo "oAct:Do( "VisualTheme", .T. )" o erro que ocorre:

Code: Select all  Expand view  RUN


   Error description: Error BASE/3012  Argument error: VISUALTHEME
   Args:
     [   1] = L   .T.

Stack Calls
===========
   Called from:  => TOLEAUTO:VISUALTHEME(0)
   Called from:  => __OBJSENDMSG(0)
   Called from: classes\activex.prg => TACTIVEX:DO(0)
   Called from: act5.prg => MAIN(67)
 
Obrigado, Regards, Saludos

Rossine.

Harbour and Harbour++
Rossine
 
Posts: 344
Joined: Tue Oct 11, 2005 11:33 am
Top

Re: Erro com 9.07

Postby Antonio Linares » Sat Aug 22, 2009 5:54 pm

Rossine,

En vez de:

oAct:Do( "VisualTheme", .T. )

prueba con:

oAct:VisualTheme = .T.
regards, saludos

Antonio Linares
www.fivetechsoft.com
User avatar
Antonio Linares
Site Admin
 
Posts: 42203
Joined: Thu Oct 06, 2005 5:47 pm
Location: Spain
Top

Re: Erro com 9.07

Postby Rossine » Sat Aug 22, 2009 6:33 pm

Olá Antonio,

Agora está 100% :shock: Deixo aqui o exemplo funcionando com a codejock:

Code: Select all  Expand view  RUN

// FWH ActiveX Call Codejock Ocx Sample //
// Richard                              //

#include "FiveWin.ch"

#define xtpControlError              0
#define xtpControlButton             1
#define xtpControlPopup              2
#define xtpControlButtonPopup        3
#define xtpControlSplitButtonPopup   4
#define xtpControlComboBox           5
#define xtpControlEdit               6
#define xtpControlCustom             7
#define xtpControlLabel              8
#define xtpControlCheckBox           9
#define xtpControlGallery           10
#define xtpControlRadioButton       11

#define xtpImageNormal               0
#define xtpImageDisabled             1
#define xtpImageHot                  2
#define xtpImageChecked              3
#define xtpImagePressed              4


function Main()  
     
   local oWnd, oAct
   
   local oRb
   local oQA, oQBtn1, oQBtn2, oQBtn3
   local oSysButton, oControl, oPopupBar  
   
   local oStatusBar, oToolTipContext, oIcons
   local oTabFiles, oGroup1
   local oTabEdit, oGroup2
   local oTabBuild
   
   local aButtons := {}
   local oButton1, oButton2, oButton3, oButton4
   local oExitBtn, oExitBtn2
   local oBmp1, oBmp2, oBmp3, obmp4, obmp5, obmp6, obmp7, obmp8, obmp9
   
   DEFINE WINDOW oWnd TITLE "FWH Support Codejock ActiveX"
   
   oBmp1 := TBitmap():Define( , "\fwh\bitmaps\16x16\new2.bmp", oWnd )
   oBmp2 := TBitmap():Define( , "\fwh\bitmaps\16x16\open2.bmp", oWnd )
   oBmp3 := TBitmap():Define( , "\fwh\bitmaps\alphabmp\explorer.bmp", oWnd )    
   oBmp4 := TBitmap():Define( , "\fwh\bitmaps\32x32\open.bmp", oWnd )
   oBmp5 := TBitmap():Define( , "\fwh\bitmaps\32x32\people.bmp", oWnd )
   oBmp6 := TBitmap():Define( , "\fwh\bitmaps\32x32\keys.bmp", oWnd )
   oBmp7 := TBitmap():Define( , "\fwh\bitmaps\32x32\quit.bmp", oWnd )
   oBmp8 := TBitmap():Define( , "\fwh\bitmaps\16x16\copy.bmp", oWnd )
   oBmp9 := TBitmap():Define( , "\fwh\bitmaps\16x16\info.bmp", oWnd )
   
   
   oAct := TActiveX():New( oWnd, "Codejock.CommandBarsFrame.13.0.0", 0, 0, 0, 0 )  
   
   //@ 0, 0 ACTIVEX oAct PROGID "Codejock.CommandBarsFrame.12.1.1" OF oWnd

   oAct:bOnEvent = { | cEvent, aParams, pParams | RibbonBarEvent( cEvent, aParams, pParams, aButtons, oWnd ) }

   oAct:Do( "AttachToWindow", oWnd:hWnd )
   
   oAct:Do( "EnableOffice2007Frame", .T. )
   oAct:VisualTheme := .t.

           
   // ToolTipContext - Richard          
   oToolTipContext := TOleAuto():New( oAct:oOleAuto:__hObj )
   oToolTipContext := oToolTipContext:ToolTipContext()
   oToolTipContext:Style = 5  && xtpToolTipOffice2007
   oToolTipContext:ShowTitleAndDescription( .T., 0 )
   oToolTipContext:ShowImage( .T., 0 )
   oToolTipContext:SetMargin( 2, 2, 2, 2 )
   oToolTipContext:MaxTipWidth = 180
   
   // StatusBar-Richard
   oStatusBar := TOleAuto():New( oAct:oOleAuto:__hObj )
   oStatusBar:StatusBar:Visible = .T.

   oStatusBar:StatusBar:AddPane( 0 )
   oStatusBar:StatusBar:AddPane( 59137 )
   oStatusBar:StatusBar:AddPane( 59138 )
   oStatusBar:StatusBar:AddPane( 59139 )  
   oStatusBar:StatusBar:IdleText = "FWH support Codejock RibbonBar"      
   
   oIcons := oAct:Do( "icons" )  
   
   oIcons:AddBitmap( oBmp1:hBitmap,1,xtpImageNormal,.f. )
   oIcons:AddBitmap( oBmp2:hBitmap,2,xtpImageNormal,.f. )
   oIcons:AddBitmap( oBmp3:hBitmap,3,xtpImageNormal,.t. ) // 4th param, Bool to Alpha Channel Support  
   oIcons:AddBitmap( oBmp4:hBitmap,4,xtpImageNormal,.f. )
   oIcons:AddBitmap( oBmp5:hBitmap,5,xtpImageNormal,.f. )
   oIcons:AddBitmap( oBmp6:hBitmap,6,xtpImageNormal,.f. )
   oIcons:AddBitmap( oBmp7:hBitmap,7,xtpImageNormal,.f. )
   oIcons:AddBitmap( oBmp8:hBitmap,8,xtpImageNormal,.f. )
   oIcons:AddBitmap( oBmp9:hBitmap,9,xtpImageNormal,.f. )
   oIcons:LoadBitmap( "\fwh\bitmaps\32x32\edit.bmp",4, xtpImageNormal)
   
   //oAct:Hide()

   // RibbonBar - Richard
   oRb = oAct:Do( "AddRibbonBar", "Ribbon Bar" )
   
   oRb:EnableDocking(64)
   oRb:EnableFrameTheme()              
   oRb:ShowQuickAccessBelowRibbon := .F.
   oRb:ShowCaptionAlways := .T.
   oRb:ShowQuickAccess := .T.  
   oRb:ShowGripper()
   
   // QuickAccess - Richard  
   oQA:= oRb:QuickAccessControls()
   oQBtn1 := oQA:Add( 1, 1, "&New"         )
   oQBtn2 := oQA:Add( 1, 2, "&Save"        )
   oQBtn3 := oQA:Add( 1, 8, "&copy"        )
   oQA:Add( 1, 9, "&info"        )
   
   // Add SysButton - Richard
   oSysButton := oRb:AddSystemButton()
   oSysButton:IconId := 5
     
   oSysButton:CommandBar:Controls:Add( 1, 4, "&New"         )
   oSysbutton:CommandBar:Controls:Add( 1, 5, "&Open..."     )
   oSysbutton:CommandBar:Controls:Add( 1, 6, "&Save"        )
   oSysbutton:CommandBar:Controls:Add( 1, 6, "Save &As..."  )
   
   oControl := oSysButton:CommandBar:Controls:Add( 4, 5, "&Print")
   oControl:BeginGroup = .T.
   
   oPopupBar := TOleAuto():New( oAct:oOleAuto:__hObj )
          oPopupBar := oPopupBar:CreateCommandBar("CXTPRibbonSystemPopupBarPage")

          oControl:CommandBar = oPopupBar
          oControl := oPopupBar:Controls:Add( 8, 0, "Preview and print the document")
          oControl:Width = 296
          oControl:DefaultItem = .T.
          oControl:Style = 1  && xtpButtonCaption
          oPopupBar:DefaultButtonStyle = 5  && xtpButtonCaptionAndDescription
          oPopupBar:SetIconSize( 32, 32 )
          oPopupBar:ShowGripper = .F.

             oPopupBar:Controls:Add( 1, 4, "Print Pre&view" )
          oPrnSetup = oPopupBar:Controls:Add( 1, 5, "Pr&int Setup..." )
             oPopupBar:Controls:Add( 1, 6, "Print Pre&view" )
             
   oSysbutton:CommandBar:Controls:Add( 1, 1230, "Prepare" )
   oSysbutton:CommandBar:Controls:Add( 1, 1235, "Send" )
   oSysbutton:CommandBar:Controls:Add( 1, 1230, "Publish" )
   oExitBtn2 = oSysbutton:CommandBar:Controls:Add( 1, 7, "Close" )
 
   oSysbutton:CommandBar:SetIconSize( 32, 32 )    
   
   
   // RibbonBar Table - Richard  
   oTabFiles = oRb:InsertTab( 0, "&Files" )
   
   oTabFiles_Grp1 = oTabFiles:Groups:AddGroup("&Clipboard", 0)
   oTabFiles_Grp1:ShowOptionButton = .T.
   
   // TabFiles Group ToolTip - Richard
   oTabFiles_Grp1:ControlGroupOption:Id = 1000
   oTabFiles_Grp1:ControlGroupOption:ToolTipText = "Clipboard"
   oTabFiles_Grp1:ControlGroupOption:DescriptionText = "Show clipboard dialog"
   oTabFiles_Grp1:ControlGroupOption:IconId := 3
     
   
   oPaste := oTabFiles_Grp1:Add( 4, 1, "&Paste")
   oPaste:CommandBar:Controls:Add( 1, 1, "&Paste" )
   oPaste:CommandBar:Controls:Add( 1, 2, "&Paste Special" )
   oButton1 = oTabFiles_Grp1:Add( xtpControlButton, 2, "&Cut" )
   oButton2 = oTabFiles_Grp1:Add( xtpControlButton, 3, "&Copy" )
         
   oBtn1 := oTabFiles_Grp1:Add(  1, 9, "Format")
   oBtn1:Enabled = .F.
   
   oBtn2 := oTabFiles_Grp1:Add(  1, 8, "Delete")
   oExitBtn := oTabFiles_Grp1:Add(  xtpControlButton, 7, "Exit")
           
   
   oTabFiles_Grp2 := oTabFiles:Groups:AddGroup( "&Font", 1)
 
   oButton3 = oTabFiles_Grp2:Add( xtpControlButton, 4, NIL )
   oButton4 = oTabfiles_Grp2:Add( xtpControlButton, 3, "" )
   oButton4:SetIconSize( 64,64 )
   oButton4:Width = 70
   oButton4:Height = 70
   
       
   oTabEdit  = oRb:InsertTab( 1, "&Edit" )  
   
   oTabBuild = oRb:InsertTab( 2, "&Build" )
   oTabBuild:Color = 5  
   oTable_Grp := oTabBuild:Groups:AddGroup( "&Show/Hide", 5025)
   oTable_Grp:Add( 9, 2807, "Ruler" )
   oTable_Grp:Add( 9, 2808, "GridLines" )
   oTable_Grp:Add( 9, 2809, "Properties" )
   oTable_Grp:Add( 9, 2810, "Document Map" )
   oTable_Grp:Add( 9, 2811, "Thumbnails" )
   oTable_Grp:Add( 9, 2812, "Document Action Bar" )
   
   oControlOptions := oRb:Controls:Add( 2, 0, "Options")
   oControlOptions:Flags = 1  && xtpFlagRightAlign

   oControl := oControlOptions:CommandBar:Controls:Add( 2, 0, "Styles")
   oControl:CommandBar:Controls:Add( 1, 3000, "Blue"   )
   oControl:CommandBar:Controls:Add( 1, 3001, "Black"  )
   oControl:CommandBar:Controls:Add( 1, 3003, "Silver" )
   oControl:CommandBar:Controls:Add( 1, 3002, "Aqua"   )

   oControlPopup := oControlOptions:CommandBar:Controls:Add( 2, 0, "Font", -1, .F.)
   oControlPopup:CommandBar:Controls:Add( 11, 32883, "System Default", -1, .F.)

   oControl := oControlPopup:CommandBar:Controls:Add( 11, 32884, "Normal", -1, .F.)
   oControl:BeginGroup = .T.
   oControlPopup:CommandBar:Controls:Add( 11, 32885, "Large", -1, .F.)
   oControlPopup:CommandBar:Controls:Add( 11, 32886, "Extra Large", -1, .F.)

   oControl := oControlPopup:CommandBar:Controls:Add( 1, 32887, "Auto Resize Icons", -1, .F.)
   oControl:BeginGroup = .T.

   oControlOptions:CommandBar:Controls:Add( 1, 3004, "Right To Left" )
   oControlOptions:CommandBar:Controls:Add( 1, 3005, "Animation" )

   oControlAbout := oRb:Controls:Add( 1, 4000, "&About")
   oControlAbout:Flags = 1  && xtpFlagRightAlign
     
   
   AAdd( aButtons, oButton1 )
   AAdd( aButtons, oButton2 )
   AADD( aButtons, oQBtn1 )
   AADD( aButtons, oQBtn2 )
   AADD( aButtons, oQBtn3 )  
   AADD( aButtons, oExitBtn )
   AADD( aButtons, oExitBtn2 )
   AADD( aButtons, oControlAbout )
   AADD( aButtons, oPrnSetup )
     
   
   oButton1:Caption = "FiveWin power!"
   oButton1:TooltipText = "Ribbonbar for FWH"
     
   ACTIVATE WINDOW oWnd
     
return nil

function RibbonBarEvent( cEvent, aParams, pParams, aButtons, oWnd )

   do case
      case cEvent == "Execute" .and. Len( aButtons ) > 0
           do case
              case aButtons[ 1 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "Button 1" )
                   
              case aButtons[ 2 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "Button 2" )

              case aButtons[ 3 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "From Quick Access Button 1" )

              case aButtons[ 4 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "From Quick Access Button 2" + CRLF + "FIVEWIN SHARING POWER" )

              case aButtons[ 5 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "From Quick Access Button 3" )
                   
              case aButtons[ 6 ]:Id == aParams[ 1 ]:Id
                   oWnd:End()      
                               
              case aButtons[ 7 ]:Id == aParams[ 1 ]:Id
                   oWnd:End()

              case aButtons[ 8 ]:Id == aParams[ 1 ]:Id
                   MsgInfo( "FWH's ActiveX Power support Codejock", "About Codejock" )      
                   
              case aButtons[ 9 ]:Id == aParams[ 1 ]:Id
                   PrinterSetup()  
           endcase        
   endcase        
   
return nil
 


Muito obrigado :D :D :D
Obrigado, Regards, Saludos

Rossine.

Harbour and Harbour++
Rossine
 
Posts: 344
Joined: Tue Oct 11, 2005 11:33 am
Top

Re: Erro com 9.07

Postby Antonio Linares » Sat Aug 22, 2009 8:09 pm

bien! :-)

gracias por el ejemplo
regards, saludos

Antonio Linares
www.fivetechsoft.com
User avatar
Antonio Linares
Site Admin
 
Posts: 42203
Joined: Thu Oct 06, 2005 5:47 pm
Location: Spain
Top

Re: Erro com 9.07

Postby Rossine » Mon Aug 24, 2009 1:45 pm

Olá Antonio,

Ao tentar compilar os exemplos do fivewin com MSVC me é retornado estes erros:

Code: Select all  Expand view  RUN

Lines 3711, Functions/Procedures 3
Generating C source output to 'toolbar3.c'... Done.
Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 15.00.30729.01 for 80x86
Copyright (C) Microsoft Corporation.  All rights reserved.

Microsoft (R) Windows (R) Resource Compiler Version 6.1.6723.1
Copyright (C) Microsoft Corporation.  All rights reserved.

FiveHCM.lib(DIB.obj) : warning LNK4006: _HB_FUN_CREATEDIBITMAP already defined i
n FiveHM.lib(IMAGE.obj); second definition ignored
hbrtl.lib(tget.obj) : warning LNK4006: _HB_FUN_GETNEW already defined in FiveHM.
lib(TCLIPGET.obj); second definition ignored
hbwin.lib(win_dll.obj) : warning LNK4006: _HB_FUN_CALLDLL already defined in Fiv
eHCM.lib(CALLDLL.obj); second definition ignored
hbwin.lib(legacyco.obj) : warning LNK4006: _HB_FUN_MESSAGEBOX already defined in
 FiveHCM.lib(MSGS.obj); second definition ignored
FiveHCM.lib(MSGSAPI.obj) : error LNK2019: unresolved external symbol _hb_oleAnsi
ToWide referenced in function _HB_FUN_SENDWIDESTRINGMESSAGE
FiveHCM.lib(RICHEDIT.obj) : error LNK2019: unresolved external symbol _OleUIPast
eSpecialA@4 referenced in function _HB_FUN_REPASTESPECIAL
toolbar3.exe : fatal error LNK1120: 2 unresolved externals
* Linking errors *
 


Como corrigir isto ?
Obrigado, Regards, Saludos

Rossine.

Harbour and Harbour++
Rossine
 
Posts: 344
Joined: Tue Oct 11, 2005 11:33 am
Top

Re: Erro com 9.07

Postby Antonio Linares » Mon Aug 24, 2009 4:27 pm

Rossine,

Estas enlazando hbwin.lib ?
regards, saludos

Antonio Linares
www.fivetechsoft.com
User avatar
Antonio Linares
Site Admin
 
Posts: 42203
Joined: Thu Oct 06, 2005 5:47 pm
Location: Spain
Top

Re: Erro com 9.07

Postby Rossine » Mon Aug 24, 2009 4:52 pm

Olá Antonio,

Estas enlazando hbwin.lib ?


Sim.

Veja meu fluxo de compilação:

Code: Select all  Expand view  RUN

@ECHO OFF
CLS
ECHO ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
ECHO ³ FiveWin for Harbour 9.01 (MSVC++) Jan. 2009      Harbour development power ³Ü
ECHO ³ (c) FiveTech, 1993-2009     for Microsoft Windows 9X/NT/200X/ME/XP/Vista/7 ³Û
ECHO ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙÛ
ECHO ÿ ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß

if A%1 == A GOTO :SINTAX
if NOT EXIST %1.prg GOTO :NOEXIST

REM ***
REM *** Adaptado para uso do FWH & MSVC Express 2008 por Vailton Renato
REM ***

ECHO Compiling...

if exist %HB_PATH%\bin\harbour.exe    set hdir=%HB_PATH%\bin
if exist %HB_PATH%\bin\vc\harbour.exe set hdir=%HB_PATH%\bin\vc

if exist %HB_PATH%\lib\hbvm.lib       set hdirl=%HB_PATH%\lib
if exist %HB_PATH%\lib\vc\hbvm.lib    set hdirl=%HB_PATH%\lib\vc

"%hdir%\harbour" %1 /D__MSVC__ /n /i..\include;%HB_PATH%\include /w /p %2 %3 > comp.log
IF ERRORLEVEL 1 GOTO COMPILEERROR

"%CC_DIR%\bin\cl" -TC -W3 -c /GA %1.c > comp.log
IF ERRORLEVEL 1 GOTO COMPILEERROR

:ENDCOMPILE

IF EXIST %1.rc "%SDK_DIR%\bin\rc" -r -d__FLAT__ %1

echo %1.obj  > msvc.tmp
echo \fwh\lib\FiveHM.lib \fwh\lib\FiveHCM.lib  >> msvc.tmp
echo "%hdirl%\hbrtl.lib"  >> msvc.tmp
echo "%hdirl%\hbvm.lib"  >> msvc.tmp
echo "%hdirl%\gtgui.lib"  >> msvc.tmp
echo "%hdirl%\hblang.lib"  >> msvc.tmp
echo "%hdirl%\hbmacro.lib"  >> msvc.tmp
echo "%hdirl%\hbrdd.lib"  >> msvc.tmp
echo "%hdirl%\rddntx.lib"  >> msvc.tmp
echo "%hdirl%\rddcdx.lib"  >> msvc.tmp
echo "%hdirl%\rddfpt.lib"  >> msvc.tmp
echo "%hdirl%\hbsix.lib"  >> msvc.tmp
echo "%hdirl%\hbdebug.lib"  >> msvc.tmp
echo "%hdirl%\hbcommon.lib"  >> msvc.tmp
echo "%hdirl%\hbpp.lib"  >> msvc.tmp
echo "%hdirl%\hbcpage.lib"  >> msvc.tmp
echo "%hdirl%\hbwin.lib"  >> msvc.tmp
echo "%hdirl%\xhb.lib"   >> msvc.tmp

rem echo "%hdirl%\hbole.lib"  >> msvc.tmp
rem echo "%hdirl%\hbcplr.lib"  >> msvc.tmp

rem a funcao sndplaysound() precisa da lib abaixo.
echo "%SDK_DIR%\lib\winmm.lib" >> msvc.tmp

rem Uncomment these two lines to use Advantage RDD
echo "%hdirl%\rddads.lib" >> msvc.tmp
rem echo "%hdirl%\ace32.lib" >> msvc.tmp

echo "%CC_DIR%\lib\libcmt.lib"  >> msvc.tmp

echo "%SDK_DIR%\lib\kernel32.lib"  >> msvc.tmp
echo "%SDK_DIR%\lib\user32.lib"    >> msvc.tmp
echo "%SDK_DIR%\lib\gdi32.lib"     >> msvc.tmp
echo "%SDK_DIR%\lib\winspool.lib"  >> msvc.tmp
echo "%SDK_DIR%\lib\comctl32.lib"  >> msvc.tmp
echo "%SDK_DIR%\lib\comdlg32.lib"  >> msvc.tmp
echo "%SDK_DIR%\lib\advapi32.lib"  >> msvc.tmp
echo "%SDK_DIR%\lib\shell32.lib"   >> msvc.tmp
echo "%SDK_DIR%\lib\ole32.lib"     >> msvc.tmp
echo "%SDK_DIR%\lib\oleaut32.lib"  >> msvc.tmp
echo "%SDK_DIR%\lib\uuid.lib"      >> msvc.tmp
echo "%SDK_DIR%\lib\odbc32.lib"    >> msvc.tmp
echo "%SDK_DIR%\lib\odbccp32.lib"  >> msvc.tmp
echo "%SDK_DIR%\lib\iphlpapi.lib"  >> msvc.tmp
echo "%SDK_DIR%\lib\mpr.lib"       >> msvc.tmp
echo "%SDK_DIR%\lib\version.lib"   >> msvc.tmp
echo "%SDK_DIR%\lib\wsock32.lib"   >> msvc.tmp
echo "%SDK_DIR%\lib\msimg32.lib"   >> msvc.tmp

IF EXIST "%1.res" echo "%1.res" >> msvc.tmp

"%CC_DIR%\bin\link" @msvc.tmp /NODEFAULTLIB:LIBC.LIB /nologo /subsystem:windows /force:multiple /NODEFAULTLIB:libcmt

IF ERRORLEVEL 1 GOTO LINKERROR
ECHO * Application successfully built *
%1
GOTO EXIT
ECHO

rem delete temporary files
@del %1.c
@del msvc.tmp

:COMPILEERROR
@qed comp.log
ECHO * Compiling errors *
GOTO EXIT

:LINKERROR
ECHO * Linking errors *
GOTO EXIT

:SINTAX
ECHO    SYNTAX: Build [Program]     {-- No especifiques la extensi¢n PRG
ECHO                                {-- Don't specify .PRG extension
GOTO EXIT

:NOEXIST
ECHO The specified PRG %1 does not exist

:EXIT

set hdir=
set hdirl=

Obrigado, Regards, Saludos

Rossine.

Harbour and Harbour++
Rossine
 
Posts: 344
Joined: Tue Oct 11, 2005 11:33 am
Top

Re: Erro com 9.07

Postby Antonio Linares » Mon Aug 24, 2009 7:00 pm

Rossine,

Comprueba que la función esté dentro de hbwin.lib

Puedes hacerlo usando el Total Commander en su opción de búsqueda en ficheros:
Image
regards, saludos

Antonio Linares
www.fivetechsoft.com
User avatar
Antonio Linares
Site Admin
 
Posts: 42203
Joined: Thu Oct 06, 2005 5:47 pm
Location: Spain
Top

Re: Erro com 9.07

Postby Rossine » Mon Aug 24, 2009 7:25 pm

Olá antonio,

Veja que dentro de hbwin.lib compilado para msvc eu tenho "hb_oleAnsiToWide" e não "_hb_oleAnsiToWide"

Image
Obrigado, Regards, Saludos

Rossine.

Harbour and Harbour++
Rossine
 
Posts: 344
Joined: Tue Oct 11, 2005 11:33 am
Top

Re: Erro com 9.07

Postby Antonio Linares » Tue Aug 25, 2009 12:14 am

Rossine,

Esa librería parece estar construida en modo C++.

Usa la version en contruida para C, no para C++.
regards, saludos

Antonio Linares
www.fivetechsoft.com
User avatar
Antonio Linares
Site Admin
 
Posts: 42203
Joined: Thu Oct 06, 2005 5:47 pm
Location: Spain
Top

Re: Erro com 9.07

Postby Rossine » Tue Aug 25, 2009 11:57 am

Olá Antonio,

Usa la version en contruida para C, no para C++.


Mas onde achar esta LIB pois harbour é que constrói ela para mim
Obrigado, Regards, Saludos

Rossine.

Harbour and Harbour++
Rossine
 
Posts: 344
Joined: Tue Oct 11, 2005 11:33 am
Top

Re: Erro com 9.07

Postby Antonio Linares » Tue Aug 25, 2009 2:30 pm

Rossine,

From http://sourceforge.net/projects/harbour-project/files/ you can download version 1.0.1:
http://sourceforge.net/projects/harbour-project/files/binaries-windows/1.0.1/harbour-1.0.1-win32-msvs2008.zip/download
Please notice that on the same website there is a ...CPP version too.

They have not provided a 2.0 version yet. Please review INSTALL in Harbour folder to build it.

We can help you if you need it
regards, saludos

Antonio Linares
www.fivetechsoft.com
User avatar
Antonio Linares
Site Admin
 
Posts: 42203
Joined: Thu Oct 06, 2005 5:47 pm
Location: Spain
Top
Previous
Post a reply

Return to FiveWin para Harbour/xHarbour

Who is online

Users browsing this forum: No registered users and 49 guests

Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group