xBrowse - Footer (SOLUCIONADO)

[MarioG]

Estimados;
Tengo el siguiente footer:


El problema es el siguiente: La columna Monto (en rojo) tiene valores positivos en la BD.
Lo que necesito es mostrarla en negativo y usando el picture "@( 99,999.99"
Alguna pista?

gracias

[cuatecatl82]

Va algo al vuelo: Si solo necsitas que el valor representado sea negativo multiplica (nValor * -1) para mostrarlo en negativo en el folder..

Si necesitas algo más elaborado comentanos y te apoyaremos..

Saludos.

[MarioG]

Victor; gracias pr responder
No escribí bien la pregunta
El valor, que llamas nValor, sería el resultado :MakeTotals().
Yo probé, sobre la columna en custión, haciendo:

Code: Select all  Expand view  RUN

:bFooter:= {|| Trans( -Val( ::oLstDeuda:Cobrado:cFooter ), "@E( 99,999.99" ) }

y me devuelve 0.
O sea la consulta sería: como obtengo el valor de dicha columna?

[joseluisysturiz]

Victor; gracias pr responder
No escribí bien la pregunta
El valor, que llamas nValor, sería el resultado :MakeTotals().
Yo probé, sobre la columna en custión, haciendo:

Code: Select all  Expand view  RUN

:bFooter:= {|| Trans( -Val( ::oLstDeuda:Cobrado:cFooter ), "@E( 99,999.99" ) }

y me devuelve 0.
O sea la consulta sería: como obtengo el valor de dicha columna?

Mario, si entiendo bien lo que quieres, nMonto de la columna cuando defines maketotal mantiene ese valor, yo lo uso cuando en una columna hay diferentes valores y quiero que maketotal sea condicionado dependiendo del valor de la celda...nose si es lo que quieres, una imagen habla mas que mil palabras, saludos...

[MarioG]

José Luis;
lo que quiero es, saber el valor (para el ejemplo 173,81). Como lo obtengo??.

[cnavarro]

Mario
Creo que para cada objeto columna hay dos datas :nTotal y :nTotalSq, quizás puedas verlo ahí.

[joseluisysturiz]

José Luis;
lo que quiero es, saber el valor (para el ejemplo 173,81). Como lo obtengo??.

Yo lo obtengo asi:

oBrw:MakeTotals()
oBrw:Refresh()
nTotalCol := oBrw:Monto:nTotal

nTotalCol recibe el valor
oBrw:Monto es la columna donde usas el maketotal,, puede ser el header de la columna o el numero, ejemplo aCol[n]
nTotal contiene el valor resultante de maketotal

espero sea lo que necesitas, saludos...

[MarioG]

Cristobal, gracias
Efectivamente :nTotal devuelve el valor.
Pero solo estoy mas cerca...
Hago lo siguiente, y me sigue mostrando el valor como positivo. Supongo que es porque el evento ocurre despues de lo que yo hago

Code: Select all  Expand view  RUN

  WITH OBJECT ::oLstDeuda
     ...
      :lFooter = TRUE
      :bChange  := {|| ::oLstDeuda:MakeTotals(), ;
                       ::oLstDeuda:Monto:cFooter:= Trans( -::oLstDeuda:Monto:nTotal, "@E( 99,999.99" ), ;
                       ::oLstDeuda:Refresh()  }

      :bGotFocus:= {|| h0["CabVentas"]:SetFocus() }
   END
 

[MarioG]

Jose Luis, gracias
Eso es lo que necesitaba!. Como bien lo apunto tambien Cristobal
Aunque como leerás, aun no tengo lo que quiero...

[joseluisysturiz]

Si quieres obtener el valor en negativo, solo debes multiplicar el resultado por menos uno (-1), como te dijo el colega al principio, saludos...

[MarioG]

Pues mi máquina no sabe multiplicar
Lo haga asi:

Code: Select all  Expand view  RUN

     :bChange  := {|| ::oLstDeuda:MakeTotals(), ;
                       ::oLstDeuda:Monto:cFooter:= Trans( -::oLstDeuda:Monto:nTotal, "@E( 99,999.99" ), ::oLstDeuda:Refresh()  }
 

o así:

Code: Select all  Expand view  RUN

     :bChange  := {|| ::oLstDeuda:MakeTotals(), ;
                       ::oLstDeuda:Monto:cFooter:= Trans( (-1*::oLstDeuda:Monto:nTotal), "@E( 99,999.99" ), ::oLstDeuda:Refresh()  }
 

y muestra como en la primer imagen que envie

[FranciscoA]

Mario, intenta asi:

Code: Select all  Expand view  RUN

    :bChange  := {|| ::oLstDeuda:MakeTotals(), ;
                       ::oLstDeuda:Monto:cFooter:= Trans( -::oLstDeuda:Monto:nTotal, "@E( 99,999.99" ), ;
                       ::oLstDeuda:RefreshFooter() }

Saludos.

[MarioG]

Francisco;
::oLstDeuda:RefreshFooter(), me da error de metodo no valido
pero, asi refresca... aunque el valor lo sigue mostrando como positivo

Code: Select all  Expand view  RUN

:bChange  := {|| ::oLstDeuda:MakeTotals(), ;
                       ::oLstDeuda:Monto:cFooter:= Trans( -::oLstDeuda:Monto:nTotal, "@E( 99,999.99" ), ;
                       ::oLstDeuda:Monto:RefreshFooter() }

me parece que despues del bChange, hace algo, por eso toma el valor original

[joseluisysturiz]

Mario, lo que yo hago no lo hago en la columna, sino afuera en una funcion, en la columna puedes colocar nTotal == tu_function() y en tu_funcion haces el calculo que quieras o coloca el -1 entre parentesis, es decir asi (-1) * tu_valor. En que quieres usar el valor de nTotal, en otra celda o para otra operacion que veo que usas en on change..? saludos...

Prueba asi
Trans( ( (-1) * ::oLstDeuda:Monto:nTotal), "@E( 99,999.99" )

[carlos vargas]

extendamos un poco xbrowse agregando una data cFooterPicture a la clase txbrwcolumn
y modifiquemos el metodo FooterStr a la clase txbrwcolumn
y ya tenemos un picture definible para cada footer.
probado con harbour y xharbour

ejemplo de uso

Code: Select all  Expand view  RUN

   WITH OBJECT oBrw
      :aCols[ 03 ]:cFooter     := "Total C$:"
      :aCols[ 06 ]:cFooterPicture := "(999,999.99)" //ejemplo
      :aCols[ 06 ]:nFooterType := AGGR_SUM
  END
 

Code: Select all  Expand view  RUN

   EXTEND CLASS TXBRWCOLUMN WITH DATA   cFooterPicture
   OVERRIDE METHOD FooterStr  IN CLASS TXBRWCOLUMN WITH KFooterStr
 

Code: Select all  Expand view  RUN

FUNCTION KFooterStr()
   LOCAL Self    := HB_QSelf()
   local cFooter := "", cType

   if ::bFooter != nil
      cFooter  := Eval( ::bFooter, Self )
      DEFAULT cFooter := ""
   elseif ::nTotal != nil .or. ! Empty( ::nFooterType )
      DEFAULT ::nFooterType := AGGR_SUM, ::nTotal := 0.0
      if ::nFooterType >= AGGR_STD
         if ::nCount > 0
            cFooter  := ::nTotalSq - ( ::nTotal * ::nTotal / ::nCount )
            cFooter  /= ::nCount - If( ::nFooterType == AGGR_STDEVP, 0, 1 )
            cFooter  ^= 0.5
         else
            cFooter  := 0
         endif
      elseif ::nFooterType == AGGR_AVG
         cFooter  := If( ::nCount > 0, ::nTotal / ::nCount, 0 )
      elseif ::nFooterType == AGGR_COUNT
         cFooter  := ::nCount
      else
         cFooter  := ::nTotal
      endif
   elseif ::cFooter != nil
      cFooter  := ::cFooter
   endif

   cType    := ValType( cFooter )
   if cType != 'C'
      if cType == ::cDataType .and. ::cEditPicture != nil
         cFooter  := cValToStr( cFooter, IIf( ::cFooterPicture==NIL, ::cEditPicture, ::cFooterPicture ),, ;
                     IfNil( ::lDisplayZeros, ::oBrw:lDisplayZeros ) )
      else
         cFooter := cValToChar( cFooter )
      endif
   endif

return cFooter