email - blat.exe

[Otto]

Hello,

blat.exe
I am working on a setup for my windows server backup.

I found some solutions where you get a notification through an email sent by blat.exe.

I blat.exe a secure software.
Can we send emails only with Fivewin, too.

Thanks in advance
Otto

[Enrico Maria Giordano]

This is what I'm using without problems:

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL cFrom         := "e.m.giordano@emagsoftware.it"
    LOCAL cServer       := "out.alice.it"
    LOCAL cTo           := "e.m.giordano@emagsoftware.it"
    LOCAL cSubject      := "Test message"
    LOCAL cMessage      := "This is a test message."
    LOCAL aAttach       := NIL
    LOCAL cSender       := NIL
    LOCAL cUser         := NIL
    LOCAL cPassword     := NIL
    LOCAL aCC           := NIL
    LOCAL lHtml         := NIL
    LOCAL cPort         := NIL
    LOCAL lNotification := NIL
    LOCAL lSSL          := NIL

    ? SENDMAIL( cFrom, cServer, cTo, cSubject, cMessage, aAttach, cSender, cUser, cPassword, aCc, lHtml, cPort, lNotification, lSSL )

    RETURN NIL


#command IF <condition> THEN <*statements*> => if <condition> ; <statements> ; end


FUNCTION SENDMAIL( cFrom, cServer, cTo, cSubject, cMessage, aAttach, cSender, cUser, cPassword, aCc, lHtml, cPort, lNotification, lSSL )

    LOCAL lOk := .F.

    LOCAL oCfg, oMsg

    LOCAL cCc := ""

    LOCAL i

    DEFAULT lHtml         := "<html" $ LOWER( cMessage )
    DEFAULT lNotification := .F.
    DEFAULT lSSL          := .F.

    TRY
        oCfg = CREATEOBJECT( "CDO.Configuration" )

        oCfg:Item( "http://schemas.microsoft.com/cdo/configuration/smtpserver" ):Value = cServer

        IF !EMPTY( cPort )
            oCfg:Item( "http://schemas.microsoft.com/cdo/configuration/smtpserverport" ):Value := VAL( cPort )
        ENDIF

        oCfg:Item( "http://schemas.microsoft.com/cdo/configuration/sendusing" ):Value = 2
        oCfg:Item( "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate" ):Value = .F.

        IF !EMPTY( cUser ) .AND. !EMPTY( cPassword )
            oCfg:Item( "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate" ):Value = .T.
            oCfg:Item( "http://schemas.microsoft.com/cdo/configuration/sendusername" ):Value = cUser
            oCfg:Item( "http://schemas.microsoft.com/cdo/configuration/sendpassword" ):Value := cPassword
            oCfg:Item( "http://schemas.microsoft.com/cdo/configuration/smtpusessl" ):Value = lSSL
        ENDIF

        oCfg:Update()

        oMsg = CREATEOBJECT( "CDO.Message" )

        oMsg:Configuration = oCfg

        IF !EMPTY( cSender ) THEN cFrom = ["] + cSender + ["] + " <" + cFrom + ">"

        oMsg:From    = cFrom
        oMsg:To      = cTo
        oMsg:Subject = cSubject

        IF !EMPTY( aCc )
            FOR i = 1 TO LEN( aCc )
                IF i > 1 THEN cCc += ";"
                cCc += aCc[ i ]
            NEXT

            oMsg:CC = cCc
        ENDIF

        IF !lHtml
            oMsg:TextBody = cMessage
        ELSE
            oMsg:HTMLBody = cMessage
        ENDIF

        IF !EMPTY( aAttach )
            FOR i = 1 TO LEN( aAttach )
                oMsg:AddAttachment( aAttach[ i ] )
            NEXT
        ENDIF

        IF lNotification
            oMsg:Fields:Item( "urn:schemas:mailheader:disposition-notification-to" ):Value = cFrom
            oMsg:Fields:Update()
        ENDIF

        oMsg:Send()

        lOk = .T.
    CATCH
    END

    RETURN lOk

EMG

[Otto]

Hello Enrico,
thank you. I will try your solution.
Best regards,
Otto

PS:
Are you travelling to the Dolomites in ferragosto?


Our problems at the moment:

[Enrico Maria Giordano]

Are you travelling to the Dolomites in ferragosto?

Unfortunately not.

EMG

[dtussman]

In Enrico's example I don't see where he is defining the port. Doesn't CDO require the port? Also, I assume this example would not work with Outlook or Office 365.

[Enrico Maria Giordano]

In Enrico's example I don't see where he is defining the port. Doesn't CDO require the port?

Code: Select all  Expand view

LOCAL cPort         := NIL

The default value is used (25, if I remember correctly). You can assign any other (string) value you need:

Code: Select all  Expand view

LOCAL cPort         := "587"

EMG

[Enrico Maria Giordano]

Also, I assume this example would not work with Outlook or Office 365.

I don't understand, sorry.

EMG