Treport de Tabla SQL con FWH nativo ( parte 3 ) (RESUELTO)

[jose_murugosa]

Como que ya me siento mal de estar preguntando cosas que debería tener resueltas, pero lo cierto es que tengo un nuevo problema con treport y rowset que no he logrado resolver.

Code: Select all  Expand view  RUN

          PRINT oPrn FILE ".\PDFS\" + wfecha + "-" + whora + ".pdf"
          REPORT oReport ;
               TITLE  "*** Informe de Entrada al Desosado ***",;
                    wfecha + " de las " + wHorainic + " hasta las " + wHoraFin ;
               HEADER "Fecha: " + dtoc(date()),;
                    "Hora:  " + time() ;
                    RIGHT ;
                    FOOTER "Página: " + str(oReport:nPage,4) ;
                    CENTERED ;
                    SUMMARY ;
                    TO DEVICE oPrn
           
          COLUMN TITLE "Cantidad" ;
               DATA oRs:Cantidad  ;
               PICTURE "99,999"   ;
               SIZE 14             ;
               FONT 1             ;
               TOTAL
     
          COLUMN TITLE "Peso Neto";  
               DATA oRs:PesoNeto  ;
               PICTURE "99,999.99";
               SIZE 12            ;          
               FONT 1             ;
               TOTAL
               
          COLUMN TITLE "Peso Promedio";  
               DATA ( oRs:PesoNeto / oRs:Cantidad ) ;
               PICTURE "999,999.99"   ;
               SIZE 12                ;          
               FONT 1        
     
     GROUP ON oRs:ProductoId ;
               HEADER "Producto: " + Alltrim( oRs:ProductoId ) + "-" + oRs:DescProd font 1
     
     END REPORT
     
     oReport:bInit :=  {|| oRs:movefirst()}
     oReport:bSkip :=  {|| oRs:movenext()}
   
     ACTIVATE REPORT oReport WHILE !oRs:Eof() ON STARTGROUP oReport:NewLine()  ;
                                              ON STARTPAGE  StartPage()

Este es el resultado, la ultima columna en blanco.



¿Que podrá ser?

[cmsoft]

José:
Al estar SUMMARY, y la columna 3 no tener TOTAL, es esperable que salga de esa manera.
Agrega la clausula TOTAL a la columna 3

Code: Select all  Expand view  RUN

COLUMN TITLE "Peso Promedio";  
               DATA ( oRs:PesoNeto / oRs:Cantidad ) ;
               PICTURE "999,999.99"   ;
               SIZE 12                ;          
               TOTAL;
               FONT 1

[jose_murugosa]

Muchas gracias por tu respuesta César.
Tienes razón, no me había dado cuenta.

Pero ahora el problema es otro, el total en la columna de peso neto me da igual que el de peso neto/cantidad.

Code: Select all  Expand view  RUN

          PRINT oPrn FILE ".\PDFS\" + wfecha + "-" + whora + ".pdf"
          REPORT oReport ;
               TITLE  "*** Informe de Entrada al Desosado ***",;
                    wfecha + " de las " + wHorainic + " hasta las " + wHoraFin ;
               HEADER "Fecha: " + dtoc(date()),;
                    "Hora:  " + time() ;
                    RIGHT ;
                    FOOTER "Página: " + str(oReport:nPage,4) ;
                    CENTERED ;
                    SUMMARY ;
                    TO DEVICE oPrn
           
          COLUMN TITLE "Cantidad" ;
               DATA oRs:Cantidad  ;
               PICTURE "99,999"   ;
               SIZE 14            ;
               FONT 1             ;
               TOTAL
     
          COLUMN TITLE "Peso Neto";  
               DATA oRs:PesoNeto  ;
               PICTURE "99,999.99";
               SIZE 12            ;          
               FONT 1             ;
               TOTAL
         
          COLUMN TITLE "Peso Promedio";  
               DATA ( oRs:PesoNeto / oRs:Cantidad ) ;
               PICTURE "999,999.99"   ;
               SIZE 12                ;          
               FONT 1                 ;        
               TOTAL

OTRA PREGUNTA: EXISTE UNA CLAUSULA PARA QUE EN LUGAR DE TOTALIZAR SAQUE UN PROMEDIO

[cmsoft]

Segun lo que entiendo, debería darte la suma de los precios promedios...
Puedes cambiarle la formula de calculo del total a la columna 3,
oReport:aColumns[3]:btotalexpr = {|| Tufuncion()}
Pero nunca lo he hecho, habría que buscar en el foro a ver si hay ejemplos.

[FranciscoA]

José:
Nunca lo he hecho con SUMARY y SQL, pero intenta asi:

Code: Select all  Expand view  RUN

oReport:bEndGroup:={||  oReport:aGroups[1]:aTotal[3]:= (oReport:aGroups[1]:aTotal[2] / oReport:aGroups[1]:aTotal[1] )  }

[jose_murugosa]

Queridos Francisco y César

Gracias mil por vuestra ayuda!!!!!

Finalmente quedó con estos cambios:

Code: Select all  Expand view  RUN

          oReport:bEndGroup  := {|| oReport:aGroups[1]:aTotal[3]:= (oReport:aGroups[1]:aTotal[2] / oReport:aGroups[1]:aTotal[1] )  }
          oReport:bEnd           := {|| oReport:aColumns[3]:nTotal := oReport:aColumns[2]:nTotal / oReport:aColumns[1]:nTotal }
          oReport:bInit           := {|| oRs:movefirst()}
          oReport:bSkip          := {|| oRs:movenext()}
          oReport:lPageTotal  := .f.
 

Gracias por dedicarme tiempo para que pudiera salir del atolladero.