Dialog refresh

[MarcoBoschi]

I have a doubt but I am not able to create a minimal example to show you.

In a dialog containing several fields: gets, button, radio, one tree and images If I press TAB key
more times happens that dialog refreshes...ONCE!
Only once until I close dialog and re-open again.
This always happens on the same object.

In old compiled versions (2006) of the same project this problem does not exist

Any idea?

[MarcoBoschi]

I've just tried another recompiled application.
I've found the same problem:
- old version works fine
- new one has this fastidious problem.

more items = more evidence ==>>
It seems to be a problem in correlation with system resources
Pressing TAB I have got a refresh always in the same object.
It depends on the application and its dialog

[James Bott]

Marco,

Are you using the UPDATE clause on all the controls?

James

[MarcoBoschi]

No James
Thanks

[Antonio Linares]

Marco,

What control is repainted ? Has that control a WHEN clause ?

All of them ? What controls do you have on your dialog ?

[MarcoBoschi]

Antonio & James,
my intention is to prepare two minimal sample this w.e.
- the first one with resource
- the second one without resource
Probably this problem is more evident with many objects

However, here from my tests:
- all controls are refresh
- for instance if I put Skinbuttons() clause this refresh is in another moment
- my three tested application compiled with an older fwh version (dated 20090716) does not present this problem
-this refresh appears only once, if I close dialog and reopen presents the same problem, only Once

Have a nice we
marco

[Enrico Maria Giordano]

This is a sample of the problem. Just click on the windows and then press TAB on the dialog. You should see a refresh:

Code: Select all  Expand view  RUN

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oWnd

    DEFINE WINDOW oWnd

    ACTIVATE WINDOW oWnd;
             ON CLICK TEST()

    RETURN NIL


STATIC FUNCTION TEST()

    LOCAL oDlg

    LOCAL cVar := SPACE( 10 )

    LOCAL i

    DEFINE DIALOG oDlg;
           SIZE 900, 600;
           TITLE "Test"

    FOR i = 0 TO 59
        @ i % 20 * 15, 150 * INT( i / 20 ) GET cVar PIXEL
        @ i % 20 * 15, 150 * INT( i / 20 ) + 50 BUTTON "Test" + LTRIM( STR( i ) ) PIXEL
        @ i % 20 * 15, 150 * INT( i / 20 ) + 100 IMAGE SIZE 30, 10 PIXEL
    NEXT

    oDlg:bStart = { || oDlg:aControls[ 2 ]:SetFocus() }

    ACTIVATE DIALOG oDlg;
             CENTER

    RETURN NIL

EMG

[MarcoBoschi]

Perfect!

Thank you Enrico

[Antonio Linares]

Marco, Enrico,

Probably these lines are the culprit for such refresh, from FWH\source\classes\control.prg:

Code: Select all  Expand view  RUN

      case nMsg == WM_UPDATEUISTATE  // buttons, radios and checkboxes were erased when pressing ALT
           nResult = Super:HandleEvent( nMsg, nWParam, nLParam )
           if Upper( ::ClassName() ) == "TBTNBMP"
              ::Refresh()
           endif  
           ::oWnd:Refresh()  // This one !!!
           return nResult
 

You can comment that line to solve it, but then we get the ALT problem back again

[Enrico Maria Giordano]

Can you recall me what the ALT problem was?

EMG

[Antonio Linares]

Enrico,

It is commented in the code:

buttons, radios and checkboxes were erased when pressing ALT

[Enrico Maria Giordano]

Ok, I'm going to examine the problem...

EMG

[Enrico Maria Giordano]

I just tried to remove WM_UPDATEUISTATE handling and found that the sample I already provided at that time works just fine now:

Code: Select all  Expand view  RUN

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oWnd

    DEFINE WINDOW oWnd

    DEFINE BUTTONBAR OF oWnd 2007

    DEFINE BUTTON;
           OF oWnd:oBar;
           FILE "C:\FWH\BITMAPS\OPEN.BMP";
           ACTION MYDIALOG()

    ACTIVATE WINDOW oWnd

    RETURN NIL


STATIC FUNCTION MYDIALOG()

    LOCAL oDlg

    DEFINE DIALOG oDlg

    ACTIVATE DIALOG oDlg;
             ON INIT TOOLBAR( oDlg );
             CENTER

    RETURN NIL


STATIC FUNCTION TOOLBAR( oDlg )

    DEFINE BUTTONBAR OF oDlg 2007

    DEFINE BUTTON;
           OF oDlg:oBar;
           FILE "C:\FWH\BITMAPS\CLOSE.BMP";
           ACTION oDlg:End()

    RETURN NIL

Maybe something is changed elsewhere that solved the problem. Can you try to replicate the bitmap vanishing problem with different samples or other kind of problem with different controls (that I never faced)?

EMG

[MarcoBoschi]

Antonio, Enrico,

by first testing the problem seems to be solved

case nMsg == WM_UPDATEUISTATE // buttons, radios and checkboxes were erased when pressing ALT
nResult = Super:HandleEvent( nMsg, nWParam, nLParam )
if Upper( ::ClassName() ) == "TBTNBMP"
::Refresh()
endif
// ::oWnd:Refresh()
return nResult

Thanks a lot and congratulations!
Marco