FiveWin Power : New Scroll Msg class

[karinha]

Como hago esto usando RECURSOS del WorkShop.exe?

Code: Select all  Expand view

// C:\FWH..\SAMPLES\DSAY2.PRG

#Include "FiveWin.ch"

FUNCTION Main()


   LOCAL cText := MemoRead( "c:\fwh\samples\maria01.prg" )
   LOCAL oDlg, oMsg, oFont, oBold

   DEFINE FONT oFont NAME "LUCIDA CONSOLE" SIZE 0,-14
   DEFINE FONT oBold NAME "VERDANA" SIZE 0,-32

   DEFINE DIALOG oDlg SIZE 800, 500 PIXEL TRUEPIXEL

   oDlg:lHelpIcon := .F.

   @ 100,100 SCROLLMSG "FiveWin Power : New Scroll Msg class" ;
      SIZE 600, 40 PIXEL OF oDlg                              ;
      FONT oBold COLOR CLR_BLACK, CLR_HGREEN HORIZONTAL       ;
      SPEED 1

   @ 200,100 SCROLLMSG oMsg TEXT cText SIZE 600, 200 PIXEL OF oDlg ;
      FONT oFont COLOR CLR_HRED, CLR_YELLOW SPEED 1

   ACTIVATE DIALOG oDlg CENTERED

   RELEASE FONT oFont, oBold

RETURN NIL

// FIN
 

Gracias.

Regards, saludos.

[cmsoft]

En la definicion no tiene un REDEFINE

Igualmente puedes hacerlo por la misma clase

Code: Select all  Expand view

#Include "FiveWin.ch"

FUNCTION Main()


   LOCAL cText := MemoRead( "c:\fwh21\samples\dsay2.prg" )
   LOCAL oDlg, oMsg1, oMsg2, oFont, oBold

   DEFINE FONT oFont NAME "LUCIDA CONSOLE" SIZE 0,-14
   DEFINE FONT oBold NAME "VERDANA" SIZE 0,-32

   DEFINE DIALOG oDlg RESOURCE "ABMS"

   oDlg:lHelpIcon := .F.

   //REDEFINE PANEL oMsg1 ID 4001 OF oDlg NOBORDER
   //REDEFINE PANEL oMsg2 ID 4002 OF oDlg NOBORDER

   /*@ 100,100 SCROLLMSG "FiveWin Power : New Scroll Msg class" ;
      SIZE 600, 40 PIXEL OF oDlg                              ;
      FONT oBold COLOR CLR_BLACK, CLR_HGREEN HORIZONTAL       ;
      SPEED 1

   @ 200,100 SCROLLMSG oMsg TEXT cText SIZE 600, 200 PIXEL OF oDlg ;
      FONT oFont COLOR CLR_HRED, CLR_YELLOW SPEED 1*/
   oMsg1 := TScrollMsg():New( 0, 0, 600, 40, "FiveWin Power : New Scroll Msg class",;
             oDlg, oBold, 1, ;
             CLR_BLACK, CLR_HGREEN, .T.,.T., ;
             .F. )
   oMsg2 := TScrollMsg():New( 0, 0, 600, 200, cText,;
             oDlg, oFont, 1, ;
             CLR_HRED, CLR_YELLOW, .F.,.T., ;
             .F. )

   oMsg1:nId := 4001
   oMsg2:nId := 4002

   ACTIVATE DIALOG oDlg CENTERED

   RELEASE FONT oFont, oBold

RETURN NIL
 

Y el RC

Code: Select all  Expand view

ABMS DIALOG DISCARDABLE 6, 18, 366, 198
STYLE WS_POPUP|DS_MODALFRAME|WS_CAPTION|WS_SYSMENU|WS_VISIBLE
CAPTION "SCROLL MSG"
FONT 8, "Tahoma"
{
  CONTROL "", 4001, "Static", WS_GROUP, 12, 8, 336, 36
  CONTROL "", 4002, "Static", WS_GROUP, 12, 52, 340, 136
}
 

[karinha]

Perfecto César.

Muchas gracias.

Regards, saludos.