Busqueda con xBrowse

[Francis]

Hola a todos del foro
Como hago para que al hacer una busqueda incremental con xbrowse, me salga lo que estoy digitando en un say, uso fwh8.10.
El xbrowse es creado con recursos, uso la clausula autosort para la busqueda...
Con el antiguo twbrowse se podia hacer esto...pero me gusta mas el xBrowse por su facilidad y demas avances.
Salu2

Francis

[Daniel Garcia-Gil]

Hola Francis...

que tipo de datos usas, RecordSet, Arrays, Dbf?

[Francis]

Hola Daniel

Uso DBF..

Salu2

[Francis]

alguna ayuda?

salu2

francis

[Daniel Garcia-Gil]

Francis

revisa fwh\samples\testxbrw.prg

[Francis]

hola

pues ya revise, pero no veo como hacer uso del say para ver lo que estoy buscando con busqueda incremental...

salu2

francis

[Francis]

hola a todos

creo que no se puede...

gracias de todas maneras

salu2

francis

[Daniel Garcia-Gil]

Hola Francis...

Una ventaja que tenemos con FW es que podemos ver las clases internamentes, revisa la xbrowse y te conseguiras con esta data:

Code: Select all  Expand view

oSeek,;      // Optional TSay control to display the value of current ::cSeek value

te dejo un ejemplo bastanta basico epero te sirva, usa la misma dbf que viene con los ejemplos de FW

Code: Select all  Expand view

#include "FiveWin.ch"
#include "InKey.ch"
#include "xbrowse.ch"


REQUEST DBFCDX


function Main()

   local oWnd, oBmp, oBar


   CheckCustCdx()

   USE CUSTOMER NEW SHARED VIA "DBFCDX"
   SET ORDER TO TAG FIRST
   GO TOP

   DEFINE WINDOW oWnd TITLE "New TXBrowse class (only for FWH)"
     
   define buttonbar oBar of oWnd size 32,32
   
   define button prompt "Test" of oBar action( Incremental( oWnd ) )
     
   SET MESSAGE OF oWnd TO FWVERSION + ", " + FWCOPYRIGHT CENTERED TIME DATE

   ACTIVATE WINDOW oWnd

return nil

//----------------------------------------------------------------------------//

STATIC FUNCTION Incremental( oWnd )

   local oChild, oBrw, oSay, cTexto := "", cAlias
   
   cAlias := select()

   DEFINE dialog oChild TITLE "Incremental seek & Inset style browse" OF oWnd size 600,400 pixel
   
   @ 10,10 say "Busqueda Incremental:" of oChild size 60,12 pixel
   @ 10,65 say oSay prompt cTexto of oChild size 50,12 pixel
   
   @ 25,5 xbrowse oBrw alias cAlias autocols size 290,170 pixel
   
   oBrw:bSeek := {|c| DbSeek( Upper( c ) ) }
   oBrw:oSeek := oSay

   oBrw:CreateFromCode()


   ACTIVATE dialog oChild ON INIT ( oBrw:SetFocus(), oChild:Resize() )

RETURN NIL


//----------------------------------------------------------------------------//

static function CheckCustCdx()

   local n

   if File( "customer.cdx" )
//      if MsgYesNo( "Re-index Customer.dbf ?" )
         FErase( "customer.cdx" )
//      endif
   endif

   if !File( "customer.cdx" )
      USE CUSTOMER EXCLUSIVE VIA "DBFCDX"
      for n := 1 to FCount()
         CreateTag( FieldName( n ) )
      next
      USE
   endif

return nil

//----------------------------------------------------------------------------//

static function CreateTag( ctag )

   INDEX ON &ctag TAG &ctag

return nil

[Francis]

hola daniel

eso era lo que me faltaba... y no sabia como.

muchas gracias

salu2

francis