error en xbrowse o FWH ???

[kpidata]

Estimados, alguien me puede explicar la siguiente situacion que ya me tiene agotado... en la funcion que esta mas abajo, en la version de
FWH 8.12, xHarbour y BCC55, funciona bien cuando pincho sobre el nombre de la columna, ordena al momento de forma ascendente y descendente los valores de esta tiene y si me cambio a la otra columna, igual, al 100%, pero si compilo con FWH 13.2, xHarbour y BCC582, solo me ordena de forma descendente una columna, si hago doble click para que cambie a descendente, no pasa nada, y que debo dar doble click sobre el titulo de la columna para que realmente ordene de esa forma, si me cambio a la otra columna,, otra vez doble click para que me muestre el ordenamiento ...de esa columna...



Function Main_Familia(cEmpresa,cUser,cCuentas)
Local oDlg, oBrw, oFont2, oCol, oSay, oBtn2[ 9 ]
Close DataBase

Select 01
Do While .T.
If NET_USE("Tab_Fam",.F.,0)
Set Index to Tab_Fam1,Tab_Fam2
Set order to 1
exit
Else
ESTADO_DBF()
RETURN Nil
Endif
Enddo

Define Font oFont2 Name "Tahoma" Size 0,-11 Bold
DEFINE DIALOG oDlg ResName "BROW6BC" TITLE "Tabla/Archivos Familia o Linea de Productos.. " TRANSPARENT COLOR Rgb( 255, 0, 0 ), Rgb(185,220,255)

oBrw:=TxBrowse():New(oDlg)
oBrw:nMarqueeStyle := MARQSTYLE_HIGHLROW // Con cursor de todo el renglón
oBrw:nColDividerStyle := LINESTYLE_RAISED
oBrw:nRowDividerStyle := LINESTYLE_RAISED
oBrw:bClrSelFocus := {|| { nRGB( 0, 0, 0), nRGB(128,255,128) } } // para barra de linea selecc cuando el control tiene el foco
oBrw:lColDividerComplete := (.t.) // (.T.) Mantiene siempre llena la pantalla
oBrw:nHeaderHeight := 35 // Altura de los encabezados
oBrw:nRowHeight := 25 // Altura del renglón
oBrw:nHeaderLines := 3 // Número de líneas de encabezados
oBrw:nDataLines := 2 // Número de líneas de detalle
oBrw:nFooterHeight := 20 // Altura del footer
oBrw:nFooterLines := 2 // Número de líneas en el footer
oBrw:lFooter := (.T.) // Sí queremos línea de footer
oBrw:lHScroll := (.T.) // Quitamos el scroll horizontal
oBrw:bClrHeader := {|| { nRGB(000,000,000), nRGB(128,255,128) } }
oBrw:bClrStd := { || If( oBrw:KeyNo() % 2 == 0, { CLR_BLACK, RGB( 224, 236, 255 ) }, { CLR_BLACK, RGB( 189, 211, 253 ) } ) }
oBrw:bClrFooter := {|| { nRGB(000,000,000), nRGB(150,200,200) } }
oBrw:bClrSel := {|| { nRGB(000,000,000), nRGB(128,255,128) } } // para barra de linea selecc cuando el control no tiene el foco
oBrw:nStretchCol := STRETCHCOL_WIDEST
oBrw:oFont := oFont2

oCol := oBrw:AddCol()
oCol:bStrData := { || Tab_Fam->Cod_Fam }
oCol:cHeader := "Codigo"
oCol:cSortOrder :="Tab_Fam1"

oCol := oBrw:AddCol()
oCol:bStrData := { || Tab_Fam->Nom_Fam }
oCol:cHeader := "Nombre"
oCol:cSortOrder :="Tab_Fam2"

oBrw:SetFocus()
oBrw:bSeek := {|c| PSeek( c ) }
oBrw:bLDblClick := {|| Add_Fam(.F.) }
oBrw:bKeyDown :={ | nKey | TeclasFam(nKey, oBrw, cEmpresa) }
oBrw:CreateFromResource(1000)

Redefine Say oBrw:oSeek Var oBrw:cSeek Id 1001 Of oDlg Picture "@!" Font oFont2 COLOR RGB(128,0,0)

ACTIVATE DIALOG oDlg CENTERED
oFont2:End()
Close DataBase
Return NIl

[armando.lagunas]

Prueba de esta forma:

tu mismo código:

Code: Select all  Expand view  RUN

Define Font oFont2 Name "Tahoma" Size 0,-11 Bold

DEFINE DIALOG oDlg ResName "BROW6BC" TITLE "Tabla/Archivos Familia o Linea de Productos.. " TRANSPARENT COLOR Rgb( 255, 0, 0 ), Rgb(185,220,255)

       REDEFINE XBROWSE oBrw ID 1000 COLUMNS "Cod_Fam","Nom_Fam" ALIAS "TAB_FAM" FONT oFont2 OF oDlg AUTOSORT FOOTERS

            oBrw:aCols[1]:cHeader    := "Codigo" ;  oBrw:aCols[1]:nWidth  := 40    ; oBrw:aCols[1]:nDataStrAlign  := AL_CENTER ; oBrw:aCols[1]:cSortOrder := "Tab_Fam1"
            oBrw:aCols[2]:cHeader    := "Nombre" ;  oBrw:aCols[2]:nWidth  := 100   ; oBrw:aCols[2]:nDataStrAlign  := AL_LEFT   ; oBrw:aCols[2]:cSortOrder := "Tab_Fam2"
           
            oBrw:nMarqueeStyle       := MARQSTYLE_HIGHLROW // Con cursor de todo el renglón
            oBrw:nColDividerStyle    := LINESTYLE_RAISED
            oBrw:nRowDividerStyle    := LINESTYLE_RAISED
            oBrw:bClrSelFocus        := {|| { nRGB( 0, 0, 0), nRGB(128,255,128) } } // para barra de linea selecc cuando el control tiene el foco
            oBrw:lColDividerComplete := (.t.) // (.T.) Mantiene siempre llena la pantalla
            oBrw:nHeaderHeight       := 35 // Altura de los encabezados
            oBrw:nRowHeight          := 25 // Altura del renglón
            oBrw:nHeaderLines        := 3 // Número de líneas de encabezados
            oBrw:nDataLines          := 2 // Número de líneas de detalle
            oBrw:nFooterHeight       := 20 // Altura del footer
            oBrw:nFooterLines        := 2 // Número de líneas en el footer
            oBrw:lFooter             := (.T.) // Sí queremos línea de footer
            oBrw:lHScroll            := (.T.) // Quitamos el scroll horizontal
            oBrw:bClrHeader          := {|| { nRGB(000,000,000), nRGB(128,255,128) } }
            oBrw:bClrStd             := { || If( oBrw:KeyNo() % 2 == 0, { CLR_BLACK, RGB( 224, 236, 255 ) }, { CLR_BLACK, RGB( 189, 211, 253 ) } ) }
            oBrw:bClrFooter          := {|| { nRGB(000,000,000), nRGB(150,200,200) } }
            oBrw:bClrSel             := {|| { nRGB(000,000,000), nRGB(128,255,128) } } // para barra de linea selecc cuando el control no tiene el foco
            oBrw:nStretchCol         := STRETCHCOL_WIDEST
            oBrw:bSeek               := {|c| PSeek( c ) }
            oBrw:bLDblClick          := {|| Add_Fam(.F.) }
            oBrw:bKeyDown            :={ | nKey | TeclasFam(nKey, oBrw, cEmpresa) }

       Redefine Say oBrw:oSeek Var oBrw:cSeek Id 1001 Of oDlg Picture "@!" Font oFont2 COLOR RGB(128,0,0)

ACTIVATE DIALOG oDlg CENTERED

 

yo uso FWH 13