Lector de XML

[Antonio Linares]

Este es un ejemplo sencillo de como analizar un XML:

Si sabes como mejorarlo, se agradece tu colaboración para que asi tengamos una función de lectura genérica de un XML

xmlreader.prg

Code: Select all | Expand

#include "FiveWin.ch"

function Main()
   
   local hFile    := FOpen( "test.xml" ) 
   Local oMnuXml  := TXmlDocument():New( hFile )
   Local oXmlNode := oMnuXml:FindFirst( "Header" )
   Local oXmlIter := TXmlIterator():New( oXmlNode ), oTagActual, cAttribute

   while .T.
      oTagActual = oXmlIter:Next()
      If oTagActual != nil
         ? oTagActual:cName, oTagActual:cData
      Else
         Exit
      Endif
   End

   oXmlNode = oMnuXml:FindFirst( "Detail" )
   oXmlIter = TXmlIterator():New( oXmlNode )

   while .T.
      oTagActual = oXmlIter:Next()
      If oTagActual != nil
         MsgInfo(  oTagActual:cName, oTagActual:cData )
         HEval( oTagActual:aAttributes, { | cKey, cValue | MsgInfo( cKey, cValue ) } )
         // MsgInfo( ValType( oTagActual:aAttributes ) )
         // for each cAttribute in oTagActual:aAttributes
         //    MsgInfo( cAttribute, oTagActual:GetAttribute( cAttribute ) )
         // next   
      Else
         Exit
      Endif
   End

   FClose( hFile )

return nil
 

[Antonio Linares]

Esta versión es más simple y debiera funcionar bien con cualquier XML

xmlreader.prg

Code: Select all | Expand

#include "FiveWin.ch"

function Main()
   
   local hFile    := FOpen( "test.xml" ) 
   Local oXmlDoc  := TXmlDocument():New( hFile )
   Local oXmlIter := TXmlIterator():New( oXmlDoc:oRoot ), oTagActual

   while .T.
      oTagActual = oXmlIter:Next()
      If oTagActual != nil
         MsgInfo( oTagActual:cName, oTagActual:cData )
         HEval( oTagActual:aAttributes, { | cKey, cValue | MsgInfo( cKey, cValue ) } )
      Else
         Exit
      Endif
   End

   FClose( hFile )

return nil

test.xml

Code: Select all | Expand

<xml>
<one>
<name>FiveWin</name>
<company>FiveTech Software</company>
</one>
<two attribute1="att1" attribute2="att2">
</two>
<three>
</three>
</xml>

[RenOmaS]

Buenas
con la version de harbour (v.3.2 rev 18563), tengo que hacer estos cambios y funciona bien

Code: Select all | Expand

#include "FiveWin.ch"                                                          
                                                                               
function Main()                                                                
                                                                               
   local hFile    := FOpen( "rai102.xml" )                                       
   Local oXmlDoc  := TXmlDocument():New( hFile )                               
   Local oXmlIter := TXmlIterator():New( oXmlDoc:oRoot ), oTagActual           
                                                                               
   while .T.                                                                   
      oTagActual = oXmlIter:Next()                                             
      If oTagActual != nil                                                     
         MsgInfo( oTagActual:cName, oTagActual:cData )   
         If Len( oTagActual:aAttributes ) > 0
         Eval( oTagActual:aAttributes, { | cKey, cValue | MsgInfo( cKey, cValue ) } )                                                                   
         endIf
      Else                                                                     
         Exit                                                                  
      Endif                                                                    
   End                                                                         
                                                                               
   FClose( hFile )                                                             
                                                                               
return nil                                                                     
 

[karinha]

También se puede hacer asi:

Code: Select all | Expand

#include "FiveWin.ch"
#include "fileio.ch"
#include "hbxml.ch"

FUNCTION Main()

   LOCAL hFile, cXml, cFileName:="TEST.XML"
   LOCAL xmlDoc, xmlIter , xmlNode, cNode, cAttrib, cValue, oCampo, oConteudo

   IF .NOT. FILE( cFileName )

      MsgInfo( "Arquivo Não Encontrado !!!","Atenção" ) // nome do arquivo

      cFileName := cGetFile( "XML File (*.Xml)|*.Xml|","Selecione arquivo XML da NFe ",curdir())

      IF .NOT. FILE( cFileName )

         RETURN NIL

      ENDIF

   ENDIF

   cNode   := NIL
   cAttrib := NIL
   cValue  := NIL
   hFile  := FOpen( cFileName )

   xmlDoc := TXmlDocument():New( hFile )

   IF xmlDoc:nStatus != HBXML_STATUS_OK

      Msginfo( "Erro ao Ler Arquivo .XML" )

      RETURN NIL

   ENDIF

   xmlIter := TXmlIterator():New( xmlDoc:oRoot )
   xmlNode := xmlIter:Find()

   DO WHILE xmlNode != NIL

      SYSREFRESH()

      IF .NOT. EMPTY( xmlNode:cData )

         IF SUBS( xmlNode:cData,1,1 ) # "<"

            oCampo    := xmlNode:cName

            oConteudo := xmlNode:cData

         ENDIF

      ELSE

        oCampo := xmlNode:cName

      ENDIF

      ? oCampo, oConteudo

      xmlNode := xmlIter:Next() // joga pro proximo campo

   ENDDO

RETURN NIL

// FIN
 

[karinha]

Eduardo Arena, que error te dá? Muestra como estás haciendo ó poste el .XML. Gracias,