Changing bitmap on TBtnBmp at runtime

[reinaldocrespo]

Hi,

Ok, how about changing the bitmap on a TbnBmp object at runtime?

Here is my code, but it isn't changing the bitmap.

Code: Select all  Expand view

...
   REDEFINE BUTTONBMP ::oBalance BITMAP "dotGreen" ID 501 OF ::oDlg TEXTRIGHT ;
               PROMPT oSelf:cDebt UPDATE
...
      ::oBalance:SetText( ::cDebt )
      ::oBalance:LoadBitMaps( IIF( nDebt > 0, "DotRed", "DotGray" ) )
      ::oBalance:Refresh()
 

Ideas?

Thank you,


Reinaldo.

[Marcelo Via Giglio]

Hola Reinaldo,

I don't know if this is the best solution, but I think work

Code: Select all  Expand view

....
::oBalance:hBitmap := LoadBitmap( GetResources(), IIF( nDebt > 0, "DotRed", "DotGray"  ) )
::oBalance:refresh()
...

saludos

Marcelo

[Marcelo Via Giglio]

Reinaldo,

viendo el código fuente, creo que lo que está mal de tu código es tan solo una "S",

cambia

::oBalance:LoadBitMaps( IIF( nDebt > 0, "DotRed", "DotGray" ) )

por

::oBalance:LoadBitMap( IIF( nDebt > 0, "DotRed", "DotGray" ) )

saludos

Marcelo

[Daniel Garcia-Gil]

Reinaldo,

viendo el código fuente, creo que lo que está mal de tu código es tan solo una "S",

cambia

::oBalance:LoadBitMaps( IIF( nDebt > 0, "DotRed", "DotGray" ) )

por

::oBalance:LoadBitMap( IIF( nDebt > 0, "DotRed", "DotGray" ) )

saludos

Marcelo

Hello

it's a wrong way, because we need release the bitmap handle first,

Reinaldo you're using correct way, your code should be work fine

::oBalance:LoadBitMap( IIF( nDebt > 0, "DotRed", "DotGray" ) )

[nageswaragunupudi]

Hi,

Ok, how about changing the bitmap on a TbnBmp object at runtime?

Here is my code, but it isn't changing the bitmap.

Code: Select all  Expand view

...
   REDEFINE BUTTONBMP ::oBalance BITMAP "dotGreen" ID 501 OF ::oDlg TEXTRIGHT ;
               PROMPT oSelf:cDebt UPDATE
...
      ::oBalance:SetText( ::cDebt )
      ::oBalance:LoadBitMaps( IIF( nDebt > 0, "DotRed", "DotGray" ) )
      ::oBalance:Refresh()
 

Ideas?

Thank you,


Reinaldo.

This is TButtonBmp object and not TBtnBmp (FWH own class) object.
Should be :LoadBitmap(...) not :LoadBitmaps(...)
Method LoadBitmap() releases previous bitmap handle.
LoadBitmap accepts single parameter.

Here is a working sample to showing switching bitmap, text and alignment

Code: Select all  Expand view

function ButtnBmpChange()

   local oDlg, oFont, oBtn

   USE CUSTOMER NEW ALIAS CUST

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 200,140 PIXEL FONT oFont

   @ 10,10 BUTTONBMP oBtn PROMPT "Go Right" BITMAP "c:\fwh\bitmaps\right1.bmp" ;
      TEXTLEFT SIZE 80,20 PIXEL OF oDlg

   @ 40,10 BUTTONBMP PROMPT "Change" SIZE 80,20 PIXEL OF oDlg ;
      ACTION If( "left" $ oBtn:cBitmap, ;
         ( oBtn:LoadBitmap( "c:\fwh\bitmaps\right1.bmp" ), ;
           oBtn:SetText( "Go Right" ), ;
           oBtn:cPosText := "TEXTLEFT", oBtn:Refresh() ), ;
         ( oBtn:LoadBitmap( "c:\fwh\bitmaps\left1.bmp" ), ;
           oBtn:SetText( "Go Left" ), ;
           oBtn:cPosText := "TEXTRIGHT", oBtn:Refresh() ) ;
         )

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont

return nil

//----------------------------------------------------------------------------//
 

[Rick Lipkin]

To All

This code worked for me ..

Rick Lipkin

Code: Select all  Expand view

DO CASE
CASE lISGOALS = .T.            // found a goals record
     oBtn4:SetColor( "G/W*" )
     oBtn4:LoadBitmaps("OK", "DOK", "DOK" )
     oBTN4:ReFresh()
     SysReFresh()
OTHERWISE
     oBtn4:SetColor( "R+/W*" )
     oBtn4:LoadBitmaps("POWER", "DPOWER", "DPOWER" )
     oBtn4:ReFresh()
     SysReFresh()
ENDCASE
 

[nageswaragunupudi]

Mr Rick

Though the caption says TBtnBmp actually the control is not TBtnBmp but TButtonBmp, if we see Mr. Reinaldo's code posted first.

Code: Select all  Expand view

  REDEFINE BUTTONBMP ::oBalance BITMAP "dotGreen" ID 501 OF ::oDlg TEXTRIGHT ;
 

The control is clearly TButtonBmp which is inherited from TButton and is basically a Windows Control.

TButtonBmp does not have Method LoadBitmaps( .... ) but only Method LoadBitmap() with a single parameter.

[reinaldocrespo]

Everyone (Marcelo, Rao, Rick, Daniel) - Thank you very much.

Before posting the question, I had tried :loadbitmaps() as well as loadbitmap(), refresh(), GetResources(), and a few others. I had followed TButtonBmp source code and still could not figure out why it wasn't working until I realized that this piece of code was never executing do to a preexisting if condition that prevented program flow from executing it. I felt really stupid LoadBitMap() followed by a refresh() works as expected. Thank you all VERY MUCH for your help.

Best regards,


Reinaldo.