Adir() varios tipos de ficheros (Solucionado)

[JoseLuis]

Buenas

Para seleccionar de un directorio los archivos jpg, hacemos:

Code: Select all  Expand view

Ficheros := Array( ADir( Publicas:cUnidad+"*.jpg" ) )

Pero si quiero seleccionar jpg y pdf , como lo hago?

[karinha]

Mira se ayuda:

https://forums.fivetechsupport.com/viewtopic.php?f=3&t=42468&p=255377&hilit=DIRECTORYRECURSE&sid=0f1daade43d96bbf95801bdd85a5b0e0&sid=13155b273d2d9de35218742e39991594#p255377

https://forums.fivetechsupport.com/viewtopic.php?f=3&t=40919&p=245088&hilit=DIRECTORYRECURSE&sid=0f1daade43d96bbf95801bdd85a5b0e0&sid=13155b273d2d9de35218742e39991594#p245088

https://forums.fivetechsupport.com/viewtopic.php?f=6&t=40329&p=240871&hilit=DIRECTORYRECURSE&sid=0f1daade43d96bbf95801bdd85a5b0e0&sid=13155b273d2d9de35218742e39991594#p240871

https://forums.fivetechsupport.com/viewtopic.php?f=3&t=36560&p=230666&hilit=directoryrecurse&sid=0f1daade43d96bbf95801bdd85a5b0e0&sid=13155b273d2d9de35218742e39991594#p230666

https://forums.fivetechsupport.com/viewtopic.php?f=6&t=11211&p=55219&hilit=aFindFile&sid=0f1daade43d96bbf95801bdd85a5b0e0&sid=13155b273d2d9de35218742e39991594#p55219

http://fivewin.com.br/index.php?/topic/20353-como-identificar-pasta-aleat%C3%A3%C2%B3ria/&tab=comments#comment-42950

Regards, saludos.

[cmsoft]

Otra opcion:

Code: Select all  Expand view

#include "FiveWin.ch"
function Main()  
    local ficheros := {}
    // Con todos los datos del fichero
    AEval(Directory(".\*.jpg"), {|x| Aadd(ficheros,x)})
    AEval(Directory(".\*.pdf"), {|x| Aadd(ficheros,x)})
    xbrowse(ficheros)
    // Solo el nombre del fichero
    AEval(Directory(".\*.jpg"), {|x| Aadd(ficheros,x[1])})
    AEval(Directory(".\*.pdf"), {|x| Aadd(ficheros,x[1])})
    xbrowse(ficheros)
return nil
 

[Jimmy]

hi,

try this CODE from HMG Forum

Code: Select all  Expand view

  aDir := HB_DirScanM( cPath, { "*.bmp", "*.jpg", "*.jpeg", "*.png", "*.gif", "*.tif", "*.tiff", "*.wmf", "*.emf" }, "", .T. )

it can recursive get all those Image Type

Code: Select all  Expand view

FUNCTION hb_DirScanM( cPath, aFileMask, cAttr, lrecursiv )
RETURN hb_DoScanM( hb_DirSepAdd( hb_defaultValue( cPath, "" ) ), ;
                   IIF( HB_ISARRAY( aFileMask ), aFileMask, IIF( HB_ISSTRING( aFileMask ), { aFileMask }, { hb_osFileMask() } ) ), ;
                   hb_defaultValue( cAttr, "" ), ;
                   hb_ps(), lrecursiv )

Code: Select all  Expand view

STATIC FUNCTION hb_doScanM( cPath, aMask, cAttr, cPathSep, lrecursiv )
LOCAL aFile
LOCAL lMatch
LOCAL aResult := {}

   DEFAULT lrecursiv := .T.

   FOR EACH aFile IN hb_vfDirectory( cPath + hb_osFileMask(), cAttr + IF( lrecursiv, "D", "" ) )
      lMatch := .F.
      AEVAL( aMask, { | x | IIF( HB_ISSTRING( x ), lMatch := hb_FileMatch( aFile[ F_NAME ], x ) .OR. lMatch, Nil ) } )
      IF "D" $ aFile[ F_ATTR ]
         IF lMatch .AND. "D" $ cAttr
            IF lrecursiv = .T.
               AADD( aResult, aFile )
            ENDIF
         ENDIF
         IF !( aFile[ F_NAME ] == "." .OR. aFile[ F_NAME ] == ".." .OR. aFile[ F_NAME ] == "" )
            AEVAL( hb_DoScanM( cPath + aFile[ F_NAME ] + cPathSep, aMask, cAttr, cPathSep ), ;
                   { | x | x[ F_NAME ] := aFile[ F_NAME ] + cPathSep + x[ F_NAME ], ;
                   AADD( aResult, x ) } )
         ENDIF
      ELSEIF lMatch
         AADD( aResult, aFile )
      ENDIF
   NEXT

RETURN aResult

[JoseLuis]

Muchas gracias por vuestra ayuda