Como evitar abrir 2 veces la misma ventana child

[jose_murugosa]

Buenas tardes, queridos amigos del foro.
Tengo una consulta:

Tengo una ventana mdi con menú.
Por medio del menú abro diferentes ventanas child que hacen cosas diferentes.
¿Cómo puedo hacer para que cuando selecciono del menú una opción elegida previamente en lugar de abrir una nueva ventana child con lo mismo, ponga foco en la ventana correspondiente que ya está abierta?
¿Es posible hacer esto?

Gracias desde ya por vuestra atención.

[sysctrl2]

a ver si es lo que buscas
saludos
https://forums.fivetechsupport.com/view ... nd+%3D+NIL

[jvtecheto]

Hola Jose.

Yo lo que hago es que desabilito las opciones que abren la ventana, como normalmente lo tenemos en un menu y en un
boton de una barra.
En la funcion que llamo a la ventana hija ejemplo

Code: Select all | Expand

ObrasBrw( oMenuObr, oObra )
 

las variables son estaticas y las tengo en el prg. principal
entonces dentro de la funcion las desabilito.

Code: Select all | Expand

oMenuObr:Disable()
oObra:Disable()
 

y compruebo que quedaran activas cuando cerrare la ventana ...

Code: Select all | Expand

ACTIVATE WINDOW OWndObr VALID ( oMenuObr:Enable(), oObra:Enable()....)
 

A mi me funciona bien.

Saludos.

Jose.

[Willi Quintana]

Mi estimado,,,
Antes de abrir la ventana declara un variable static. espero que captes la idea

Code: Select all | Expand

static nNumWin := 0

lSalir := .f.

If nNumWin > 0
   Return(Nil)
EndIf
DEFINE WINDOW oWndM MDI  ...............
           REDEFINE BTNBMP. oSalir ,,,,,,,,,,,,,, ACTION (lSalir := .t., oWndM:End())
ACTIVATE WINDOW ON INIT (nNumWin++) VALID lSalir
If lSalir
  nNUmWin := 0
EndIf
Return(NIl)
 

[nageswaragunupudi]

Sample:

Code: Select all | Expand

#include "fivewin.ch"

function Main()

   local oWnd, oBar

   DEFINE WINDOW oWnd MDI
   DEFINE BUTTONBAR oBar OF oWnd SIZE 100,32 2007
   DEFINE BUTTON OF oBar PROMPT "Child-1" CENTER ACTION Child1()
   DEFINE BUTTON OF oBar PROMPT "Child-2" CENTER ACTION Child2()
   ACTIVATE WINDOW oWnd

return nil

function Child1()

   static oWnd

   if oWnd != nil
      oWnd:Activate()
      return nil
   endif

   DEFINE WINDOW oWnd MDICHILD OF WndMain() TITLE "CHILD-1"
   oWnd:SetColor( 0, CLR_WHITE )
   oWnd:bPainted := { || oWnd:SayText( "CHILD WINDOW-1" ) }
   oWnd:bPostEnd := { || oWnd := nil }
   ACTIVATE WINDOW oWnd

return nil

function Child2()

   static oWnd

   if oWnd != nil
      oWnd:Activate()
      return nil
   endif

   DEFINE WINDOW oWnd MDICHILD OF WndMain() TITLE "CHILD-2"
   oWnd:SetColor( 0, CLR_WHITE )
   oWnd:bPainted := { || oWnd:SayText( "CHILD WINDOW-2" ) }
   oWnd:bPostEnd := { || oWnd := nil }
   ACTIVATE WINDOW oWnd

return nil

[jose_murugosa]

Muchisimas gracias a todos por sus sugerencias y soluciones.
He logrado el objetivo gracias a Uds.
Es hermoso contar con este foro de amigos que tanto tiempo dedican a ayudarnos.
Muchiiiiiisiiiiimmmmmaaaaaas GRACIAS!!!!