Question about SET KEY

[driessen]

Hello,

I often use the statement SET KEY.

Is there a way to find out which functions are connected to certain keys.

For instance :

SET KEY VK_F10 TO TelMessage

Can I find out to which key the function TelMessage is connected ?

Thanks.

[Antonio Linares]

Michel,

SetKey( nKey ) sets or retrieves the associated codeblock.

Here you have a working example:

Code: Select all  Expand view

#include "FiveWin.ch"

function Main()

   SET KEY VK_F10 TO TelMessage

   Eval( SetKey( VK_F10 ) )

return nil

function TelMessage()

   MsgInfo( "From TelMessage" )

return nil


[Antonio Linares]

If you want to do it the other way round, from the function name to get the associated key, then you have to keep an array yourself:

Code: Select all  Expand view

#include "FiveWin.ch"

#command SET KEY <n> TO <f> => ( SetKey( <n>, {|p, l, v| <f>(p, l, v)} ), AAdd( aFunctions, { <n>, <(f)> } ) )

static aFunctions := {}

function Main()

   SET KEY VK_F10 TO TelMessage

   MsgInfo( GetKey( "TelMessage" ) )

return nil

function TelMessage()

   MsgInfo( "From TelMessage" )

return nil

function GetKey( cProcName )

   local nAt := AScan( aFunctions, { | a | a[ 2 ] == cProcName } )
   
return If( nAt != 0, aFunctions[ nAt ][ 1 ], 0 ) 


[driessen]

Antonio,

Thanks a lot. This is the answer I was looking for.

Have a nice weekend.