xBrowse - RestoreState() – wrong column sequence

[frose]

Hi,

changing the column sequence, RestoreState() results in a wrong column <-> data relation!

Original browse:


Browse with changed column sequence:


Browse with wrong relations after two "SaveState() - RestoreState()" iterations:


Sample:

Code: Select all  Expand view

#include "fivewin.ch"
#include "xbrowse.ch"
#include "FILEIO.CH"

function Main()

   local oWnd, oBrw, oCol
   LOCAL cState := ""
   LOCAL aState
   LOCAL i
   LOCAL nFileHandle
   
   REQUEST DBFCDX
   USE RSTRSTT
   INDEX ON Field->Prmtr_txt TO RSTRSTT
   SET ORDER TO "RSTRSTT"

   IF FILE( "rstrstts.txt" )
       nFileHandle := FOpen( "rstrstts.txt", FO_READ )
      FSeek( nFileHandle, 0, FS_SET )
      HB_FReadLine( nFileHandle, @cState )
      FClose( nFileHandle )
   ENDIF

      GO TOP
      DEFINE WINDOW oWnd TITLE "Test RestoreState() FWH 1010"
      @ 0, 0 XBROWSE oBrw OF oWnd LINES CELL
      oBrw:nMarqueeStyle = MARQSTYLE_HIGHLROW
      oBrw:CreateFromCode()
      aState := ARead( HexToStr( SubStr( cState, 5 ) ) )
      oBrw:RestoreState( cState )
     
      FOR each oCol in oBrw:aCols
          IF oCol:nWidth > 500
            oCol:nWidth := 150
         ENDIF
      NEXT

      oWnd:oClient := oBrw
     
      ACTIVATE WINDOW oWnd VALID ( cState := oBrw:SaveState(), .T. )
     
      nFileHandle := FCreate( "rstrstts.txt", FO_EXCLUSIVE )
      FWrite( nFileHandle, cState )
      FClose( nFileHandle )

RETURN NIL

 

[gkuhnert]

Frose,

I can confirm, that this error occurs in some constellations. Now I have the first name in the column for surname. If I change the order of columns again to another sequence, everything is fine. If I change back, the error is there again.

[frose]

Gilbert,

seems we are the Beta-testers

[nageswaragunupudi]

Instead of

Code: Select all  Expand view

     @ 0, 0 XBROWSE oBrw OF oWnd LINES CELL

please modify adding the alias

Code: Select all  Expand view

     @ 0, 0 XBROWSE oBrw OF oWnd ALIAS 'RSTRSTT' LINES CELL

Also,
modify

Code: Select all  Expand view

     oBrw:RestoreState( cState )

as

Code: Select all  Expand view

if ! Empty( cState )
      oBrw:RestoreState( cState )
endif

Please try with these modifications.

[frose]

Dear Mr. Rao,

same behaviour as before!

Please let me emphasise one detail once more, perhaps it's important for you: The wrong column sequence starts after the SECOND "SaveState() - RestoreState()" iteration!

Here the steps in detail:
- changing the sequence
- closing the program, saving <cState> first time
- starting the program, all is OK!
- closing the program (without changing anything), saving <cState> second time
- starting the program, wrong sequence!

[nageswaragunupudi]

I am sorry.
Please add AUTOCOLS also

Code: Select all  Expand view

@ 0, 0 XBROWSE oBrw OF oWnd AUTOCOLS ALIAS 'RSTRSTT' LINES CELL

Will you please try with this change and report the result please?

[frose]

Dear Mr. Rao,

nothing changed, still wrong sequences

Did you test it? Have you a functional sample? I'm a little bit confused

Can you give some comments for better understanding whats going on?

[nageswaragunupudi]

Mr. Frose,

Yes, it is a problem to be resolved. Shall try to come up with a fix soon.

[frose]

Mr. Rao,

thank you for the info.

Kind regards from cold and grey Germany

[nageswaragunupudi]

Mr. Frose,

Will you please try by replacing SaveState and RestoreState methods with the following code?

Code: Select all  Expand view

//----------------------------------------------------------------------------//

METHOD SaveState( aAdditionalData ) CLASS TXBrowse

   local aData    := { "nCreationOrders", "nRowHeight", "nWidths", "lHides", "cGrpHdrs", "cHeaders" }
   local aState   := {}

   if ValType( aAdditionalData ) == 'A'
      AEval( aAdditionalData, { |c| AAdd( aData, c ) } )
   endif

   AEval( aData, { |c| AAdd( aState, { c, OSend( Self, c ) } ) } ) // modified
   aState[ 1, 1 ] := "ReArrangeCols"

return "XSS:" + HB_StrToHex( ASave( aState ) )

//----------------------------------------------------------------------------//

METHOD RestoreState( cState ) CLASS TXBrowse

   local aState

   if Left( cState, 4 ) == 'XSS:'
      aState      := ARead( HB_HexToStr( SubStr( cState, 5 ) ) )
      ::ReArrangeCols( aState[ 1, 2 ] )  // added
      AEval( aState, { |a| OSend( Self, "_" + a[ 1 ], a[ 2 ] ) }, 2 ) // modified
      AEval( aState[ 1, 2 ], { |n,i| ::aCols[ i ]:nCreationOrder := n } ) // added
   else
      ::OldRestoreState( cState )
   endif

   ::GetDisplayCols()
   ::Refresh()

return nil

//----------------------------------------------------------------------------//
 

[frose]

Mr. Rao,

it's working fine now, thank you very much

[gkuhnert]

Frank, Rao,

seems to work for me too now. Thank you very much!
(will these changes be included in the next release?)