Metro desde recursos?

[Armando]

Amigos del foro:

Es posible que los BMP de los botones en la clase METRO sean desde recursos?

Saludos

[Antonio Linares]

Estimado Armando,

Sí, de hecho ya está implementado para el próximo build de FWH:

Code: Select all  Expand view  RUN

METHOD AddButton( cCaption, nClrText, nClrPane, lLarge, cImgName, bAction ) CLASS TMetro

   local oBtn
   local nX := ::nOriginX + ( ::nRow * ( ::nBtnHeight + 8 ) )
   local nY := ::nOriginY + ( ::nCol * ( ::nBtnWidth + 8 ) )
   
   DEFAULT lLarge := .F.
   
   if File( cImgName )
      @ nX, nY BTNBMP oBtn ;
         SIZE ( ::nBtnWidth * If( lLarge, 2, 1 ) ) + If( lLarge, 8, 0 ), ::nBtnHeight ;
         OF ::oWnd PROMPT cCaption NOBORDER FILENAME cImgName
   else  
      @ nX, nY BTNBMP oBtn ;
         SIZE ( ::nBtnWidth * If( lLarge, 2, 1 ) ) + If( lLarge, 8, 0 ), ::nBtnHeight ;
         OF ::oWnd PROMPT cCaption NOBORDER RESOURCE cImgName
   endif  
     
   oBtn:bAction = bAction  
     
   oBtn:SetColor( nClrText, nClrPane )    
   
   AAdd( ::aButtons, oBtn )
   
   ::nCol++
   if lLarge
      ::nCol++
   endif  
   if ( ATail( ::aButtons ):nLeft + ATail( ::aButtons ):nWidth ) > ( ::nOriginY * 4 ) + 50
      ::nRow++
      ::nCol = 0
   endif  
   
return nil    
 

@ nX, nY BTNBMP oBtn ;
SIZE ( ::nBtnWidth * If( lLarge, 2, 1 ) ) + If( lLarge, 8, 0 ), ::nBtnHeight ;
OF ::oWnd PROMPT cCaption NOBORDER RESOURCE cImgName

[Armando]

Master Antonio:

Muchas gracias, empezaré a ahorrar.

Saludos

[Antonio Linares]

Puedes modificar la clase tu mismo con ese código

[Armando]

Master:

Soy ñoño es eso, pero lo intentaré.

Saludos

[Armando]

Maestro Antonio:

Lo logré

Ahora, será posible lo mismo pero para el BACKGROUND ?

Code: Select all  Expand view  RUN

   DEFINE METRO oMetro ;
      TITLE "AppRpt, Archivos para contabilidad" ;
      BACKGROUND ".\earth.bmp"

Saludos y muchas gracias

[Antonio Linares]

Solo tienes que modificar estas líneas en el método New():

Code: Select all  Expand view  RUN

  if File( cFileName )
      ::hBitmap = ReadBitmap( 0, cFileName )
   else
      ::hBitmap = LoadBitmap( GetResources(), cFileName )  
   endif    

Lo incluimos también para el próximo build!

[Armando]

Master:

Grande !.

Por el momento con eso tengo suficiente.

Saludos