SetClipboardData to UTF-8

[frose]

wondering how to set the clipboard data to UTF-8.
Using now:

Code: Select all | Expand

HB_CDPSELECT( "UTF8" )
FW_SetUnicode( .T. )
SetClipboardData( CF_TEXT, "Ärzte" )

cValue := GetClpData( CF_TEXT )
 

cValue is:

Code: Select all | Expand

Ärzte

Does someone know it, then please give me a hint.

[nageswaragunupudi]

Copying data correctly to clipboard but there is problem in pasting, i.e, GetClpData
We are looking to all the issues raised by you.

[karinha]

Code: Select all | Expand

// C:\FWH..\SAMPLES\FROSE3UT.PRG

#include "FiveWin.ch"

REQUEST HB_LANG_PT
REQUEST HB_CODEPAGE_PT850

static oWnd

FUNCTION Main()

   LOCAL oBar

   // Germany?
   HB_LANGSELECT( 'PT' )     // Default language is now Portuguese
   HB_SETCODEPAGE( "PT850" )

   FW_SetUnicode( .T. )

   // Harbour (not xHarbour) to display unicode filenames
   HB_SETCODEPAGE( "UTF8" )  // ???
   // HB_CDPSELECT( "UTF8" )

   DEFINE WINDOW oWnd TITLE "3D objects"

   DEFINE BUTTONBAR oBar _3D OF oWnd

   DEFINE BUTTON OF oBar ACTION BuildClip()

   SET MESSAGE OF oWnd TO "3D Objects" NOINSET CLOCK DATE KEYBOARD

   ACTIVATE WINDOW oWnd

RETURN NIL

FUNCTION BuildClip()

   LOCAL cList := ""
   LOCAL cText := "Ärzte"
   LOCAL oClp

   // Open Editor and CTRL+V
   DEFINE CLIPBOARD oClp OF oWnd

   oClp:SetText( cText )

   oClp:End()

   IF IsUtf8( cText ) // No comprendo. No funciona.

      ? cText

   ELSE

      QUIT

   ENDIF

RETURN NIL

// fin / end
 

[nageswaragunupudi]

Can you make a small bugfix in fwh\source\function\imgtxtio.prg
You see this code at line no: 3850

Code: Select all | Expand

      if !Empty( uData ) .and. IsTextUnicode( uData )

Please change it as

Code: Select all | Expand

      if !Empty( uData )

Then, please run this program:

Code: Select all | Expand

#include "fivewin.ch"

function Main()

   local cText, cPaste

   FW_SetUnicode( .T. )

   cText := "Ärzte"
   FW_CopyToClipBoard( cText )
   ? "Copied to ClipBoard " + cText
   cPaste := FW_GetClipboardData()
   ? "Copied : " + cText, "Pasted : " + cPaste, ;
     "Compare",cText == cPaste  

return nil

This is working correctly for me on many Unicode language texts.
Once this runs ok for you, please test with many different combinations of text and provide your valuable feedback.
Note: Hereafter please use the above functions

[Jimmy]

moin,

wondering how to set the clipboard data to UTF-8.
Using now:
Does someone know it, then please give me a hint.

try this

Code: Select all | Expand

#include "Fivewin.ch"
#define CF_TEXT 1
#define CF_UNICODETEXT 13

PROCEDURE MAIN
LOCAL cValue := "Hello"

    HB_CDPSELECT( "UTF8" )
    FW_SetUnicode( .T. )
    * SetClipboardData( CF_TEXT , "Ärzte" )
    CopyToClipboard( "Ärzte" )
    * ? cValue := GetClpData(CF_TEXT)
    ? cValue := TextFromClipboard()
RETURN

Code: Select all | Expand

FUNCTION CopyToClipboard( cText )
LOCAL oClip := TClipBoard() :New()

   IF oClip:Open()
      oClip:SetText( cText )
      oClip:Close()
   ENDIF

   oClip:End()
RETURN nil

Code: Select all | Expand

FUNCTION TextFromClipboard()
LOCAL cText := ""
LOCAL oClip := TClipBoard() :New()

   IF oClip:Open()
      cText := oClip:GetText()
      oClip:Close()

      IF CRLF $ cText
         cText := TRIM( STRTRAN( cText, CRLF, "" ) )
      ENDIF
   ENDIF

   oClip:End()
RETURN cText

[frose]

Can you make a small bugfix...

Almost ok:

Code: Select all | Expand

Ágota Kristóf
ängstlichen
Ärzte
Åsa Böker
Íngrid Betancourt
Ñejo
Ólafur Arnalds
Ölsardinen
Øresund Space Collective
überbewertet
Überblick
Анастасия Варнавская
벤자민 (Benzamin)
수지 Suzy

Hex codes:
C3 81 67 6F 74 61 20 4B 72 69 73 74 C3 B3 66 0D 0A C3 A4 6E 67 73 74 6C 69 63 68 65 6E 0D 0A C3 84 72 7A 74 65 0D 0A C3 85 73 61 20 42 C3 B6 6B 65 72 0D 0A C3 8D 6E 67 72 69 64 20 42 65 74 61 6E 63 6F 75 72 74 0D 0A C3 91 65 6A 6F 0D 0A C3 93 6C 61 66 75 72 20 41 72 6E 61 6C 64 73 0D 0A C3 96 6C 73 61 72 64 69 6E 65 6E 0D 0A C3 98 72 65 73 75 6E 64 20 53 70 61 63 65 20 43 6F 6C 6C 65 63 74 69 76 65 0D 0A C3 BC 62 65 72 62 65 77 65 72 74 65 74 0D 0A C3 9C 62 65 72 62 6C 69 63 6B 0D 0A D0 90 D0 BD D0 B0 D1 81 D1 82 D0 B0 D1 81 D0 B8 D1 8F 20 D0 92 D0 B0 D1 80 D0 BD D0 B0 D0 B2 D1 81 D0 BA D0 B0 D1 8F 0D 0A EB B2 A4 EC 9E 90 EB AF BC 20 28 42 65 6E 7A 61 6D 69 6E 29 0D 0A EC 88 98 EC A7 80 20 53 75 7A 79

I only found one term that has problems when combined with other terms that contain at least ONE multibyte character.
Alone ok:

Code: Select all | Expand

Þráinn Bertelsson

Hex codes:
C3 9E 72 E1 69 6E 6E 20 42 65 72 74 65 6C 73 73 6F 6E

Two other terms are ok:

Code: Select all | Expand

벤자민 (Benzamin)
Анастасия Варнавская

Hex codes:
EB B2 A4 EC 9E 90 EB AF BC 20 28 42 65 6E 7A 61 6D 69 6E 29 0D 0A D0 90 D0 BD D0 B0 D1 81 D1 82 D0 B0 D1 81 D0 B8 D1 8F 20 D0 92 D0 B0 D1 80 D0 BD D0 B0 D0 B2 D1 81 D0 BA D0 B0 D1 8F

Combined NOT ok:

Code: Select all | Expand

Þráinn Bertelsson
Анастасия Варнавская
벤자민 (Benzamin)

Hex codes:
C3 9E 72 E1 69 6E 6E 20 42 65 72 74 65 6C 73 73 6F 6E 0D 0A D0 90 D0 BD D0 B0 D1 81 D1 82 D0 B0 D1 81 D0 B8 D1 8F 20 D0 92 D0 B0 D1 80 D0 BD D0 B0 D0 B2 D1 81 D0 BA D0 B0 D1 8F 0D 0A EB B2 A4 EC 9E 90 EB AF BC 20 28 42 65 6E 7A 61 6D 69 6E 29

The order does not matter.

[frose]

One more.
Single terms ok:

Code: Select all | Expand

Thráinn Bertelsson

Hex codes:
54 68 72 C3 A1 69 6E 6E 20 42 65 72 74 65 6C 73 73 6F 6E

Code: Select all | Expand

Þráinn Bertelsson

Hex codes:
DE 72 E1 69 6E 6E 20 42 65 72 74 65 6C 73 73 6F 6E

Together not ok:

Code: Select all | Expand

Þráinn Bertelsson
Thráinn Bertelsson
Thrainn Bertelsson

Hex codes:
DE 72 E1 69 6E 6E 20 42 65 72 74 65 6C 73 73 6F 6E 0D 0A 54 68 72 C3 A1 69 6E 6E 20 42 65 72 74 65 6C 73 73 6F 6E 0D 0A 54 68 72 61 69 6E 6E 20 42 65 72 74 65 6C 73 73 6F 6E

[nageswaragunupudi]

Please run this program as it is:

Code: Select all | Expand

#include "fivewin.ch"

function main()

   local cText, cPaste
   local aText[ 4 ]

   FW_SetUnicode( .t. )

TEXT INTO aText[ 1 ]
Ágota Kristóf
ängstlichen
Ärzte
Åsa Böker
Íngrid Betancourt
Ñejo
Ólafur Arnalds
Ölsardinen
Øresund Space Collective
überbewertet
Überblick
Анастасия Варнавская
벤자민 (Benzamin)
수지 Suzy
ENDTEXT
   aText[ 2 ] := "Þráinn Bertelsson"

TEXT INTO aText[ 3 ]
벤자민 (Benzamin)
Анастасия Варнавская
ENDTEXT

TEXT INTO aText[ 4 ]
Þráinn Bertelsson
Анастасия Варнавская
벤자민 (Benzamin)
ENDTEXT
 

   FOR EACH cText IN aText
  
      FW_CopyToClipBoard( cText )
      cPaste := FW_GetClipBoardData()
 
     ? "Original Text :" + CRLF + ;
        cText + CRLF + ;
       "Pasted from Clipboard :" + ;
       cPaste + CRLF + ;
       "Compare : " + ;
       If( cText == cPaste, "EXACTLY EQUAL", "Diiferent" )

   NEXT

return nil

// USE THESE CLIPBOARD FUNCTIONS ONLY

static function FW_CopyToClipBoard( uValue, nFormat )

   local lCopied  := .f.

   if HB_ISPOINTER( uValue ) // assumes GDI+ Image object
      GDIPLUSImageToClipBoard( uValue )
      return .t.
   endif

   if uValue != nil
      if Empty( nFormat ) .and. HB_ISARRAY( uValue ) .and. ;
         AScan( uValue, { |u| ValType( u ) != "C" } ) == 0
            nFormat  := 15
      endif
      DEFAULT nFormat := If( HB_ISSTRING( uValue ), 1, ;
                         If( HB_ISNUMERIC( uValue ) .and. ISHBITMAP( uValue ), 2, nil ) )
      if Empty( nFormat )
         if ValType( uValue ) $ "AH"
            uValue   := FW_ValToExp( uValue )
         else
            uValue   := cValToChar( uValue )
         endif
         nFormat  := 1
      endif

      if nFormat != nil
         if OpenClipBoard( GetDeskTopWindow() )
            EmptyClipboard()
            if nFormat == 1 .and. IsUtf8( uValue )
               uValue    := utf8toutf16( uValue )
               if !( Right( uValue, 2 ) == Chr( 0 ) + Chr( 0 ) )
                  uValue    += ( Chr( 0 ) + Chr( 0 ) )
               endif
               lCopied  := SetClipboardData( 13, uValue )
            elseif nFormat == 15
               if !HB_ISARRAY( uValue )
                  uValue   := { uValue }
               endif
               lCopied  := SetClipboardData( 15, uValue )
            else
               lCopied  := SetClipboardData( nFormat, uValue )
            endif
            CloseClipboard()
         endif
      endif
   endif

return lCopied

//----------------------------------------------------------------------------//

static function FW_GetClipBoardData( nFormat ) // [@nFormat]

   local uData, lCopied

   if nFormat == 3; nFormat := 14; endif
   if !Empty( nFormat := GetClipContentFormat( nFormat ) )
      if OpenClipBoard( GetDeskTopWindow() )
         uData := GetClpData( nFormat )
         EmptyClipboard()
         CloseClipboard()
      endif
   endif

   do case
   case nFormat == 15   // CF_HDROP
      uData := If( Empty( uData ), {}, DragQueryFiles( uData ) )
   case nFormat == 13    // CF_UNICODETEXT
      if !Empty( uData ) //.and. IsTextUnicode( uData )
         uData := UTF16TOUTF8( uData )
      endif
   endcase

return uData

//----------------------------------------------------------------------------//
 

Please use an editor which treats all UTF8 text correctly for Unicode programs

[nageswaragunupudi]

I tried to copy your text from the webpage to notepad (utf8).


Second line not copied correctly.
What is happening?

[nageswaragunupudi]

Mr Froze
In your postings above, you were also posting hex codes.
May I know how were you deriving those hex codes?

[frose]

Second line not copied correctly.
What is happening?

Mr. Rao,
yes, it must be something if the values are extracted from a TXBrowse!
I will explore this and come back to it.

[frose]

May I know how were you deriving those hex codes?

Code: Select all | Expand

StrToHex( cVar1, " " )

[frose]

Please run this program as it is:
...

Yes all compares are 'exactly equal', so that we can assume, that the clipboard runs well under UTF-8

[nageswaragunupudi]

Please run this program as it is:
...

Yes all compares are 'exactly equal', so that we can assume, that the clipboard runs well under UTF-8

From now onwards, please use the above two functions.
I noticed a small bug in TClipboard class and do not use it till it is fixed (for Unicode only)
Both the above functions are available in FWH2204 but the second function requires a fix. Fixed in the version under release.

[frose]

Second line not copied correctly.
What is happening?

Mr. Rao,
yes, it must be something if the values are extracted from a TXBrowse!
I will explore this and come back to it.

Have cleaned up the source code, now it works