Consulta sobre la clase folderEx

[TecniSoftware]

Hay alguna manera de que un objeto TFolderEx no pinte las pestañas?
La idea es hacer que la seleccion sea mediante un xbrowse a la izquierda, por ello no quiero ver las pestañas.
He intentado con oFolder:nFolderHeight := 0 pero algo hace que se trabe y funcione con mucha lentitud y mal.

Lo que deseo hacer es un dialogo con una serie de items a la izquierda en un xbrowse, que al ir cambiando de fila, a la derecha seleccione
un TScrollPanel diferente que tendrá varios controles.

Agradezco cualquier ayuda.

[Antonio Linares]

Estimado Alejandro,

Creas el diálogo desde código fuente ó usando recursos ?

[TecniSoftware]

Antonio

Creo el diálogo desde código.

Muchas gracias

[nageswaragunupudi]

Use Pages, instead of Folder or FolderEx.

[Antonio Linares]

Estimado Alejandro,

Aqui tienes un ejemplo funcionando: (Incluido en el próximo build de FWH)

Code: Select all  Expand view  RUN

#include "FiveWin.ch"

function Main()

   local oDlg, oXBrw, oPages
 
   DEFINE DIALOG oDlg SIZE 600, 400 PIXEL TRUEPIXEL ;
      TITLE "XBrowse and Pages"
 
   @ 10, 20 XBROWSE oXBrw SIZE 160, 200 PIXEL OF oDlg;
      DATASOURCE { "First", "Second" } AUTOCOLS ;
      HEADERS "Page" NOBORDER
 
   WITH OBJECT oXBrw
      :nStretchCol   := 1
      :lHScroll      := .f.
      :bChange = { || oPages:SetOption( oXBrw:BookMark ) }
      :CreateFromCode()
   END
 
   oPages = TPages():New( 10, 200, 380, 580, oDlg )
 
   ACTIVATE DIALOG oDlg CENTERED ;
      ON INIT BuildPages( oPages )
 
return nil

function BuildPages( oPages )

   local oScrPanel1 := TScrollPanel():New( 0, 0, 300, 300, oPages )
   local oScrPanel2 := TScrollPanel():New( 0, 0, 300, 300, oPages )

   @  1, 1 SAY "Hello" OF oScrPanel1
   @ 10, 1 SAY "Bye"   OF oScrPanel1
   oScrPanel1:SetRange()

   oPages:AddPage( oScrPanel1 )

   @  1, 1 SAY "Another page" OF oScrPanel2
   @ 10, 1 SAY "End"   OF oScrPanel2
   oScrPanel2:SetRange()

   oPages:AddPage( oScrPanel2 )

   oPages:SetOption( 1 )

return .T.    

[TecniSoftware]

Estimado Alejandro,

Aqui tienes un ejemplo funcionando: (Incluido en el próximo build de FWH)

Excelente Antonio, muchas gracias!
Justo lo que necesitaba!