SE PODRA EJECUTAR control desk.cpl DESDE FWH?

[AIDA]

Hola

se podra ejecutar control desk.cpl desde una aplicacion FWH

si es que se puede que tengo que hacer


Gracias por todo


Aida

[Rochinha]

Exemplo:

Code: Select all  Expand view  RUN

/*
  Controlando el Sistema desde Fivewin
  by TheFull & Joaquim Ferrer (2000)

  Hola a Todos,
  Aqui os dejamos estos TIPS para el Disfrute del Personal.
  */
#include "FiveWin.ch"
#include "dll.ch"

#DEFINE WM_SYSCOMMAND  274     // &H112
#DEFINE SC_TASKLIST   61744    //&HF130
#DEFINE SC_SCREENSAVE 61760   // &HF140
#DEFINE SW_HIDE           0   // &H0
#DEFINE SW_SHOWNA         8   // &H8
#DEFINE SW_SHOW           5   // &H5
#DEFINE SW_SHOWNORMAL     1
#DEFINE SC_MONITORPOWER  61808   //&HF170   Gracias a Ramon Ramirez por la info
#DEFINE SM_CLEANBOOT     67

Static oWnd
Function Main()

   local oBar, oFnt

   // Lanzo conexion a Internet          |-----------> Nombre Conexion
   //Winexec("rundll rnaui.dll,RnaDial Uni2",0);

   DEFINE WINDOW oWnd FROM 1, 1 To 22, 75 ;
      TITLE "Controlando el Sistema desde Fivewin"

   DEFINE BUTTONBAR oBar OF oWnd SIZE 150,26 3D

   DEFINE FONT oFnt NAME "Arial" SIZE 0, 12

   DEFINE BUTTON OF oBar  PROMPT "Disable Barra " FONT oFnt ;
                    ACTION ( EnableWindow(FindWindowEx(FindWindow('Shell_TrayWnd', nil), 0, 'Button', nil), .F. ) )
   DEFINE BUTTON OF oBar  PROMPT "Enable Barra " FONT oFnt ;
                    ACTION ( EnableWindow(FindWindowEx(FindWindow('Shell_TrayWnd', nil), 0, 'Button', nil), .T.  ) )
   // Ocultar Iconos del Escritorio
   DEFINE BUTTON OF oBar  PROMPT "Ocultar iconos del Escritorio " FONT oFnt ACTION ShowWindow( FindWindow(nil,'Program Manager'), SW_HIDE)
   // Mostrar Iconos del Escritorio
   DEFINE BUTTON OF oBar  PROMPT "Mostrar Iconos del Escritorio " FONT oFnt ACTION ShowWindow( FindWindow(nil,'Program Manager'), SW_SHOW)
   // Ocultar Barra de Tareas de WIndows
   DEFINE BUTTON OF oBar  PROMPT "Ocultar Barra de Tareas " FONT oFnt ACTION ShowWindow(FindWindow( 'Shell_TrayWnd',nil), SW_HIDE )
   // Mostrar Barra de Tareas de WIndows
   DEFINE BUTTON OF oBar  PROMPT "Mostrar Barra de Tareas " FONT oFnt ACTION ShowWindow(FindWindow( 'Shell_TrayWnd',nil), SW_SHOWNA)
   // Pulsar el boton de Inicio
   DEFINE BUTTON OF oBar  PROMPT "Boton Inicio" FONT oFnt ACTION (SendMessage(oWnd:hWnd,WM_SYSCOMMAND,SC_TASKLIST,0))
   // Lanza el salvapantallas
   DEFINE BUTTON OF oBar  PROMPT "Salvapantallas" FONT oFnt ACTION GetForeWin( ) // GetDeskWin( ) // (SendMessage(oWnd:hWnd,WM_SYSCOMMAND,SC_SCREENSAVE,0))
   // Abrir el Panel de Control
   DEFINE BUTTON OF oBar  PROMPT "Panel Control" FONT oFnt ACTION (Control("shell32.dll,Control_RunDLL",oWnd))
   // Mostrar el diálogo 'Agregar/Quitar programas' (Instalar/Desinstalar)
   DEFINE BUTTON OF oBar  PROMPT "Agregar/Quitar programas" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL appwiz.cpl,,1',oWnd))
   //Mostrar el diálogo 'Agregar/Quitar componentes de windows' (Instalar/Desinstalar)
   DEFINE BUTTON OF oBar  PROMPT "Agregar Componentes" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL appwiz.cpl,,2',oWnd))
   //Crear Disco de Sistema
   DEFINE BUTTON OF oBar  PROMPT "Disco Inicio" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL appwiz.cpl,,3',oWnd))
   //Mostrar el diálogo 'Propiedades de pantalla (Fondo)'
   DEFINE BUTTON OF oBar  PROMPT "Pantalla(Fondo)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL desk.cpl,,0',oWnd))
   //Mostrar el diálogo 'Propiedades de pantalla (Protector de Pantalla)'
   DEFINE BUTTON OF oBar  PROMPT "Pantalla(Protector) " FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL desk.cpl,,1',oWnd))
   //Mostrar el diálogo 'Propiedades de pantalla (Apariencia)'
   DEFINE BUTTON OF oBar  PROMPT "Pantalla(Apariencia)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL desk.cpl,,2',oWnd))
   //Mostrar el diálogo 'Propiedades de pantalla (Configuracion)'
   DEFINE BUTTON OF oBar  PROMPT "Pantalla(Propiedades)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL desk.cpl,,3',oWnd))
   //Mostrar el diálogo 'Busqueda rápida'
   DEFINE BUTTON OF oBar  PROMPT "Busqueda rapida" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL findfast.cpl',oWnd))
   //Mostrar el diálogo 'Internet (General)
   DEFINE BUTTON OF oBar  PROMPT "Internet General" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL inetcpl.cpl,,0',oWnd))
   //Mostrar el diálogo 'Internet (Seguridad)'
   DEFINE BUTTON OF oBar  PROMPT "Internet Seguridad" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL inetcpl.cpl,,1',oWnd))
   //Mostrar el diálogo 'Internet (Contenido)'
   DEFINE BUTTON OF oBar  PROMPT "Internet Contenido" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL inetcpl.cpl,,2',oWnd))
   //Mostrar el diálogo 'Internet (Conexion)'
   DEFINE BUTTON OF oBar  PROMPT "Internet Conexion" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL inetcpl.cpl,,3',oWnd))
   //Mostrar el diálogo 'Internet (Programas)'
   DEFINE BUTTON OF oBar  PROMPT "Internet Progrograma" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL inetcpl.cpl,,4',oWnd))
   //Mostrar el diálogo 'Internet (Avanzado)'
   DEFINE BUTTON OF oBar  PROMPT "Internet Avanzado" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL inetcpl.cpl,,5',oWnd))
   //Mostrar el diálogo 'Propiedades de Configuracion Regional (Configuracion Regional)
   DEFINE BUTTON OF oBar  PROMPT "Config.Regional" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL intl.cpl,,0',oWnd))
   //Mostrar el diálogo 'Propiedades de Configuracion Regional (Numero)'
   DEFINE BUTTON OF oBar  PROMPT "Config.Reg.Numero" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL intl.cpl,,1',oWnd))
   //Mostrar el diálogo 'Propiedades de Configuracion Regional (Moneda)'
   DEFINE BUTTON OF oBar  PROMPT "Config.Reg.Moneda" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL intl.cpl,,2',oWnd))
   //Mostrar el diálogo 'Propiedades de Configuracion Regional (Hora)'
   DEFINE BUTTON OF oBar  PROMPT "Config.Reg.Hora" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL intl.cpl,,3',oWnd))
   //Mostrar el diálogo 'Propiedades de Configuracion Regional (Fecha)'
   DEFINE BUTTON OF oBar  PROMPT "Config.Reg.Fecha" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL intl.cpl,,4',oWnd))
   //Mostrar el diálogo 'Dispositivos de Juego (General)'
   DEFINE BUTTON OF oBar  PROMPT "Juegos(General)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL joy.cpl,,0',oWnd))
   //Mostrar el diálogo 'Dispositivos de Juego (Avanzado)'
   DEFINE BUTTON OF oBar  PROMPT "Juegos(Avanzado)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL joy.cpl,,0',oWnd))
   //Mostrar el diálogo 'Raton'
   DEFINE BUTTON OF oBar  PROMPT "Raton" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL main.cpl @0',oWnd))
   //Mostrar el diálogo 'Teclado'
   DEFINE BUTTON OF oBar  PROMPT "Teclado" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL main.cpl @1',oWnd))
   //Mostrar el diálogo 'Impresora'
   DEFINE BUTTON OF oBar  PROMPT "Impresora" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL main.cpl @2',oWnd))
   //Mostrar el diálogo 'Fuentes'
   DEFINE BUTTON OF oBar  PROMPT "Fuentes" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL main.cpl @3',oWnd))
   //Mostrar el diálogo 'Propiedades Multimedia (Sonido)'
   DEFINE BUTTON OF oBar  PROMPT "Multimedia(Sonido)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL mmsys.cpl,,0',oWnd))
   //Mostrar el diálogo 'Propiedades Multimedia (Video)'
   DEFINE BUTTON OF oBar  PROMPT "Multimedia(Video)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL mmsys.cpl,,1',oWnd))
   //Mostrar el diálogo 'Propiedades Multimedia (Midi)'
   DEFINE BUTTON OF oBar  PROMPT "Multimedia(Midi)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL mmsys.cpl,,2',oWnd))
   //Mostrar el diálogo 'Propiedades Multimedia (Cd audio)'
   DEFINE BUTTON OF oBar  PROMPT "Multimedia(Cd Audio)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL mmsys.cpl,,3',oWnd))
   //Mostrar el diálogo 'Propiedades Multimedia (Dispositivos)'
   DEFINE BUTTON OF oBar  PROMPT "Multimedia(Dispositivos)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL mmsys.cpl,,4',oWnd))
   //Mostrar el diálogo 'Propiedades de red'
   DEFINE BUTTON OF oBar  PROMPT "Propiedades de Red" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL netcpl.cpl',oWnd))
   //Mostrar el diálogo 'Asistente para conexión de red'
   DEFINE BUTTON OF oBar  PROMPT "Asistente Conexion Red" FONT oFnt ACTION (Control('rnaui.dll,RnaWizard',oWnd))
   //Mostrar el diálogo 'Administracion OBDC'
   DEFINE BUTTON OF oBar  PROMPT "Administracion OBDC" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL odbccp32.cpl',oWnd))
   //Mostrar el diálogo 'Sistema (General)'
   DEFINE BUTTON OF oBar  PROMPT "Sistema(General)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL sysdm.cpl,,0',oWnd))
   //Mostrar el diálogo 'Sistema (Dispositivos)'
   DEFINE BUTTON OF oBar  PROMPT "Sistema(Dispositivos)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL sysdm.cpl,,1',oWnd))
   //Mostrar el diálogo 'Sistema (Perfiles hardware)'
   DEFINE BUTTON OF oBar  PROMPT "Sistema(Perfiles)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL sysdm.cpl,,2',oWnd))
   //Mostrar el diálogo 'Sistema (Rendimiento)'
   DEFINE BUTTON OF oBar  PROMPT "Sistema(Rendimiento)" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL sysdm.cpl,,3',oWnd))
   //Mostrar el diálogo 'Asistente hardware'
   DEFINE BUTTON OF oBar  PROMPT "Asistente Hardware" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL sysdm.cpl @1',oWnd))
   //Mostrar el diálogo 'Asistente para añadir impresoras'
   DEFINE BUTTON OF oBar  PROMPT "Asistente Impresoras" FONT oFnt ACTION (Control('shell32.dll,SHHelpShortcuts_RunDLL AddPrinter',oWnd))
   //Mostrar el diálogo 'Temas de escritorio'
   DEFINE BUTTON OF oBar  PROMPT "Temas Escritorio" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL themes.cpl',oWnd))
   //Mostrar el diálogo 'Fecha/Hora (General)'
   DEFINE BUTTON OF oBar  PROMPT "Fecha/Hora General" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL timedate.cpl',oWnd))
   //Mostrar el diálogo 'Fecha/Hora (Zona horaria)'
   DEFINE BUTTON OF oBar  PROMPT "Fecha/Hora  Zona" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL timedate.cpl,,/f',oWnd))
   //Mostrar el diálogo 'Asistente para añadir modem'
   DEFINE BUTTON OF oBar  PROMPT "Asistente Modem" FONT oFnt ACTION (Control('shell32.dll,Control_RunDLL modem.cpl,,add',oWnd))
   //Mostrar el diálogo 'Instalar TCP/IP'
   DEFINE BUTTON OF oBar  PROMPT "Instalar Tcp/IP" FONT oFnt ACTION (Control('setupapi.dll,InstallHinfSection MSTCP.Install 4 nettrans.inf',oWnd))
   //Mostrar el diálogo 'Instalar Adaptador telefonico para redes'
   DEFINE BUTTON OF oBar  PROMPT "Instalar Adap.Tele.Redes" FONT oFnt ACTION (Control('setupx.dll,InstallHinfSection RNA 12345 rna.inf',oWnd))
   //Mostrar el diálogo 'Llamar a traves del acceso telefonico'
   DEFINE BUTTON OF oBar  PROMPT "LLama Tel" FONT oFnt ACTION (Control('rnaui.dll,RnaDial DUNConnectionName',oWnd))
   //Mostrar Dialogo de Formateando discos
   // Donde esta el 0 ->Formateo Rapido
   // Si pones   el 1 ->Formateo Total
   // Si pones   el 2 ->Copiar Solamente Archivos Sistema
   DEFINE BUTTON OF oBar  PROMPT "Formateando.." FONT oFnt ;
      ACTION ( ShellExecute(oWnd:hWnd,"Open","C:\Windows\Rundll32.exe","Shell32.dll,SHFormatDrive","C:\WINDOWS",0))
   //Apagar el Equipo si nos deja otras aplicaciones que esten abiertas
   DEFINE BUTTON OF oBar  PROMPT "Apagar Equipo Confirma." FONT oFnt ACTION ( Apaga(1,0) )
   //Reiniciar el equipo
   DEFINE BUTTON OF oBar  PROMPT "Reiniciar el Equipo." FONT oFnt    ACTION ( Apaga(2,0) )
   //Apagar el Equipo sin pedir confirmacion ni nada. Las aplicaciones abiertas que se las apañen.. ;)
   DEFINE BUTTON OF oBar  PROMPT "Apaga y Vamonos XD." FONT oFnt     ACTION ( Apaga(5,0) )
   //Lanza el navegador por defecto
   DEFINE BUTTON OF oBar  PROMPT "Navegador" FONT oFnt ;
          ACTION ShellExecute( GetActiveWindow() ,nil,'c:\html\index.htm','','',SW_SHOW)
   // Apagamos( bajo consumo ) y encedemos el Monitor
   // Ojo!! Si lo apagas, la unica manera de encenderlo es con la instruccion con contiene -1
   // En un timer funcionaria de muerte!!!
   DEFINE BUTTON OF oBar  PROMPT "Apagando / Encendiendo Monitor " FONT oFnt ;
     ACTION ( SendMessage(oWnd:hWnd, WM_SYSCOMMAND, SC_MONITORPOWER, 0 ),syswait(20),;
              SendMessage(oWnd:hWnd, WM_SYSCOMMAND, SC_MONITORPOWER, -1 ))
   // Saber como Arranque de Windows
   //   0- Si se hizo un arranque normal
   //   1- Si se hizo un arranque a prueba de fallos
   //   2- Si se hizo un arranque a prueba de fallos con arranque en red
   DEFINE BUTTON OF oBar  PROMPT "Como he arrancado Win? " FONT oFnt ;
          ACTION ( MsgInfo( GetSysTemMetrics(SM_CLEANBOOT))  )

   // Barra flotante en el INIT de la Ventana porque la Clausula FLOAT en la
   // barra se hace la 'titola' un lio
   ACTIVATE WINDOW oWnd MAXIMIZED ON INIT ( oBar:Float() )
   oFnt:End()
   // Por si acaso nos vamos con la barra ocultada
   ShowWindow(FindWindow( 'Shell_TrayWnd',nil), SW_SHOWNA)
return nil
//

// Funcion Generica
// Recibe : cString - Cadena a montar ( orden )
//        : oWnd    - Ventana para coger el Handle
function Control(cString,oWnd)
   Local Result := ShellExecute(oWnd:hWnd, nil,GetWinDir()+'\system32\rundll32.exe',;
                         cString, nil, SW_SHOW)
   RETURN NIL

function GetSysTemMetrics(cString,oWnd)
   RETURN GetSysMetrics(cString)

function FindWindowEx(cString)
   RETURN .t.

DLL32 Function Apaga(uFlags As LONG,dwReserved AS LONG) ;
    AS LONG PASCAL FROM "ExitWindowsEx" LIB "USER32.DLL"

DLL32 FUNCTION GetDeskWin( ) ;
    AS LONG PASCAL  FROM "GetDesktopWindow" LIB "USER32.DLL"

DLL32 FUNCTION GetForeWin( );
   AS LONG PASCAL;
   FROM "GetForegroundWindow" LIB "USER32.DLL"


[AIDA]

Gracias Rochinha

si me sirvio de mucho

que lindo Gracias

Aida