Error with bEditValid - xBrowse

[Maurizio]

Antonio ,
In this example below bEditVAlid is executed 2 times

Code: Select all  Expand view

#include "FiveWin.ch"
#include "XBrowse.ch"

function Main()

   local oDlg, oBrw
   
   Local aDati := {{0,0,0},{0,0,0},{0,0,0} }
 
   DEFINE DIALOG oDlg RESOURCE "Test"
   REDEFINE XBROWSE oBrw ID 10 OF oDlg ARRAY aDati AUTOCOLS CELL LINES
   
   WITH OBJECT oBrw:aCols[1]
      :nEditType     := EDIT_GET
      :bEditValid    := { | oGet, oCol | MSGINFO("Hello") ,.T. }
   END
   ACTIVATE DIALOG oDlg

return nil

The RC File is

Code: Select all  Expand view

LANGUAGE LANG_ENGLISH,SUBLANG_ENGLISH_US

TEST DIALOG DISCARDABLE 68, 43, 336, 213
STYLE WS_POPUP|DS_MODALFRAME|WS_CAPTION|WS_SYSMENU|WS_VISIBLE
CAPTION "Test"
FONT 8, "MS Sans Serif"
{
  CONTROL "", 10, "TXBrowse", WS_TABSTOP|0x00a00000, 0, 0, 168, 84
}
 

But with this code it is executed correctly 1 time

Code: Select all  Expand view

#include "FiveWin.ch"
#include "XBrowse.ch"

function Main()

   local oDlg, oBrw
   
   Local aDati := {{0,0,0},{0,0,0},{0,0,0} }
   
   DEFINE WINDOW oDlg

   @ 10,10 XBROWSE oBrw OF oDlg ARRAY aDati AUTOCOLS CELL LINES
   WITH OBJECT oBrw:aCols[1]
      :nEditType     := EDIT_GET
      :bEditValid    := { | oGet, oCol | MSGINFO("Hello") ,.T. }
   END
   
   oBrw:CreateFromCode()
   oDlg:oClient   := oBrw

 ACTIVATE WINDOW oDlg
   

return nil
 

Regards Maurizo

[Maurizio]

Hello ,

Is there a solution to this problem?

Regards Maurizio

[Daniel Garcia-Gil]

Hello Maurizio..

try with this...
viewtopic.php?f=6&t=15953&p=82608&hilit=bvalid#p82608

[nageswaragunupudi]

Please modify xbrowse.prg ( version 10.2 ) like this:
line no:9781-9783
Original code:

Code: Select all  Expand view

  if ::bEditValid != nil
      ::oEditGet:bValid := { | oGet, lRet | oGet:lValidating := .T., lRet := Eval( ::bEditValid, oGet, Self ), oGet:lValidating := .F., If( ! lRet, oGet:SetFocus(),), lRet }
   endif
 

Modify the assignment to ::oEditGet:bValid as :-

Code: Select all  Expand view

     ::oEditGet:bValid := { | oGet, lRet | oGet:lValidating := .T., lRet := Eval( ::bEditValid, oGet, Self ), ;
               oGet:lValidating := .F., If( ! lRet, oGet:SetFocus(), oGet:bValid := nil ), lRet }
 

With this modification, EditValid is executed only once.

[Maurizio]

Thank Nage

now works correctly ,
Antonio is it possible include in the original version ?

Maurizio

[Antonio Linares]

Maurizio,

Yes, we are going to include it