Dos de xBrowse

[Armando]

Amigo y colegas:

en xBrowse con FASTEDIT en una columna utilizo EDIT_GET_BUTTON, para mostrar un BMP en el boton
usan el siguiente código

Code: Select all | Expand

:AddBmpFile("Ruta y nombre del bmlp")
 

Esto para tomar el BMP desde un file, y para tomarlo de recursos como es el código?

Abusando de su gentileza, un ejemplo para un checkbox tambien en xBrowse con FASTEDIT

Saludos y gracias anticipadas

[leandro]

Amigo buenas noches como estas?

Creo que es lo que necesitas

Code: Select all | Expand

oCol:AddResource( "nombrerecurso" )

[Armando]

Hola Leandro Amigo:

Te agradezco la respuesta pero no me aparece el BMP, se ve el botón pero sin imágen
este es el código, tal vez me falta algo?

Code: Select all | Expand

WITH OBJECT :aCols[01]
   :cOrder           := "A"
   :nHeadStrAlign       := AL_LEFT
   :AddResource( "BUS16" )
   :lBmpStretch      := (.T.)
   :bEditBlock       := { | | MsgInfo("Hola carola !")  }
END
 

Abusando de tu apoyo, cual es el código para un CHECKBOX?, igual en un TXBrowse FASTEDIT

Saludos

[leandro]

Amigo este es el código como lo tengo definido

Code: Select all | Expand

    oCol          = oBrwReci:AddCol()
    oCol:bStrData := {|| if(Len( ::detalle ) > 0 , Transform(::detalle[oBrwReci:nArrayAt]["id"],oLamcla:PIC9) ,"" ) }
    oCol:AddResource( oLamcla:cIcoAgr ) 
    oCol:cHeader  = "Item"
    oCol:nWidth   = 30
    oCol:nHeadStrAlign = AL_LEFT
    oCol:nDataStrAlign = AL_LEFT    
    oCol:oHeaderFont = oFont
    oCol:nFootBmpNo    := 1
    oCol:bLClickFooter := {|r,c,f,o| ::lNuevoItem := .T. ,::tipopago(cbTipItem) }
 

[leandro]

y así esta con checkbox

Code: Select all | Expand

WITH OBJECT oBrw
    :aCols[1]:AddResource({oLamcla:cIcoLlAb,oLamcla:cIcoLlDe,oLamcla:cIcoLlIt})
    :aCols[1]:nWidth   := 300

    :aCols[2]:bEditValue := {|| oBrw:oTreeItem:Cargo[2] }
    :aCols[2]:cDataType  := "L"
    :aCols[2]:nEditType := EDIT_GET
    :aCols[2]:SetCheck()
    :aCols[2]:bOnPostEdit    := { | o, x, n | EVAL(cbCambioEstado,x,oBrw:oTreeItem:Cargo[1]) }      
END 
 

[Armando]

Leandro:

Muchas gracias.

Voy a probarlos

[nageswaragunupudi]

oCol:nBtnBmp := <imagefile/resourcename>

[Armando]

Master. Mr. Rao:

Thank you so much

Best regards

[nageswaragunupudi]

Please try this sample

Code: Select all | Expand

#include "fivewin.ch"

REQUEST DBFCDX

function Main()

   local aStates
   local oDlg, oBrw, oFont

   SetGetColorFocus()

   USE STATES
   aStates  := FW_DbfToArray()
   CLOSE STATES

   USE CUSTOMER NEW SHARED VIA "DBFCDX"

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-16
   DEFINE DIALOG oDlg SIZE 700,400 PIXEL TRUEPIXEL FONT oFont
   @ 20,20 XBROWSE oBrw SIZE -20,-20 PIXEL OF oDlg ;
      DATASOURCE "CUSTOMER" ;
      COLUMNS "FIRST AS NAME", "CITY", "STATE", "MARRIED", "MARRIED AS STATUS" ;
      COLSIZES 140,140,140 ;
      LINES NOBORDER

   WITH OBJECT oBrw
      :nRowHeight    := 30
      WITH OBJECT :City
         :nEditType     := EDIT_GET_BUTTON
         :bEditBlock    := < |r,c,oCol|
               local cCity := oCol:Value
               if !MsgGet( "CITY", "Name", @cCity ) .or. ;
                  Empty( cCity ) .or. ;
                  Trim( cCity ) == Trim( oCol:Value )
                  cCity := nil  // return nil for no change
               endif
               return cCity
               >

         :nBtnWidth     := 30
         :nBtnBmp       := "..\icons\mouse.ico"
      END
      WITH OBJECT :State
         :nEditType     := EDIT_LISTBOX
         :aEditListTxt  := aStates
         :bClrEdit      := { || { CLR_BLACK, CLR_YELLOW } }
         :nBtnWidth     := 30
         :nBtnBmp       := "..\bitmaps\dialog.bmp"
      END
      WITH OBJECT :Married
         :SetCheck( nil, .t. )
      END
      WITH OBJECT :Status
         :SetCheck( { "..\bitmaps\users.bmp", "..\bitmaps\user.bmp" }, ;
            .t., ;
            { "Married", "Single" } )
      END
      //
      :CreateFromCode()
   END

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil
 

[Armando]

Mr. Rao:

Awesome!

Thank you so much

With best regards