Bug in TMenu

[Enrico Maria Giordano]

In the following sample, open the menu and wait for the timer to change the prompt. You will see that the menuitem temporary losts its 2007 style:

Code: Select all  Expand view

#include "Fivewin.ch"


FUNCTION MAIN()

    LOCAL oWnd, oMenu, oTimer

    MENU oMenu 2007
        MENUITEM "Test"

        MENU
            MENUITEM "Test" CHECKED
        ENDMENU
    ENDMENU

    DEFINE WINDOW oWnd;
           MENU oMenu

    DEFINE TIMER oTimer OF oWnd;
           INTERVAL 3000;
           ACTION ( TONE( 440, 1 ), oMenu:aItems[ 1 ]:bAction:aItems[ 1 ]:SetPrompt( "Changed" ) )

    ACTIVATE TIMER oTimer

    ACTIVATE WINDOW oWnd

    RELEASE TIMER oTimer

    RETURN NIL

EMG

[Enrico Maria Giordano]

Already fixed in the upcoming FWH release.

EMG

[Antonio Linares]

Enrico,

Thanks for the fix

We appreciate if you post the fix here, so users can already apply it, thanks

[Enrico Maria Giordano]

Here it is:

Code: Select all  Expand view

#define MF_BYCOMMAND  0
#define MF_ENABLED    0
#define MF_UNCHECKED  0
#define MF_GRAYED     1
#define MF_DISABLED   2
#define MF_CHECKED    8
#define MF_POPUP     16   // 0x0010
#define MF_BREAK     64
#define MF_OWNERDRAW 256  // 0x0100
#define MF_HELP   16384   // 0x4000

Code: Select all  Expand view

METHOD SetPrompt( cPrompt ) CLASS TMenuItem

   local nNewId, nFlags

   ::cPrompt = cPrompt

   if ValType( ::bAction ) == "O" .and. ;
      Upper( ::bAction:ClassName() ) == "TMENU"
      nNewId := ::bAction:hMenu
      nFlags := MF_POPUP
   else
      nNewId := ::nId
      nFlags := nOR( If( ::lActive, MF_ENABLED,;
                nOR( MF_DISABLED, MF_GRAYED ) ),;
                If( ::lChecked, MF_CHECKED, 0 ),;
                If( ::lHelp, MF_HELP, 0 ),;
                If( ::lBreak, MF_BREAK, 0 ),;
                If( ::oMenu:l2007, MF_OWNERDRAW, 0 ) )
   endif

   if ::oMenu != nil
      ModifyMenu( ::oMenu:hMenu, ::nId, nFlags, nNewId, cPrompt )

      if ::oMenu:oWnd != nil
         DrawMenuBar( ::oMenu:oWnd:hWnd )
      endif
   endif

return nil

EMG

[Antonio Linares]

Enrico,

Many thanks