Imaqen desde Url solucionado ...

[mastintin]

Pues con este nuevo metodo para Timage ...
Falta que controle los posibles fallos si no existe la imagen en la url o asi, pero en principio funciona.Lo he probado con una imagen gif, jpg y png .
Tiene un problema y es que si llamamos a mas de una imagen , no llega a terminarse la carga de la imagen antes de que termine de la carga de la ventana .
Esto tendría que controlarse con el evento OnResponseFinished pero no se como hacerlo así que os lo dejo a vosotros.

Code: Select all  Expand view

METHOD LoadFromURL(cUrl ) CLASS TImage
local oHttp
local cResp
  Try
      oHttp := CreateObject( "winhttp.winhttprequest.5.1" )
      oHttp:Open("GET", cUrl, .f. )
      oHttp:Send()
      cResp := oHttp:ResponseBody()
  Catch
      MsgStop( "Error" )
      Return .f.
  End Try
 
   ::LoadFromMemory( cResp )
   ::Refresh()
Return .t.

 

[Antonio Linares]

Manuel,

Sencillamente genial

Añadido ya para la próxima versión de FWH

Muchas gracias!

[AngelSalom]

Buenas, amigos. No consigo hacer funcionar este nuevo método. Lo he pasado a función para no modificar (de momento) la clase, pero no me carga ninguna imagen. He probado a grabarla por si era un tema de refresco o similar pero entonces "petarda" el ejemplo.

Aquí dejo el código a ver si encontráis algún fallo. Gracias.

Code: Select all  Expand view

#include "FiveWin.ch"
#include "Image.ch"

//----------------------------------------------------------------------------//

function Main()

   Local oDlg, oImage

   DEFINE DIALOG oDlg FROM 0, 0 TO 25, 60
   @ 0, 0 IMAGE oImage SIZE 150, 150 OF oDlg SCROLL // ADJUST

   @ 1, 28 BUTTON "URL"   SIZE 50, 10 OF oDlg ACTION CargaImagenDesdeUrl (oImage,"http://forums.fivetechsupport.com/styles/prosilver/imageset/site_logo.gif")
   @ 2, 28 BUTTON "Salir" SIZE 50, 10 OF oDlg ACTION oDlg:End()
   
   ACTIVATE DIALOG oDlg CENTER

Return ( nil)

Function CargaImagenDesdeUrl (oImage,cUrl)
local oHttp
local cResp
  Try
      oHttp := CreateObject( "winhttp.winhttprequest.5.1" )
      oHttp:Open("GET", cUrl, .f. )
      oHttp:Send()
      cResp := oHttp:ResponseBody()
  Catch
      MsgStop( "Error cargando imagen" )
      Return .f.
  End Try

   oImage:LoadFromMemory( cResp )
   oImage:Refresh()
   msginfo (cUrl,"Imagen cargada")
Return (.t.)
 

[mastintin]

¿ usas un proxi ?

[AngelSalom]

No, lo he probado en el trabajo y en casa con el mismo resultado.

[acuellar]

Angel

Probé tu ejemplo y funciona.

Antonio / Manuel

Cómo se puede evitar la librería freeimage.dll con FWH1412

Saludos,

Adhemar

[AngelSalom]

Vaya, pues no sé a que pude ser debido ...

[Antonio Linares]

Adhemar,

Estamos en ello, a ver si finalmente podemos eliminarla.

De momento hay que seguir usándola

[acuellar]

Perfecto.

Gracias.

Saludos,

Adhemar

[Silvio.Falconi]

Manuel,

Sencillamente genial

Añadido ya para la próxima versión de FWH

Muchas gracias!

Antonio,
I think the mastintin method need a modify :

If the user Have a Proxy the method LoadFromURL(cUrl ) not run ok




to add proxy it can be

Code: Select all  Expand view

#define HTTPREQUEST_PROXYSETTING_DEFAULT   0
#define HTTPREQUEST_PROXYSETTING_PRECONFIG 0
#define HTTPREQUEST_PROXYSETTING_DIRECT    1
#define HTTPREQUEST_PROXYSETTING_PROXY     2


#define HTTPREQUEST_SETCREDENTIALS_FOR_SERVER  0
#define HTTPREQUEST_SETCREDENTIALS_FOR_PROXY   1

METHOD LoadFromURL(cUrl ,lProxy, cUserName, cPassword,nPort,cProxy) CLASS TImage
local oHttp
local cResp
  Try
     oHttp := CreateObject( "winhttp.winhttprequest.5.1" )

      if lProxy
         oHttp:SetProxy( HTTPREQUEST_PROXYSETTING_PROXY, cProxy+":"+alltrim(str(nPort)))
      endif


      oHttp:Open("GET", cUrl, .f. )

        if lProxy
         oHttp:SetCredentials(cUserName,cPassword,HTTPREQUEST_SETCREDENTIALS_FOR_PROXY)
      endif


      oHttp:Send()
      cResp := oHttp:ResponseBody()
  Catch
      MsgStop( "Error" )
      Return .f.
  End Try

   ::LoadFromMemory( cResp )
   ::Refresh()
Return .t.

 
 

I use it on Yahoo Meteo and Yahoo finance ( created by Mastintin)