2010 style

[Daniel Garcia-Gil]

Hello:

is a big pleasure present to all the next release of fivewin with style 2010

Ribbon, Menu and Message Bar

Ribbon, no change is required, only add 2010 to comamnd, new clause STARTBTN <nOpcion>, will show a "start" button (blue)

Code: Select all  Expand view  RUN

  DEFINE RIBBONBAR ::oRBar WINDOW ::oWnd ;
          PROMPT "Archivo", ;
                 "Configuración", ;
                 "Ficheros", ;
                 "Informes", ;
                 "Ayudas" HEIGHT 133 OPTION 2 2010 STARTBTN 1

Menu: is possible combine both style 2010 and 2007

Code: Select all  Expand view  RUN

  MENU oMenu 2010
      MENUITEM "&Archivo"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1"
            MENUITEM "Item 2" MESSAGE "Item 2"
         ENDMENU

      MENUITEM "&Edicion"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1 "            
            MENUITEM "Item 2" MESSAGE "Item 2 "
            MENUITEM "Item 3" MESSAGE "Item 3"
            MENUITEM "Item 4" MESSAGE "Item 4"            
            SEPARATOR
            MENUITEM "Item 5" MESSAGE "Item 5"                        
               MENU 2007
                  MENUITEM "Item 1" MESSAGE "Item 1"
                  MENUITEM "Item 2" MESSAGE "Item 2"
               ENDMENU            
         ENDMENU

MessageBar: only add 2010 to command

Code: Select all  Expand view  RUN

SET MESSAGE OF ::oWnd TO "Testing Class RibbonBar Style 2010 and Message Bar 2010 colors" ;
      CENTERED CLOCK KEYBOARD 2010

[Daniel Garcia-Gil]

Sample

http://www.sitasoft.net/fivewin/samples/rb2010.zip

[ukservice]

Daniel,

Thank you. Great news!!!.

What about Buttonbmp and Skinbuttons?

Also. in your sample, I click con Archivo and I get an error:

Code: Select all  Expand view  RUN

Application
===========
   Path and name: C:\Users\REPC~1\AppData\Local\Temp\Rar$EX00.466\ribbon.exe (32 bits)
   Size: 2,035,712 bytes
   Time from start: 0 hours 0 mins 1 secs
   Error occurred at: 05/21/11, 13:12:37
   Error description: Error BASE/1004  No exported method: HIDE
   Args:
     [   1] = U  

Stack Calls
===========
   Called from:  => HIDE(0)
   Called from: ribbon.prg => (b)TAPPLICATION_BACKSTAGE(522)
   Called from: .\prg\TRIBBON.PRG => TRIBBONBAR:BACKSTAGE(788)
   Called from: ribbon.prg => (b)TAPPLICATION_BUILDRIBBON(245)
   Called from: .\prg\TRIBBON.PRG => TRIBBONBAR:SETOPTION(1002)
   Called from: .\prg\TRIBBON.PRG => TRIBBONBAR:LBUTTONDOWN(881)
   Called from: .\source\classes\CONTROL.PRG => TCONTROL:HANDLEEVENT(1492)
   Called from: .\prg\TRIBBON.PRG => TRIBBONBAR:HANDLEEVENT(1030)
   Called from: .\prg\WINDOW.PRG => _FWH(3428)
   Called from:  => WINRUN(0)
   Called from: .\prg\WINDOW.PRG => TWINDOW:ACTIVATE(992)
   Called from: ribbon.prg => TAPPLICATION:RUN(70)
   Called from: ribbon.prg => MAIN(19)

System
======
   CPU type: Pentium(R) Dual-Core  CPU      E5500  @ 2.80GHz 2800 Mhz
   Hardware memory: 1920 megs

   Free System resources: 90 %
        GDI    resources: 90 %
        User   resources: 90 %

   Compiler version: Harbour 2.1.0rc2 (Rev. 16334)
   Windows version: 6.1, Build 7600

   Windows total applications running: 4
      1
      2 AutoComplete
      3 SysFader
      4 Default IME
   
   Procedure     Type   Value
   ==========================
   HIDE
     Param   1:    O    Class: ERROR
   (b)TAPPLICATION_BACKSTAGE
     Local   1:    U    
     Local   2:    N    0
   TRIBBONBAR:BACKSTAGE
     Param   1:    O    Class: TRIBBONBAR
   (b)TAPPLICATION_BUILDRIBBON
   TRIBBONBAR:SETOPTION
     Param   1:    N    1
     Param   2:    N    2
   TRIBBONBAR:LBUTTONDOWN
     Param   1:    N    1
     Local   1:    N    2
   TCONTROL:HANDLEEVENT
     Param   1:    N    17
     Param   2:    N    52
     Param   3:    N    1
     Local   1:    N    1
     Local   2:    N    15
   TRIBBONBAR:HANDLEEVENT
     Param   1:    N    513
     Param   2:    N    1
     Param   3:    N    1114164
     Local   1:    U    
   _FWH
     Param   1:    N    513
     Param   2:    N    1
     Param   3:    N    1114164
     Local   1:    O    Class: TRIBBONBAR
   WINRUN
     Param   1:    N    1114164
     Param   2:    N    513
     Param   3:    N    1
     Param   4:    N    1114164
     Param   5:    N    2
     Local   1:    O    Class: TRIBBONBAR
   TWINDOW:ACTIVATE
     Param   1:    N    918886
   TAPPLICATION:RUN
     Param   1:    C    "MAXIMIZED"
     Param   2:    U    
     Param   3:    U    
     Param   4:    U    
     Param   5:    U    
     Param   6:    U    
     Param   7:    U    
     Param   8:    U    
     Param   9:    U    
     Param  10:    U    
     Param  11:    U    
     Param  12:    U    
     Param  13:    U    
     Param  14:    U    
     Param  15:    U    
     Param  16:    U    
     Param  17:    U    
     Param  18:    U    
     Param  19:    U    
     Local   1:    O    Class: TWINDOW
     Local   2:    U    
     Local   3:    U    
   MAIN

Linked RDDs
===========
   DBF
   DBFFPT
   DBFBLOB
   DBFNTX

DataBases in use
================

Classes in use:
===============
     1 ERROR
     2 HBCLASS
     3 HBOBJECT
     4 TAPPLICATION
     5 TWINDOW
     6 TMENU
     7 TMENUITEM
     8 TBRUSH
     9 TFONT
    10 TCONTROL
    11 TRIBBONBAR
    12 TRPANEL
    13 TBACKSTAGE
    14 TBACKSTAGEOPTION
    15 TRBGROUP
    16 TRBTN
    17 TMSGBAR
    18 TRECT
    19 TMSGITEM
    20 TTIMER
    21 TREG32

Memory Analysis
===============
      266 Static variables

   Dynamic memory consume:
      Actual  Value:          0 bytes
      Highest Value:          0 bytes


[Daniel Garcia-Gil]

Hello

yes is a mistake in sample, no in source code... i'll fix and upload the new sample

[ukservice]

Thank you very much for quick support and reaction.

What about Buttonbmp and Skinbuttons?.

[Francisco Horta]

que tal Daniel,

comp puedo ponerle un degradado a una message bar?
salu2
paco

[Daniel Garcia-Gil]

Francisco

El nuevo estilo estara disponible en la proxima version de fivewin...

[Daniel Garcia-Gil]

Thank you very much for quick support and reaction.

What about Buttonbmp and Skinbuttons?.

what do you know about it?

you can build your own skin, is very easy with skinbutton

[ukservice]

Hello Daniel,

In BTNBMP, how do I set 2010 style?.

Thank you.

[Daniel Garcia-Gil]

Hello

Fivewin have 4 different class to design a button, TButton, TButtonbmp, TBtnbmp, TRbbtn

each one have a different behaviors and different way to customizable

to BtnBmp by programing we can not build all features of 2010 style, instead you can use TButton, TButtonbmp (skinbutton), TRbbtn (changing colors data )

[ukservice]

Daniel,

And why don´t you modify BTNBMP to accept 2010 clause?.

Thank you.

[norberto]

Hi Daniel, can you share the code of rb2010 sample? thanks

[Daniel Garcia-Gil]

Hello

sure...

Code: Select all  Expand view  RUN

#include "fivewin.ch"
#include "ribbon.ch"
#include "xbrowse.ch"

//----------------------------------------------------------------------------//

function Main()

   local oApp := TApplication():New()
   
   oApp:Run()
   
return nil

//----------------------------------------------------------------------------//

CLASS TApplication

   DATA oWnd
   DATA oRBar
   
   METHOD New()
   METHOD BuildMenu()
   METHOD BuildRibbon()
   
   METHOD BackStage(  )
   
   METHOD Resize( )
   
   METHOD Run()
   
ENDCLASS

//----------------------------------------------------------------------------//

METHOD New() CLASS TApplication


   DEFINE WINDOW ::oWnd TITLE "RibbonBar Style 2010 - Test";
      MENU ::BuildMenu() COLOR "N/W*"

   ::BuildRibbon( )

   SET MESSAGE OF ::oWnd TO "Testing Class RibbonBar Style 2010 and Message Bar 2010 colors" ;
      CENTERED CLOCK KEYBOARD 2010
   
   ::oWnd:Center()
   
return Self

METHOD Run() CLASS TApplication
     

     ACTIVATE WINDOW ::oWnd MAXIMIZED
     
return nil

METHOD Resize( nSizeType, nWidth, nHeight ) CLASS TApplication

   local n
     
   if nWidth != NIL
     ::oTitle:Move( , , nWidth - 1 )
     for n = 1 to 2
        ::aBrw[ n + 2 ]:Move( , nWidth / 2 + 10, nWidth / 2 - 20 )
        ::aTtls[ n + 2 ]:Move( , nWidth / 2 + 10, nWidth / 2 - 20 )
        ::aBrw[ n ]:Move( , 10, nWidth / 2 - 20 )
        ::aTtls[ n ]:Move( , 10, nWidth / 2 - 20 )        
     next
     
     ::oSplit:Adjust()
     
  endif
   
RETURN NIL


METHOD BuildRibbon() CLASS TApplication

   local oMenu, oMainMenu
   local oGr, oGr1, oGr2, oGr3, oGr4
   local oBtn,   oBtn1,  oBtn2,  oBtn3,  oBtn4, oBtn5
   local oBtn6,  oBtn7,  oBtn8,  oBtn9,  oBtn10
   local oBtn11, oBtn12, oBtn13, oBtn14, oBtn15
   local oBtn16, oBtn17, oBtn18, oBtn19, oBtn20
   local oBtn21, oBtn22, oBtn23, oBtn24, oBtn25
   local oBtn26, oBtn27, oBtn28, oBtn29, oBtn30
   local oBtn31, oBtn32, oBtn33, oBtn34, oBtn35
   local oSay1, oChk1, lVal1 := .T.
   local oTBtn0, oTBtn1, oTBtn2, oTBtn3
   local aClrMenu1 := { { 0.5, RGB( 69, 124, 188 ), RGB( 41, 93, 171 ) }, ;
                       { 0.5, RGB( 26, 64, 136 ), RGB( 56, 135, 191 ) } }
   local aClrMenu2 := { { 0.5, RGB( 123, 178, 236 ), RGB( 71, 126, 205 ) }, ;
                       { 0.5, RGB( 17, 78, 175 ), RGB( 128, 225, 255 ) } }
                        

   MENU oMenu POPUP 2010
      MENUITEM "Style Set" FILE ".\bitmaps\styleset161.BMP"
      MENUITEM "Colors"
      MENUITEM "Font"
   ENDMENU
                        
   DEFINE RIBBONBAR ::oRBar WINDOW ::oWnd ;
          PROMPT "Archivo", ;
                 "Configuración", ;
                 "Ficheros", ;
                 "Informes", ;
                 "Ayudas" HEIGHT 133 OPTION 2 2010 STARTBTN 1
   
   ::oRBar:bAction = {| nOpt, nOld | if( nOpt == ::oRBar:nStart, ::oRBar:BackStage(), ) }
   ::BackStage( ::oRBar )


   ADD GROUP oGr RIBBON ::oRBar TO OPTION 2 PROMPT "Clipboard" width 130 //BITMAP "..\bitmap\fivetech.BMP"
   
   ADD GROUP oGr1 RIBBON ::oRBar TO OPTION 2 PROMPT "Font" WIDTH 205
   
   ADD GROUP oGr2 RIBBON ::oRBar TO OPTION 2 PROMPT "Paragraph" WIDTH 215
   
   ADD GROUP oGr3 RIBBON ::oRBar TO OPTION 2 PROMPT "Styles" WIDTH 75 BITMAP ".\bitmaps\style16.BMP"
   
   ADD GROUP oGr4 RIBBON ::oRBar TO OPTION 2 PROMPT "Editing"
   
   @ 2,5 ADD BUTTON oBtn1 PROMPT "Paste" BITMAP ".\bitmaps\PASTE32.BMP" GROUP oGr ACTION ( Msginfo( "Paste" ) ) ;
   SPLITPOPUP ROUND RSIZE 2 SIZE 50,65

   @ 2, 55 ADD BUTTON oBtn2 GROUP oGr BITMAP ".\bitmaps\cut16.BMP" ;
     SIZE 60, 20 PROMPT "Cut"  MOSTLEFT round ;
     action ( msginfo( "Cut" ) )
   
   @ 24, 55 ADD BUTTON oBtn3 GROUP oGr BITMAP ".\bitmaps\copy16.BMP" ;
     SIZE 65, 20 PROMPT "Copy"  MOSTLEFT round action ( msginfo( "Copy" ) )

   @ 46, 55 ADD BUTTON oBtn4 GROUP oGr BITMAP ".\bitmaps\paste16.BMP" ;
     SIZE 70, 20 PROMPT "Paste"  MOSTLEFT round ;
     action( msginfo( "Paste" ) )
     
   @ 68, 30 ADD BUTTON oSay1 GROUP oGr SIZE 65, 15 PROMPT "A Say" SAYBUTTON
     
   @ 10, 05 ADD BUTTON oBtn5 GROUP oGr1 BITMAP ".\bitmaps\bold16.bmp" SIZE 25, 20 ROUND ;
   ACTION( oBtn5:lSelected := !oBtn5:lSelected )
   
   @ 10, 30 ADD BUTTON oBtn6 GROUP oGr1 BITMAP ".\bitmaps\italic16.bmp" SIZE 25, 20 ROUND ;
      ACTION( oBtn6:lSelected := !oBtn6:lSelected )
   
   @ 10, 55 ADD BUTTON oBtn7 GROUP oGr1 BITMAP ".\bitmaps\underline16.bmp" SIZE 35, 20 ROUND Popup
   
   @ 10, 90 ADD BUTTON oBtn8 GROUP oGr1 BITMAP ".\bitmaps\strikethru16.bmp" SIZE 25, 20 ROUND;
      ACTION( oBtn8:lSelected := !oBtn8:lSelected )
   
   
   @ 10, 115 ADD BUTTON oBtn9 GROUP oGr1 BITMAP ".\bitmaps\subindex16.bmp"  SIZE 25, 20 ROUND;
      ACTION( oBtn9:lSelected := !oBtn9:lSelected, oBtn10:lSelected := .f., oBtn10:Refresh() )
   
   @ 10, 140 ADD BUTTON oBtn10 GROUP oGr1 BITMAP ".\bitmaps\superindex16.bmp"  SIZE 25, 20 ROUND ;
      ACTION( oBtn10:lSelected := !oBtn10:lSelected, oBtn9:lSelected := .f., oBtn9:Refresh() )
   
   @ 10, 165 ADD BUTTON oBtn11 GROUP oGr1 BITMAP ".\bitmaps\casing16.bmp" SIZE 35, 20 ROUND POPUP


   @ 40, 05 ADD BUTTON oBtn11 GROUP oGr1 BITMAP ".\bitmaps\hilight16.bmp" SIZE 35, 20 ROUND POPUP
   
   @ 40, 40 ADD BUTTON oBtn12 GROUP oGr1 BITMAP ".\bitmaps\fontcolor16.bmp" SIZE 35, 20 ROUND POPUP
   
   @ 40, 100 ADD BUTTON oBtn13 GROUP oGr1 BITMAP ".\bitmaps\fontsizeincrease16.bmp" SIZE 25, 20 ROUND

   
   @ 40, 125 ADD BUTTON oBtn14 GROUP oGr1 BITMAP ".\bitmaps\fontsizedecrease16.bmp" SIZE 25, 20 ROUND
   
   
   @ 40, 175 ADD BUTTON oBtn16 GROUP oGr1 BITMAP ".\bitmaps\style16.bmp" SIZE 25, 20 ROUND

   @ 64, 70 ADD BUTTON oChk1 GROUP oGr1 BITMAP ".\bitmaps\checkon.bmp" MOSTLEFT SIZE 85, 18 PROMPT "Checkbox" ;
      ACTION ( lVal1 := ! lVal1, oChk1:SetFile( If( lVal1, ".\bitmaps\checkon.bmp", ".\bitmaps\checkoff.bmp" ) ) )


   @ 10, 05 ADD BUTTON oBtn17 GROUP oGr2 BITMAP ".\bitmaps\unorderedlist16.bmp" SIZE 35, 20 ROUND POPUP
   
   @ 10, 40 ADD BUTTON oBtn18 GROUP oGr2 BITMAP ".\bitmaps\orderedlist16.bmp" SIZE 35, 20 ROUND POPUP
   
   @ 10, 75 ADD BUTTON oBtn19 GROUP oGr2 BITMAP ".\bitmaps\multilevellist16.bmp" SIZE 35, 20 ROUND ;
     POPUP MENU oMenu

   @ 10, 110 ADD BUTTON oBtn20 GROUP oGr2 BITMAP ".\bitmaps\textalignleft16.bmp" SIZE 25, 20 ROUND ;
   ACTION( ChangeSelect( { oBtn20, oBtn21, oBtn22, oBtn23 } ) )
   
   @ 10, 135 ADD BUTTON oBtn21 GROUP oGr2 BITMAP ".\bitmaps\textaligncenter16.bmp" SIZE 25, 20 ROUND ;
      ACTION( ChangeSelect( { oBtn21, oBtn20, oBtn22, oBtn23 } ) )
   
   @ 10, 160 ADD BUTTON oBtn22 GROUP oGr2 BITMAP ".\bitmaps\textalignright16.bmp" SIZE 25, 20 ROUND;
      ACTION( ChangeSelect( { oBtn22, oBtn21, oBtn20, oBtn23 } ) )
   
   @ 10, 185 ADD BUTTON oBtn23 GROUP oGr2 BITMAP ".\bitmaps\textalignjustify16.bmp" SIZE 25, 20 ROUND;
      ACTION( ChangeSelect( { oBtn23, oBtn21, oBtn22, oBtn20 } ) )


   @ 40, 05 ADD BUTTON oBtn24 GROUP oGr2 BITMAP ".\bitmaps\fill16.bmp" SIZE 35, 20 ROUND POPUP
   
   @ 40, 40 ADD BUTTON oBtn25 GROUP oGr2 BITMAP ".\bitmaps\borderbottom16.bmp" SIZE 35, 20 ROUND
   
   @ 40, 80 ADD BUTTON oBtn26 GROUP oGr2 BITMAP ".\bitmaps\indentdecrease16.bmp" SIZE 25, 20 ROUND

   @ 40, 105 ADD BUTTON oBtn27 GROUP oGr2 BITMAP ".\bitmaps\indentincrease16.bmp" SIZE 25, 20 ROUND

   @ 40, 135 ADD BUTTON oBtn28 GROUP oGr2 BITMAP ".\bitmaps\sort16.bmp" SIZE 25, 20 ROUND
   
   @ 40, 160 ADD BUTTON oBtn29 GROUP oGr2 BITMAP ".\bitmaps\paragraphspacing16.bmp" SIZE 25, 20 ROUND
     
   @ 40, 185 ADD BUTTON oBtn30 GROUP oGr2 BITMAP ".\bitmaps\invisiblechars16.bmp" SIZE 25, 20 ROUND

   @ 3,5 ADD BUTTON oBtn31 PROMPT "Change"+CRLF+"Styles" BITMAP ".\bitmaps\stylechange32.BMP" GROUP oGr3 ;
     ROUND RSIZE 2 SIZE 65,75 TOP

   @ 2,5 ADD BUTTON oBtn32 PROMPT "Find" BITMAP ".\bitmaps\find32.BMP" GROUP oGr4 ;
     SPLITPOPUP ROUND SIZE 50,65

   @ 2, 55 ADD BUTTON oBtn33 GROUP oGr4 BITMAP ".\bitmaps\replace16.BMP" ;
     SIZE 80, 20 PROMPT "Replace"  MOSTLEFT round ;
     ACTION msginfo( "Replace" )
   
   @ 24, 55 ADD BUTTON oBtn34 GROUP oGr4 BITMAP ".\bitmaps\goto16.BMP" ;
     SIZE 65, 20 PROMPT "Go To"  MOSTLEFT round ;
     ACTION msginfo( "Go To" )

   @ 46, 55 ADD BUTTON oBtn35 GROUP oGr4 BITMAP ".\bitmaps\select16.BMP" ;
     SIZE 70, 20 PROMPT "Select"  MOSTLEFT round POPUP

return nil

METHOD BuildMenu()
   local oMenu

   MENU oMenu 2010
      MENUITEM "&Archivo"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1"
            MENUITEM "Item 2" MESSAGE "Item 2"
         ENDMENU

      MENUITEM "&Edicion"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1 "            
            MENUITEM "Item 2" MESSAGE "Item 2 "
            MENUITEM "Item 3" MESSAGE "Item 3"
            SEPARATOR
            MENUITEM "Item 4" MESSAGE "Item 4"            
            SEPARATOR
            MENUITEM "Item 5" MESSAGE "Item 5"                        
               MENU 2007
                  MENUITEM "Item 1" MESSAGE "Item 1"
                  SEPARATOR
                  MENUITEM "Item 2" MESSAGE "Item 2"
               ENDMENU            
         ENDMENU

      MENUITEM "&Ver"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1"
            MENUITEM "Item 2" MESSAGE "Item 2"
         ENDMENU
         
      MENUITEM "&Datos"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1"
            MENUITEM "Item 2" MESSAGE "Item 2"
         ENDMENU
         
      MENUITEM "&Proceso"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1"
            MENUITEM "Item 2" MESSAGE "Item 2"
         ENDMENU
         
      MENUITEM "&Impresiones"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1"
            MENUITEM "Item 2" MESSAGE "Item 2"
         ENDMENU                  

      MENUITEM "&Herramientas"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1"
            MENUITEM "Item 2" MESSAGE "Item 2"
         ENDMENU                          

      MENUITEM "In&ternet"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1"
            MENUITEM "Item 2" MESSAGE "Item 2"
         ENDMENU                  

      MENUITEM "&Ventanas"
         MENU
            MENUITEM "Item 1" MESSAGE "Item 1"
            MENUITEM "Item 2" MESSAGE "Item 2"
         ENDMENU                  

   ENDMENU

return oMenu


Procedure ChangeSelect( aObj )

   local n
     
   aObj[ 1 ]:lSelected := .t.
   for n = 2 to len( aObj )
      aObj[ n ]:lSelected := .f.
      aObj[ n ]:Refresh()
   next
return

//----------------------------------------------------------------------------//

METHOD BackStage(  ) CLASS TApplication

   local  oBackStage, oSelf := Self
   
   DEFINE BACKSTAGE oBackStage
   
   DEFINE BSBUTTON OF oBackStage PROMPT "Save" ;
          BITMAP ".\bitmaps\alphabmp\bs_save.bmp" ACTION Msginfo( oOpt:cPrompt );
          GRADIENT { { 1, nRGB(  255, 255, 0 ), nRGB( 255, 255, 255 ) } }
         
   DEFINE BSBUTTON OF oBackStage PROMPT "Save As" ;
          BITMAP ".\bitmaps\alphabmp\bs_saveas.bmp" ACTION Msginfo( oOpt:cPrompt );
          GRADIENT { { 1,  nRGB( 242, 96, 96 ), nRGB( 195, 37, 37 ) } };
          COLORTEXT CLR_BLACK, CLR_WHITE
   
   DEFINE BSBUTTON OF oBackStage PROMPT "Open" ;
          BITMAP ".\bitmaps\alphabmp\bs_open.bmp" ACTION Msginfo( oOpt:cPrompt )
   
   DEFINE BSBUTTON OF oBackStage PROMPT "Close";
          BITMAP ".\bitmaps\alphabmp\bs_close.bmp" ACTION Msginfo( oOpt:cPrompt )
   

   DEFINE BSSELECT OF oBackStage PROMPT "Information";
          COLORTEXT NIL, CLR_HRED ACTION Msginfo( oOpt:cPrompt )

   DEFINE BSSELECT OF oBackStage PROMPT "New" ACTION Msginfo( oOpt:cPrompt )

   DEFINE BSSELECT OF oBackStage PROMPT "Print" ACTION Msginfo( oOpt:cPrompt )

   DEFINE BSSELECT OF oBackStage PROMPT "Save / Send" ACTION Msginfo( oOpt:cPrompt );
      GRADIENT { { 1, nRGB(  255, 255, 0 ), nRGB( 255, 255, 255 ) } }

   DEFINE BSSELECT OF oBackStage PROMPT "Help" ACTION Msginfo( oOpt:cPrompt );
          COLORS nRGB( 242, 96, 96 ), nRGB( 195, 37, 37 )

   DEFINE BSBUTTON OF oBackStage PROMPT "Option" ;
          BITMAP ".\bitmaps\alphabmp\bs_options.bmp" ACTION Msginfo( oOpt:cPrompt )
         
   DEFINE BSBUTTON OF oBackStage PROMPT "Exit" ;
          BITMAP ".\bitmaps\alphabmp\bs_exit.bmp" ACTION Msginfo( oSelf:oWnd:End() )

   
   SET BACKSTAGE oBackStage TO ::oRBar

   
return nil
     

 

[norberto]

HI, set message and define message is the same?

i use this way:

DEFINE MESSAGE oMsgBar OF oWndMain PROMPT oSys[_Sistema_] NOINSET KEYBOARD 2010

and dont respect colors of 2010 style.

thaks for the code.


sorry, in my code i put this line : /*oMsgbar:l2007 := TRUE */, without this works fine. thanks

[norberto]

Daniel, i try compile my app with 2010 style menu, dont have the gray color , but blue, like old menu. same with your sample rb2010.prg. i missing something??



inside is 2010 style



thanks