GroupHeader en la TReport (Antonio/Mr. Rao)

[Armando]

Hola colegas:

En la clase TReport ¿existe la posibilidad de poner un título que abarque dos o mas columnas?
algo similar a SetGroupHeader de la clase xBrowse

Code: Select all  Expand view

               :SetGroupHeader( "E N T R A D A S",04,05 )
               :SetGroupHeader( "S A L I D A S",06,07 )
 

Si aún no es posible, ¿qué tan factible es incorporar esta mejora a la clase?

Saludos

[nageswaragunupudi]

Possible.
Test pogram:

Code: Select all  Expand view

#include "fivewin.ch"

function Main()

   local oRep

   USE CUSTOMER
   REPORT oRep PREVIEW

   COLUMN TITLE "SlNo" DATA FIELD->ID GRID
   COLUMN TITLE "First" GROUPTITLE "NAME" DATA FIELD->FIRST
   COLUMN TITLE "Last"  GROUPTITLE "NAME" DATA FIELD->LAST
   COLUMN TITLE "Age" DATA FIELD->AGE GRID
   COLUMN TITLE "City"  GROUPTITLE "ADDRESS" DATA FIELD->CITY
   COLUMN TITLE "Zip"   GROUPTITLE "ADDRESS" DATA FIELD->ZIP
   COLUMN TITLE "State" GROUPTITLE "ADDRESS" DATA FIELD->STATE
   COLUMN TITLE "SALARY" DATA FIELD->SALARY GRID

   ENDREPORT
   oRep:lJoin := .t.

   ACTIVATE REPORT oRep

return nil
 

[Armando]

Mr. Rao:

I can already see that it is possible, thank you very much

This is my code But I can't get the vertical lines

Code: Select all  Expand view

      REPORT oReporte CAPTION "Diferencias entre físico y teórico" PREVIEW;
         HEADER AllTrim(oApp:cRazonSocial),;
         "",;
         "Diferencias entre físico y teórico",;
         "" CENTER;
         TITLE "Fecha: "+Date2Txt(DATE()),;
         "Hoja No:"+STR(oReporte:nPage,3);
         FONT aFnt[1],aFnt[2],aFnt[3];
         PEN aPen[1],aPen[2]

         COLUMN TITLE "Folio"                                      DATA oRsMrb:Fields("MAR_FOL"):Value SIZE  5 RIGHT PICTURE "@Z 9999999"
         COLUMN TITLE "Marca"                                      DATA oRsMrb:Fields("MAR_DES"):Value SIZE 12 LEFT
         COLUMN TITLE "Parte"                                      DATA oRsMrb:Fields("MAR_PAR"):Value SIZE 15 LEFT
         COLUMN TITLE "Descripción"                            DATA oRsMrb:Fields("PAR_DES"):Value SIZE 30 LEFT
         COLUMN TITLE "Ultimo.Cos."                            DATA oRsMrb:Fields("MAR_ULC"):Value SIZE 08 RIGHT PICTURE "@Z 999,999.99"
         COLUMN TITLE "Unidades"       GROUPTITLE "TEORICO"       DATA oRsMrb:Fields("MAR_TEO"):Value SIZE 07 RIGHT PICTURE "@Z 9,999,999"   TOTAL
         COLUMN TITLE "Valores"    GROUPTITLE "TEORICO"       DATA oRsMrb:Fields("MAR_VAT"):Value SIZE 11 RIGHT PICTURE "@Z 999,999.99"  TOTAL
         COLUMN TITLE "Unidades"       GROUPTITLE "FISICO"        DATA oRsMrb:Fields("MAR_FIS"):Value SIZE 07 RIGHT PICTURE "@Z 9,999,999"   TOTAL
         COLUMN TITLE "Valores"    GROUPTITLE "FISICO"        DATA oRsMrb:Fields("MAR_VAF"):Value SIZE 11 RIGHT PICTURE "@Z 999,999.99"  TOTAL
         COLUMN TITLE "Unidades"       GROUPTITLE "DIFERENCIAS"   DATA oRsMrb:Fields("MAR_DIU"):Value SIZE 07 RIGHT PICTURE "@Z 9,999,999"   TOTAL
         COLUMN TITLE "Valores"    GROUPTITLE "DIFERENCIAS"   DATA oRsMrb:Fields("MAR_DIV"):Value SIZE 11 RIGHT PICTURE "@Z 999,999.99"  TOTAL
      ENDREPORT

      oReporte:lJoin := (.T.)

      IF oReporte:lCreated
         oReporte:SetTxtColor(CLR_BLACK,1)  // Color del texto de la hoja default NEGRO
         oReporte:SetTxtColor(CLR_HRED,2)       // Color de encabezado y totales del grupo
         oReporte:SetTxtColor(CLR_HRED,3)       // Color para el primer titulo del encabezado
         oReporte:SetPenColor(CLR_HBLUE)        // Color para las líneas
         oReporte:oHeader:aFont[1] := {||3}

         oReporte:oTitle:aPad[1] := RPT_LEFT
         oReporte:oTitle:aPad[2] := RPT_RIGHT

         oReporte:lPageTotal     := (.F.)
         oReporte:bPostEnd         := { || Totales(oReporte)}

         oReporte:bSkip          := { || (nLinea++, oRsMrb:MoveNext())}
      ENDIF

      ACTIVATE REPORT oReporte;
         ON STARTPAGE Alinea(oReporte,1,2);
         WHILE nLinea <= nHasta
 

Could you give me a hand
Best regards

[nageswaragunupudi]

If we add the clause GRID to the COLUMN definition, vertical lines are drawn on both sides of the column.

[Armando]

Thank you Mr. Rao:

Now everything works fine

Regards