Problemas con Report

[horacio]

Colegas, en una rutina de impresión usando TReport tengo el inconveniente que me intercala hojas en blanco y no encuentro el motivo. Posteo una imagen y el código

Code: Select all  Expand view

Function RptEgresos()

    Local i
    Local oRpt
    Local oPen1
    Local oFont1
    Local oFont2
    Local oFont3
    Local oFont4
    Local oFont5
    Local oRec := oClone( oRs )
    Memvar o
   
    Define Font oFont1 Name 'Arial'  Size 0, -08
    Define Font oFont2 Name 'Tahoma' Size 0, -08 Bold
    Define Font oFont3 Name 'Arial'  Size 0, -11 Bold
    Define Font oFont4 Name 'Arial'  Size 0, -06
    Define Font oFont5 Name 'Arial'  Size 0, -08 Bold
    Define Pen oPen1 Width 1 Color CLR_HGRAY

   
    oRec : GoTop()
    Report oRpt Header o : cEmpresa, 'Fecha: ' + DToC( Date() ) Title ' ' , "LISTADO DE EGRESOS " , Alltrim( StrTran( cTitulo, '- ', '' ) ), '', '' ;
                        Font oFont1, oFont2, oFont3, oFont4, oFont5 Pen oPen1 Caption 'Listado de facturas' Footer 'QBIT - Sistemas Digitales De Gestión' Preview
       
        Column Title 'Nº COMP.'  Data StrZero( 1, 4 ) + '-' + StrZero( oRec : id_comp, 6 ) VCenter Center Size 11 //grid
        Column Title 'Nº FACT.'  Data StrZero( Val( oRec : id_factura ), 8 ) VCenter Center Size 11 //grid
        Column Title "FECHA"     Data DToC( oRec : fecha ) Font 1 Center VCenter Size 08
        Column Title "PROVEEDOR" Data oRec : descrip Font 1 Size 28 VCenter
        Column Title "IMPORTE"   Data oRec : importe Font 1 Size 10 VCenter Picture "@E 99,999,999.99" Total
   
    EndReport
    For i := 1 To Len( oRpt : aColumns )
        oRpt : aColumns[ i ] : bTitleFont := { || 2 }
        oRpt : aColumns[ i ] : bTotalFont := { || 2 }
    End
    oRpt : lBoxOnTotal := .t.   
    oRpt : aColumns[ 1 ] : nPad := 3
    oRpt : aColumns[ 2 ] : nPad := 3
    oRpt : aColumns[ 5 ] :  bDataFont := { || 5 }
    oRpt : oTitle : aFont[ 1 ] := { || 4 }
    oRpt : oTitle : aFont[ 2 ] := { || 3 }
    oRpt : oTitle : aFont[ 3 ] := { || 2 }
    oRpt : oHeader : aFont[ 1 ] := { || 2 }
    oRpt : nTotalLine   := 1
    oRpt : nTitleUpLine := 1
    oRpt : nTitleDnLine := 1
    oRpt : oFooter : aFont[ 1 ] := { || 4 }
    oRpt : bSkip := { || oRec : Skip() }
    oRpt : lPageTotal :=.t.
    oRpt : CellView()
    Activate Report oRpt    While ( !oRec : Eof() ) 
    Release Font oFont1, oFont2, oFont3, oFont4, oFont5
    oPen1 : End()
    oRec : End()
    oRec := Nil
    oBrwE : SetFocus()
    Return 0
   
 

Alguna idea ? Muchas gracias.

Saludos

[horacio]

Haciendo pruebas y comentariando esta linea: oRpt : CellView() funciona perfectamente. Me interesa esta opción. Alguna manera de arreglarlo ?

Saludos

[karinha]

Mira se ayuda:

http://forums.fivetechsupport.com/viewtopic.php?f=6&t=14856&p=76743&hilit=oReport%3ACellView#p76743

Saludos.

[horacio]

Gracias Joao por responder, no me ayuda en nada ya que el problema que plantea ese post no es el problema que me sucede a mi.

[karinha]

Horácio mira los ejemplos en c:\fwh\samples\report

Saludos.

[horacio]

Joao, seguí tu sugerencia e indudablemente es un bug de este método. En rep01.prg que se encuentra en \samples\report se puede ver el efecto de la página en blanco.

Saludos

[cnavarro]

Horacio, haz una prueba quitando esta linea

Code: Select all  Expand view

oRpt : nTitleDnLine := 1
 

[horacio]

Gracias Cristobal por tu sugerencia pero no arregla este problema.

Saludos

[cnavarro]

Es para saber por donde pueden ir los tiros.
Quita también la linea por encima del title

[karinha]

Horácio, REP20.PRG, REP21.PR y REP22.PRG parece bién. rep11.prg perfecto. Saludos.

[horacio]

La solución funciona de esta manera

Code: Select all  Expand view

    oRpt : nTotalLine   := 0
    oRpt : nTitleUpLine := 0
    oRpt : nTitleDnLine := 0
 

Pero ya no se dibujan las lineas del header y la verdad no queda muy bonito.

Saludos

[horacio]

Joao, ninguna de esas rutinas usan el método CellView(). Prueba de compilar rep01 y me comentas. Gracias

Saludos

[cnavarro]

Si solo cambias

oRpt : nTotalLine := 0

y dejas las demás sigue ocurriendo ?

[horacio]

Cristobal, He probado todas las posibilidades con estas datas y la única que funciona es cuando su valor es cero.

Saludos

[karinha]

Horácio, REP01.PRG modificado, prueba y comente. saludos.

Code: Select all  Expand view

#include "FiveWin.ch"
#include "report.ch"

request DBFCDX

STATIC oReport

Function Rep01()

   LOCAL oPen1, oPen2, oFont1, oFont2, oFont3, oReport

   USE TEST NEW VIA "DBFCDX"

   GO TOP

   DEFINE PEN oPen1 Width 2 COLOR CLR_HGRAY
   // DEFINE PEN oPen1 WIDTH 2
   DEFINE PEN oPen2 WIDTH 1

   DEFINE FONT oFont1 NAME "Arial"       SIZE 0, -11
   DEFINE FONT oFont2 NAME "Arial"       SIZE 0, -11
   DEFINE FONT oFont3 NAME "Courier New" SIZE 0,  09 BOLD

   REPORT oReport TITLE  "*** My First Report ***" PREVIEW

   oReport:oDevice:lPrvModal := .T.
   oReport:oDevice:SetPage(9) //-> Formato A4

   oReport:lAutoLand := .F.  // Vertical  // Manuel Mercado.
   // PrnPortrait()   //vertical ou
   // oReport:SetPortrait() //Vertical

   COLUMN TITLE "St"         DATA Test->State
   COLUMN TITLE "First Name" DATA Test->First
   COLUMN TITLE "   Salary"  DATA Test->Salary

   END REPORT

   IF !oReport:lCreated
      RETURN NIL
   ELSE
      oReport:SetTxtColor(CLR_HBLUE,1)
      oReport:SetTxtColor(CLR_HRED, 2)
      oReport:SetTxtColor(CLR_HBLUE,3)
      oReport:SetPenColor(CLR_HBLUE  )
      oReport:SetShdColor(CLR_HCYAN  )
   ENDIF

   oReport:CellView()

   ACTIVATE REPORT oReport

   oPen1:End()  
   oPen2:End()  
   oFont1:End()
   oFont2:End()
   oFont3:End()

   CLOSE TEST

RETURN NIL