new bug in FW 11.11

[ukservice]

Hello,

I open this app, click on 3rd prompt, Windows:

.prg

Code: Select all  Expand view

// Testing FiveWin own folders controls support

#include "FiveWin.ch"
#include "Folder.ch"

//----------------------------------------------------------------------------//

function Main()

   local oDlg, oFld, oCbx, oSay
   local nValue := 2, oChk, lChk := .t.
   local cItem, oImageList


   Local oGet1,oGet2,oGet3,oGet4
   local cVar1 := "testing gets" //space(11)
   local cVar2 := "HELLOOOOOO"
   local cVar3 := 0


   DEFINE DIALOG oDlg RESOURCE "Test"

   REDEFINE FOLDER oFld ID 110 OF oDlg ;
      PROMPT "Cli&pper", "&and", "&Windows", "&Magic" ;
      DIALOGS "Sub1", "Sub2", "SUB3"

   oFld:aEnable = { .t., .t., .t., .f. }

   REDEFINE COMBOBOX oCbx VAR cItem ITEMS { "This", "is", "a test" } ;
      ID 100 OF oFld:aDialogs[ 1 ]


   REDEFINE SAY oSay ID 10 OF oFld:aDialogs[ 1 ] PROMPT "Test" COLOR "R+/B"

   REDEFINE BUTTON ID 110 OF oFld:aDialogs[ 1 ] ;   // Redefining a child
      ACTION oChk:SetText( Time() )

   REDEFINE BUTTON ID 120 OF oFld:aDialogs[ 1 ] ;
      ACTION DoBrowse()

   REDEFINE BITMAP ID 130 OF oFld:aDialogs[ 1 ] ;
      FILE "..\bitmaps\question.bmp" TRANSPARENT

   REDEFINE RADIO nValue ID 110, 120, 130 OF oFld:aDialogs[ 2 ] ;
      ON CHANGE MsgBeep()

   REDEFINE BUTTON ID 104 OF oFld:aDialogs[ 2 ] ;   // Redefining a child
      ACTION oFld:SetPrompts( { "one", "two", "three", "four" } )



   REDEFINE GET oGet1 VAR cVar1 ID 101 of oFld:aDialogs[ 3 ]
   REDEFINE GET oGet2 VAR cVar2 ID 102 of oFld:aDialogs[ 3 ]
   REDEFINE GET oGet3 VAR cVar3 ID 103 of oFld:aDialogs[ 3 ]






   REDEFINE BUTTON ID 120 OF oDlg ;
      ACTION oDlg:End()

   oFld:aDialogs[ 1 ]:bRClicked = { || MsgInfo( "page 1" ) }
   oFld:aDialogs[ 2 ]:bRClicked = { || MsgInfo( "page 2" ) }

   ACTIVATE DIALOG oDlg CENTERED ;
      VALID MsgYesNo( "Want to end ?" ) ;
      ON INIT SetImages( oDlg, oFld )

return nil

//----------------------------------------------------------------------------//

function DoBrowse()

   USE Customer
   Browse()
   USE

return nil

//----------------------------------------------------------------------------//

function SetImages( oDlg, oFld )

   local oImageList

   DEFINE IMAGELIST oImageList SIZE 16, 16

   oImageList:AddMasked( TBitmap():Define( "new",,    oDlg ), nRGB( 192, 192, 192 ) )
   oImageList:AddMasked( TBitmap():Define( "open",,   oDlg ), nRGB( 192, 192, 192 ) )
   oImageList:AddMasked( TBitmap():Define( "search",, oDlg ), nRGB( 192, 192, 192 ) )
   oImageList:AddMasked( TBitmap():Define( "print",,  oDlg ), nRGB( 192, 192, 192 ) )

   oFld:SetImageList( oImageList )

return nil

//----------------------------------------------------------------------------//

procedure AppSys  // Xbase++ requirement

return

//----------------------------------------------------------------------------//

.rc file:

Code: Select all  Expand view

#include ".\..\include\WinApi.ch"

#ifdef __FLAT__
  1 24 "winxp\WindowsXP.Manifest"
#endif

#ifdef __64__
   1 24 "WinXP/WindowsXP.Manifest64"
#endif

//new    BITMAP "../bitmaps/16x16/new.bmp"
//open   BITMAP "../bitmaps/16x16/open.bmp"
//search BITMAP "../bitmaps/16x16/search.bmp"
//print  BITMAP "../bitmaps/16x16/print.bmp"


Test DIALOG 19, 47, 233, 124
STYLE DS_MODALFRAME | WS_POPUP | WS_CAPTION | WS_SYSMENU
CAPTION "FiveWin Folders Demo"
{
 CONTROL "", 110, "SysTabControl32", 0 | WS_CHILD | WS_VISIBLE | WS_TABSTOP, 4, 5, 225, 99
 PUSHBUTTON "&OK", 120, 98, 108, 37, 14
}


sub1 DIALOG 18, 18, 205, 80
STYLE WS_CHILD | 4
{
 GROUPBOX "Group", -1, 7, 5, 140, 31, BS_GROUPBOX
 LTEXT "A label", 10, 22, 17, 48, 8
 COMBOBOX 100, 74, 14, 49, 33, CBS_DROPDOWN | WS_TABSTOP
 GROUPBOX "Another group", -1, 8, 39, 139, 37, BS_GROUPBOX
 PUSHBUTTON "&First", 110, 34, 58, 24, 14
 PUSHBUTTON "&SubDialog", 120, 68, 58, 43, 14
 CONTROL "", 130, "TBitmap", 0 | WS_CHILD | WS_VISIBLE, 159, 19, 35, 38
}


sub2 DIALOG 18, 18, 142, 67
STYLE WS_CHILD | 4
{
 CONTROL "Text", 110, "BUTTON", BS_AUTORADIOBUTTON | WS_CHILD | WS_VISIBLE | WS_GROUP | WS_TABSTOP, 37, 30, 28, 12
 CONTROL "Text", 120, "BUTTON", BS_AUTORADIOBUTTON | WS_CHILD | WS_VISIBLE | WS_TABSTOP, 37, 41, 28, 12
 CONTROL "Text", 130, "BUTTON", BS_AUTORADIOBUTTON | WS_CHILD | WS_VISIBLE | WS_TABSTOP, 37, 52, 28, 12
 PUSHBUTTON "&Second", 104, 93, 26, 32, 12
}


sub3 DIALOG 18, 18, 142, 67
STYLE WS_CHILD | 4
{
 EDITTEXT 101, 60, 10, 72, 12
 LTEXT "Get 1:", -1, 7, 12, 34, 8
 EDITTEXT 102, 60, 25, 72, 12
 LTEXT "Get 2:", -1, 7, 27, 34, 8
 EDITTEXT 103, 60, 40, 72, 12
 LTEXT "Get 3:", -1, 7, 42, 34, 8
}

 

Next, I open Teamviewer 7 and get 2 and get 3 vanish.

Please, see picture:
[IMG=http://img851.imageshack.us/img851/4852/bugteamviewer.th.png][/IMG]

Uploaded with ImageShack.us


I have Windows 7 with themes.

Without themes, it does not happen.

Also, with a simple dialog does not happen. Just with Folders.

Thank you very much.

[ukservice]

up.