Ancho de columnas en XBROWSER. RESUELTO

[FiveWiDi]

Hola a todos,

Estoy actualizando una aplicación bastante vieja y empiezo a utilizar XBROWSER así:

XBROWSER TITLE oTdbfComuni:cName + "-" + oTdbfComuni:cFile + " - Família:" + cCodiFami ;
COLUMNS { "BASEASSO", "REFEASOC", "ESTAT", "CODIFAMI" } ;
SETUP ( oBrw:cHeaders := { "Base associada", "Codi Associat", "Estat", "Codi Família" } )

¿Cómo puedo indicar los anchos de las columnas?

Muchas gracias,

[FranciscoA]

Carlos:

Code: Select all  Expand view

XBROWSER TITLE oTdbfComuni:cName + "-" + oTdbfComuni:cFile + " - Família:" + cCodiFami ;
COLUMNS { "BASEASSO", "REFEASOC", "ESTAT", "CODIFAMI" } ;
SETUP ( oBrw:cHeaders := { "Base associada", "Codi Associat", "Estat", "Codi Família" } ,;
            oBrw:nWidths := {100,80,60,100}  )
 

Saludos.

[FiveWiDi]

Perfecto!!!!!

Muchas gracias.

[FiveWiDi]

Otra consulta parecida.

¿Cómo puedo cambiar el título del DIALOG del XBROWSER durante la ejecución según valores?

Gracias,

[FranciscoA]

Otra consulta parecida.

¿Cómo puedo cambiar el título del DIALOG del XBROWSER durante la ejecución según valores?

Gracias,

No estoy seguro de haber entendido bien tu pregunta, pero aqui está un ejemplo.

Code: Select all  Expand view

#include "fivewin.ch"
#include "xbrowse.ch"
//---------------------------------------------------------//
FUNCTION MAIN()
EjempXBR(1)
EjempXBR(2)
Return nil

//---------------------------------------------------------//
FUNCTION EjempXBR(nOpc)
local aCols, aHeaders, aWidths, cTitle

if nOpc = 1
   USE STATES
   aCols := {"Code","Name"}
   aHeaders := {"Codigo","Nombre"}
   aWidths := {50,200}
else
   USE CUSTOMER
   aCols := {"First","Last","Street","City"}
   aHeaders := {"Nombre","Apellido","Calle","Ciudad"}
   aWidths := {100,100,200,100}
endif

cTitle := "HOJEANDO TABLA " + Alias()

XBROWSER Alias() ;
   TITLE cTitle ;
 COLUMNS aCols ;
   SETUP ( oBrw:cHeaders      := aHeaders,;
           oBrw:nWidths       := aWidths ,;
           oBrw:nMarqueeStyle := MARQSTYLE_HIGHLWIN7 ,;
           oBrw:bRecSelHeader := { || "KeyNo" } ,;
           oBrw:bRecSelData   := { |o| o:KeyNo } ,;
           oBrw:lFooter       := .t. ,;
           oBrw:bRecSelFooter := { |o| o:nLen } ,;
           oBrw:nRecSelWidth  := "9999" )

CLOSE

Return nil
 

[FiveWiDi]

Gracias Francisco por el interés.

Ciertamente escoges el título del Browser según la tabla que consultas; yo me expliqué mal.

El caso es que consigo añadir un botón al browse que me permite filtrar la DBF; entonces al pulsar ese botón (está en la buttonbar), quiero cambiar el título del DIALOG, pero no sé hacerlo.

Añado el botón así:

Code: Select all  Expand view

SETUP ( oBrw:cHeaders := { "Data tramesa", "Enviat?", "Destinatari", "Assumpte",    "Mitjà", "N.Annexes",    "Tipus", "Base associada", "Codi Associat", "Estat", "Codi Família", "Hora envío" }, ;
                     oBrw:nWidths  := {             75,        45,           150,        250,        150,          50,         35,               75,              80,      35,            100,           75 }, ;
                     TBtnBmp():NewBar( ,,  ,,, ;
                                       {|This|  This:cToolTip := (aFiltro := Filtro01( AMPAArra, AMPAarra[1][1][2][1][1], 'COMUNI', oTdbfComuni, Nil, .T., aFiltro, .F. ) )[2] }, ;
                                       .T., oBrw:oWnd:oBar, .F.,, aFiltro[2], .F.,, ;
                                       "This:cToolTip := (aFiltro := Filtro01( AMPAArra, AMPAarra[1][1][2][1][1], 'COMUNI', oTdbfComuni, Nil, .T., aFiltro, .F. ) )[2]", ;
                                       ,"Flt",,,,,,,,, .F.,,, ) ;
)

[FiveWiDi]

Así:

Code: Select all  Expand view

             SETUP ( oBrw:cHeaders := { "Data tramesa", "Enviat?", "Destinatari", "Assumpte",    "Mitjà", "N.Annexes",    "Tipus", "Base associada", "Codi Associat", "Estat", "Codi Família", "Hora envío" }, ;
                     oBrw:nWidths  := {             75,        45,           150,        250,        150,          50,         35,               75,              80,      35,            100,           75 }, ;
                     TBtnBmp():NewBar( ,,  ,,, ;
                                       {|This|  This:oWnd:oWnd:SetText( "Filtro: " + (aFiltro := Filtro01( AMPAArra, AMPAarra[1][1][2][1][1], 'COMUNI', oTdbfComuni, Nil, .T., aFiltro, .F. ) )[2] ) }, ;
                                       .T., oBrw:oWnd:oBar, .F.,, GetTrad( "Filtrar" ), .F.,, ;
                                       "This:oWnd:oWnd:SetText( (aFiltro := Filtro01( AMPAArra, AMPAarra[1][1][2][1][1], 'COMUNI', oTdbfComuni, Nil, .T., aFiltro, .F. ) )[2] )", ;
                                       ,"Flt",,,,,,,,, .F.,,, ) ;
                   )