XBROWSE y color

[FiveWiDi]

Hola a todos,

Tengo un XBROWSE definido a código.

El caso es que cuando la row que tenía el foco pierde el foco, toma el color negro de texto y de fondo. ¿Cómo lo puedo cambiar?

Muchas gracias

[cmsoft]

Prueba asi:

Code: Select all  Expand view  RUN

     oBrw:bClrStd := { || If( oBrw:KeyNo() % 2 == 0, { CLR_BLACK, RGB(193,221,255)},  { CLR_BLACK, RGB(221,245,255)} ) }      //Efecto pijama
     oBrw:bClrSel := {|| { nRGB(  0,  0,  0), nRGB(248,195, 34) } } // Celda Seleccionada
     oBrw:lColDividerComplete  := .t.                    
     oBrw:nColDividerStyle     := LINESTYLE_INSET
     oBrw:nRowDividerStyle     := LINESTYLE_INSET
     oBrw:bClrSelFocus  := {|| { nRGB(  0,  0,  0), nRGB(248,195, 34) } }  // para barra de linea selecc cuando el control tiene el foco
     oBrw:nMarqueeStyle    := MARQSTYLE_HIGHLCELL  //solo ilumina la celda actual
 

[karinha]

Buenm dia.

Code: Select all  Expand view  RUN

// Cores na xBrowse
static function BrwColors( oBrw, lFoot )

   local cClrBack
   DEFAULT lFoot          := .F.

   oBrw:l2007             := .F.
   oBrw:nRowHeight        := 24
   oBrw:nHeaderHeight     := 24
   oBrw:lFooter               := lFoot
   
   //oBrw:lRecordSelector     := .F.
   //oBrw:lColDividerComplete := .F.
   //oBrw:lRowDividerComplete := .F.
   
   oBrw:lFlatStyle        := .T.
   oBrw:bClrHeader        := { || { CLR_BLACK, CLR_WHITE, CLR_WHITE } } //RGB( 232, 255, 232 ), RGB( 232, 255, 232 ) }}
   oBrw:lFullGrid         := .F.
   oBrw:nRowDividerStyle  := LINESTYLE_NOLINES //DARKGRAY  //LINESTYLE_LIGHTGRAY      //
   oBrw:nColDividerStyle  := LINESTYLE_NOLINES //LIGHTGRAY // LINESTYLE_NOLINES

   oBrw:nMarqueeStyle := MARQSTYLE_HIGHLROW
   oBrw:bClrStd = { || If( oBrw:KeyNo() % 2 == 0, ;
                         { If( ( oBrw:cAlias )->( Deleted() ), CLR_HRED, CLR_BLUE ),;
                           RGB( 198, 255, 198 ) }, ;
                         { If( ( oBrw:cAlias )->( Deleted() ), CLR_HRED, CLR_BLUE ),;
                           RGB( 232, 255, 232 ) } ) }
   oBrw:bClrSel = { || { If( ( oBrw:cAlias )->( Deleted() ), CLR_HRED, CLR_WHITE ),;
                           RGB( 34, 177, 76 ) } } //RGB( 0x33, 0x66, 0xCC ) } }
   
   cClrBack = Eval( oBrw:bClrSelFocus )[ 2 ]
   oBrw:bClrSelFocus  := { || { If( ( oBrw:cAlias )->( Deleted() ), CLR_HRED, CLR_WHITE ),;
                              cClrBack } }
   oBrw:SetColor( CLR_BLUE, RGB( 232, 255, 232 ) )

   oBrw:SetFont( oFont1 )

return nil
 

Regards, saludos.

[FiveWiDi]

Muchas gracias a ambos, lo pruebo.